/* This file is a derivation of that found with the newlib-1.6 distribution
 * for the idp.ld file.  That file, it appears, was originally written by
 * Rob Savoye.  Other ideas came from Joel Sherrill for the RTEMS linkcmds
 * file (this is basically a mixture of the two).
 *
 *  $Id$
 */

/*
 * Setup the memory map of the MC68ec0x0 Board (IDP)
 * stack grows up towards high memory. This works for
 * both the rom68k and the mon68k monitors.
 */

StackSize = DEFINED(StackSize) ? StackSize : 0x1000;

MEMORY 
{
     ram : org = 0x10000, l = 2M
}

SECTIONS
{
    .text 0x10000:  
    {
        text_start = . ;
        _text_start = . ;
        *(.text)
	. = ALIGN (16);

	*(.eh_fram)
	. = ALIGN (16);

	/*
	 * C++ constructors
	 */
	__CTOR_LIST__ = .;
	LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
	*(.ctors)
	LONG(0)
	__CTOR_END__ = .;
	__DTOR_LIST__ = .;
	LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
	*(.dtors)
	LONG(0)
	__DTOR_END__ = .;
        etext = ALIGN( 0x10 ) ;
        _etext = .;
    } 
    .data ADDR( .text ) + SIZEOF( .text ): 
    {
        data_start = . ;
        _data_start = .;
        *(.data)
        edata = ALIGN( 0x10 ) ;
        _edata = .;
    }
    .bss ADDR( .data ) + SIZEOF( .data ): 
    {
        bss_start = . ;
        _bss_start = . ;
        *(.bss)
        *(COMMON)
	. += StackSize; /* XXX -- Old gld can't handle this */
	. = ALIGN (16);
	stack_init = .;
        end = . ;
        _end = . ;
    }  
}