/**
* @file
*
* @ingroup lpc32xx_linker_mzx_stage_2
*
* @brief Memory map.
*/
/**
* @defgroup lpc32xx_linker_mzx_stage_2 MZX Stage-2 Program Memory Map
*
* @ingroup bsp_linker
*
* @brief MZX stage-2 program memory map.
*
*
* Region Name | Region Begin | Region Size |
* RAM_INT | 0x08000000 | 256k |
* RAM_MMU | 0x81c00000 | 16k |
* RAM_EXT | 0x81c04000 | 4M - 16k |
*
*
*
* Section Name | Section Runtime Region | Section Load Region |
* .start | RAM_EXT | |
* .vector | RAM_INT | |
* .text | RAM_EXT | RAM_EXT |
* .rodata | RAM_EXT | RAM_EXT |
* .data | RAM_EXT | RAM_EXT |
* .fast | RAM_EXT | RAM_EXT |
* .bss | RAM_EXT | |
* .work | RAM_EXT | |
* .stack | RAM_INT | |
*
*/
MEMORY {
RAM_INT : ORIGIN = 0x08000000, LENGTH = 256k
RAM_MMU : ORIGIN = 0x81c00000, LENGTH = 16k /* SDRAM on DYCS0 */
RAM_EXT : ORIGIN = 0x81c04000, LENGTH = 4M - 16k /* SDRAM on DYCS0 */
NIRVANA : ORIGIN = 0, LENGTH = 0
}
REGION_ALIAS ("REGION_START", RAM_EXT);
REGION_ALIAS ("REGION_VECTOR", RAM_INT);
REGION_ALIAS ("REGION_TEXT", RAM_EXT);
REGION_ALIAS ("REGION_TEXT_LOAD", RAM_EXT);
REGION_ALIAS ("REGION_RODATA", RAM_EXT);
REGION_ALIAS ("REGION_RODATA_LOAD", RAM_EXT);
REGION_ALIAS ("REGION_DATA", RAM_EXT);
REGION_ALIAS ("REGION_DATA_LOAD", RAM_EXT);
REGION_ALIAS ("REGION_FAST", RAM_EXT);
REGION_ALIAS ("REGION_FAST_LOAD", RAM_EXT);
REGION_ALIAS ("REGION_BSS", RAM_EXT);
REGION_ALIAS ("REGION_WORK", RAM_EXT);
REGION_ALIAS ("REGION_STACK", RAM_INT);
bsp_stack_svc_size = DEFINED (bsp_stack_svc_size) ? bsp_stack_svc_size : 8192;
INCLUDE linkcmds.lpc32xx