Index: src/exec/aclocal/bsp-alias.m4
===================================================================
--- c/src/exec/aclocal/bsp-alias.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,39 +1,0 @@
-dnl
-dnl  $Id$
-dnl 
-
-dnl _RTEMS_BSP_ALIAS(BSP_ALIAS,RTEMS_BSP_FAMILY)
-dnl Internal subroutine to RTEMS_BSP_ALIAS
-AC_DEFUN(_RTEMS_BSP_ALIAS,
-[# account for "aliased" bsps which share source code
-  case $1 in
-    simcpu32)     $2=sim68000         ;; # BSVC CPU32 variant
-    c3xsim)       $2=c4xsim           ;; # TI C3x Simulator in gdb
-    mcp750)       $2=motorola_powerpc ;; # Motorola PPC board variant
-    mvme2307)     $2=motorola_powerpc ;; # Motorola PPC board variant
-    mvme162lx)    $2=mvme162          ;; # m68k - mvme162 board variant
-    gen68360_040) $2=gen68360         ;; # m68k - 68360 in companion mode
-    p4600)        $2=p4000            ;; # mips64orion - p4000 board w/IDT 4600
-    p4650)        $2=p4000            ;; # mips64orion - p4000 board w/IDT 4650
-    mbx8*)        $2=mbx8xx           ;; # MBX821/MBX860 board
-    pc386dx)      $2=pc386            ;; # i386 - PC w/o FPU
-    pc486)        $2=pc386            ;; # i386 - PC with i486DX
-    pc586)        $2=pc386            ;; # i386 - PC with Pentium
-    pc686)        $2=pc386            ;; # i386 - PC with PentiumPro
-    pck6)         $2=pc386            ;; # i386 - PC with K6
-    bare*)        $2=bare             ;; # EXP: bare-aliases
-    erc32nfp)     $2=erc32            ;; # erc32 without fpu
-    leon1)     	  $2=leon             ;; # leon without fpu
-    leon2)     	  $2=leon             ;; # leon with fpu
-    simsh7032)    $2=shsim            ;; # SH7032 simulator
-    simsh7045)    $2=shsim            ;; # SH7045 simulator
-    *)            $2=$1;;
-  esac]
-)
-
-dnl RTEMS_BSP_ALIAS(BSP_ALIAS,RTEMS_BSP_FAMILY)
-dnl convert a bsp alias $1 into its bsp directory RTEMS_BSP_FAMILY
-AC_DEFUN(RTEMS_BSP_ALIAS,
-[_RTEMS_BSP_ALIAS(m4_if([$1],,[$RTEMS_BSP],[$1]),
-  m4_if([$2],,[RTEMS_BSP_FAMILY],[$2]))]
-)
Index: src/exec/aclocal/canonical-host.m4
===================================================================
--- c/src/exec/aclocal/canonical-host.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,25 +1,0 @@
-dnl $Id$
-
-AC_DEFUN(RTEMS_CANONICAL_HOST,
-[dnl
-AC_REQUIRE([AC_CANONICAL_HOST])
-RTEMS_HOST=$host_os
-case "${target}" in
-  # hpux unix port should go here
-  i[[34567]]86-*linux*)          # unix "simulator" port
-        RTEMS_HOST=Linux
-	;;
-  i[[34567]]86-*freebsd*)         # unix "simulator" port
-        RTEMS_HOST=FreeBSD
-	;;
-  i[[34567]]86-pc-cygwin*) 	# Cygwin is just enough unix like :)
-        RTEMS_HOST=Cygwin
-	;;
-  sparc-sun-solaris*)           # unix "simulator" port
-        RTEMS_HOST=Solaris
-	;;
-  *) 
-	;;
-esac
-AC_SUBST(RTEMS_HOST)
-])dnl
Index: src/exec/aclocal/canonical-target-name.m4
===================================================================
--- c/src/exec/aclocal/canonical-target-name.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,38 +1,0 @@
-dnl
-dnl $Id$
-dnl
-
-dnl canonicalize target cpu
-dnl NOTE: Most rtems targets do not fullfil autoconf's
-dnl target naming conventions "processor-vendor-os"
-dnl Therefore autoconf's AC_CANONICAL_TARGET will fail for them
-dnl and we have to fix it for rtems ourselves 
-
-AC_DEFUN(RTEMS_CANONICAL_TARGET_CPU,
-[
-AC_CANONICAL_TARGET
-AC_MSG_CHECKING(rtems target cpu)
-case "${target}" in
-  # hpux unix port should go here
-  i[[34567]]86-*linux*)		# unix "simulator" port
-	RTEMS_CPU=unix
-	;;
-  i[[34567]]86-*freebsd*) 	# unix "simulator" port
-	RTEMS_CPU=unix
-	;;
-  i[[34567]]86-pc-cygwin*) 	# Cygwin is just enough unix like :)
-	RTEMS_CPU=unix
-	;;
-  no_cpu-*rtems*)
-        RTEMS_CPU=no_cpu
-	;;
-  sparc-sun-solaris*)           # unix "simulator" port
-	RTEMS_CPU=unix
-	;;
-  *) 
-	RTEMS_CPU=`echo $target | sed 's%^\([[^-]]*\)-\(.*\)$%\1%'`
-	;;
-esac
-AC_SUBST(RTEMS_CPU)
-AC_MSG_RESULT($RTEMS_CPU)
-])
Index: src/exec/aclocal/canonicalize-tools.m4
===================================================================
--- c/src/exec/aclocal/canonicalize-tools.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,16 +1,0 @@
-dnl
-dnl $Id$
-dnl
-dnl Set target tools
-dnl
-
-AC_DEFUN(RTEMS_CANONICALIZE_TOOLS,
-[AC_REQUIRE([RTEMS_PROG_CC])dnl
-
-dnl FIXME: What shall be done if these tools are not available?
-  RTEMS_CHECK_TOOL(AR,ar,no)
-  RTEMS_CHECK_TOOL(LD,ld,no)
-
-dnl special treatment of ranlib
-  RTEMS_CHECK_TOOL(RANLIB,ranlib,:)
-])
Index: src/exec/aclocal/check-bsp-cache.m4
===================================================================
--- c/src/exec/aclocal/check-bsp-cache.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,13 +1,0 @@
-dnl $Id$
-
-dnl RTEMS_CHECK_BSP_CACHE(RTEMS_BSP)
-AC_DEFUN(RTEMS_CHECK_BSP_CACHE,
-[
-AC_REQUIRE([RTEMS_CHECK_CPU])dnl sets RTEMS_CPU, target
-AC_REQUIRE([RTEMS_ENV_RTEMSBSP])dnl set RTEMS_BSP
-AC_REQUIRE([RTEMS_TOP])dnl sets RTEMS_TOPdir
-AC_CACHE_CHECK([for RTEMS_CPU_MODEL], rtems_cv_RTEMS_CPU_MODEL,
-. $RTEMS_TOPdir/c/[$]$1/make/[$]$1.cache)
-RTEMS_CPU_MODEL=$rtems_cv_RTEMS_CPU_MODEL
-AC_SUBST(RTEMS_CPU_MODEL)
-])dnl
Index: src/exec/aclocal/check-bsps.m4
===================================================================
--- c/src/exec/aclocal/check-bsps.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,13 +1,0 @@
-dnl $Id$
-
-AC_DEFUN(RTEMS_CHECK_CUSTOM_BSP,
-[dnl
-AC_REQUIRE([RTEMS_TOP])
-
-AC_MSG_CHECKING([for make/custom/[$]$1.cfg])
-if test -r "$srcdir/$RTEMS_TOPdir/../../make/custom/[$]$1.cfg"; then
-  AC_MSG_RESULT([yes])
-else
-  AC_MSG_ERROR([no])
-fi
-])dnl
Index: src/exec/aclocal/check-cpu.m4
===================================================================
--- c/src/exec/aclocal/check-cpu.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,17 +1,0 @@
-dnl $Id$
-
-dnl check if RTEMS support a cpu
-AC_DEFUN(RTEMS_CHECK_CPU,
-[dnl
-AC_REQUIRE([RTEMS_TOP])
-AC_REQUIRE([RTEMS_CANONICAL_TARGET_CPU])
-
-# Is this a supported CPU?
-AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
-if test -d "$srcdir/$RTEMS_TOPdir/exec/score/cpu/$RTEMS_CPU"; then
-  AC_MSG_RESULT(yes)
-else
-  AC_MSG_ERROR(no)
-fi
-])dnl
-
Index: src/exec/aclocal/check-itron.m4
===================================================================
--- c/src/exec/aclocal/check-itron.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,37 +1,0 @@
-dnl $Id$
-dnl
-AC_DEFUN(RTEMS_CHECK_ITRON_API,
-[dnl
-AC_REQUIRE([RTEMS_CHECK_CPU])dnl
-AC_REQUIRE([RTEMS_ENABLE_ITRON])dnl
-
-AC_CACHE_CHECK([whether CPU supports libitron],
-  rtems_cv_HAS_ITRON_API,
-  [dnl
-    case "$RTEMS_CPU" in
-    unix*)
-      rtems_cv_HAS_ITRON_API="no"
-      ;;
-    *)
-      if test "${RTEMS_HAS_ITRON_API}" = "yes"; then
-        rtems_cv_HAS_ITRON_API="yes";
-      else
-        rtems_cv_HAS_ITRON_API="disabled";
-      fi
-      ;;
-    esac])
-if test "$rtems_cv_HAS_ITRON_API" = "yes"; then
-  HAS_ITRON_API="yes";
-else
-  HAS_ITRON_API="no";
-fi
-AC_SUBST(HAS_ITRON_API)dnl
-])
-
-AC_DEFUN(RTEMS_DEFINE_ITRON_API,
-[AC_REQUIRE([RTEMS_CHECK_ITRON_API])dnl
-if test x"${HAS_ITRON_API}" = x"yes";
-then
-  AC_DEFINE_UNQUOTED(RTEMS_ITRON_API,1,[if itron api is supported])
-fi
-])
Index: src/exec/aclocal/check-multiprocessing.m4
===================================================================
--- c/src/exec/aclocal/check-multiprocessing.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,22 +1,0 @@
-dnl
-dnl $Id$
-dnl
-
-AC_DEFUN(RTEMS_CHECK_MULTIPROCESSING,
-[dnl
-AC_REQUIRE([RTEMS_ENV_RTEMSCPU])dnl
-AC_REQUIRE([RTEMS_CHECK_CPU])dnl
-AC_REQUIRE([RTEMS_ENABLE_MULTIPROCESSING])dnl
-
-AS_IF([test "$enable_multiprocessing" = "yes"],
-  [HAS_MP="yes"],
-  [HAS_MP="no"])
-])
-
-AC_DEFUN(RTEMS_DEFINE_MULTIPROCESSING,
-[AC_REQUIRE([RTEMS_CHECK_MULTIPROCESSING])dnl
-if test x"${HAS_MP}" = x"yes";
-then
-  AC_DEFINE_UNQUOTED(RTEMS_MULTIPROCESSING,1,[if multiprocessing is enabled])
-fi
-])
Index: src/exec/aclocal/check-networking.m4
===================================================================
--- c/src/exec/aclocal/check-networking.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,29 +1,0 @@
-dnl $Id$
-dnl
-AC_DEFUN(RTEMS_CHECK_NETWORKING,
-[dnl
-AC_REQUIRE([RTEMS_CHECK_CPU])dnl
-AC_REQUIRE([RTEMS_ENABLE_NETWORKING])dnl
-
-AC_CACHE_CHECK([whether BSP supports networking],
-  rtems_cv_HAS_NETWORKING,
-  [dnl
-    case "$RTEMS_CPU" in
-    unix*)
-      rtems_cv_HAS_NETWORKING="no"
-      ;;
-    *)
-      if test "${RTEMS_HAS_NETWORKING}" = "yes"; then
-        rtems_cv_HAS_NETWORKING="yes";
-      else
-        rtems_cv_HAS_NETWORKING="disabled";
-      fi
-      ;;
-    esac])
-if test "$rtems_cv_HAS_NETWORKING" = "yes"; then
-  HAS_NETWORKING="yes";
-else
-  HAS_NETWORKING="no";
-fi
-AC_SUBST(HAS_NETWORKING)dnl
-])
Index: src/exec/aclocal/check-newlib.m4
===================================================================
--- c/src/exec/aclocal/check-newlib.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,31 +1,0 @@
-dnl $Id$
-
-AC_DEFUN(RTEMS_CHECK_NEWLIB,
-[dnl
-AC_REQUIRE([RTEMS_PROG_CC_FOR_TARGET])dnl
-AC_REQUIRE([RTEMS_CANONICALIZE_TOOLS])dnl
-AC_CACHE_CHECK([for RTEMS newlib],
-  rtems_cv_use_newlib,
-  [
-dnl some versions of newlib provide not_required_by_rtems
-    AC_TRY_LINK(
-      [extern void not_required_by_rtems() ;],
-      [not_required_by_rtems()],
-      rtems_cv_use_newlib="yes")
-
-dnl some versions of newlib provide rtems_provides_crt0()
-    AS_IF([test -z "$rtems_cv_use_newlib"],
-      [AC_TRY_LINK(
-        [extern void rtems_provides_crt0() ;],
-        [rtems_provides_crt0()],
-        rtems_cv_use_newlib="yes",
-        rtems_cv_use_newlib="no")]
-    )
-  ])
-  RTEMS_USE_NEWLIB="$rtems_cv_use_newlib"
-  AC_SUBST(RTEMS_USE_NEWLIB)
-
-  AS_IF([test x"${RTEMS_USE_NEWLIB}" = x"yes"],
-    [ AC_DEFINE_UNQUOTED(RTEMS_NEWLIB,1,[if using newlib])]
-  )
-])
Index: src/exec/aclocal/check-posix.m4
===================================================================
--- c/src/exec/aclocal/check-posix.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,36 +1,0 @@
-dnl $Id$
-dnl
-AC_DEFUN(RTEMS_CHECK_POSIX_API,
-[dnl
-AC_REQUIRE([RTEMS_CHECK_CPU])dnl
-AC_REQUIRE([RTEMS_ENABLE_POSIX])dnl
-
-AC_CACHE_CHECK([whether CPU supports libposix],
-  rtems_cv_HAS_POSIX_API,
-  [dnl
-    case "$RTEMS_CPU" in
-    unix*)
-      rtems_cv_HAS_POSIX_API="no"
-      ;;
-    *)
-      if test "${RTEMS_HAS_POSIX_API}" = "yes"; then
-        rtems_cv_HAS_POSIX_API="yes";
-      else
-        rtems_cv_HAS_POSIX_API="disabled";
-      fi
-      ;;
-    esac])
-if test "$rtems_cv_HAS_POSIX_API" = "yes"; then
-  HAS_POSIX_API="yes";
-else
-  HAS_POSIX_API="no";
-fi
-AC_SUBST(HAS_POSIX_API)dnl
-])
-
-AC_DEFUN(RTEMS_DEFINE_POSIX_API,
-[AC_REQUIRE([RTEMS_CHECK_POSIX_API])dnl
-AS_IF(
-  [test x"${HAS_POSIX_API}" = x"yes"],
-  [AC_DEFINE_UNQUOTED(RTEMS_POSIX_API,1,[if posix api is supported])])
-])
Index: src/exec/aclocal/check-tool.m4
===================================================================
--- c/src/exec/aclocal/check-tool.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,11 +1,0 @@
-dnl $Id$
-
-## Check for a cross tool, similar to AC_CHECK_TOOL, but do not fall back to
-## the un-prefixed version of PROG-TO-CHECK-FOR.
-dnl RTEMS_CHECK_TOOL(VARIABLE, PROG-TO-CHECK-FOR[, VALUE-IF-NOT-FOUND [, PATH]])
-AC_DEFUN(RTEMS_CHECK_TOOL,
-[
-  AS_IF([test "x$build_alias" != "x$host_alias"],
-    [rtems_tool_prefix=${ac_tool_prefix}])
-  AC_CHECK_PROG($1, ${rtems_tool_prefix}$2, ${rtems_tool_prefix}$2, $3, $4)
-])
Index: src/exec/aclocal/enable-bare.m4
===================================================================
--- c/src/exec/aclocal/enable-bare.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,19 +1,0 @@
-AC_DEFUN(RTEMS_ENABLE_BARE,
-[
-AC_ARG_ENABLE(bare-cpu-cflags,
-AC_HELP_STRING([--enable-bare-cpu-cflags],[specify a particular cpu cflag (bare bsp specific)]),
-[case "${enableval}" in
-  no) BARE_CPU_CFLAGS="" ;;
-  *)    BARE_CPU_CFLAGS="${enableval}" ;;
-esac],
-[BARE_CPU_CFLAGS=""])
-
-AC_ARG_ENABLE(bare-cpu-model,
-AC_HELP_STRING([--enable-bare-cpu-model],[specify a particular cpu model (bare bsp specific)]),
-[case "${enableval}" in
-  no)   BARE_CPU_MODEL="" ;;
-  *)    BARE_CPU_MODEL="${enableval}" ;;
-esac],
-[BARE_CPU_MODEL=""])
-])
-
Index: src/exec/aclocal/enable-inlines.m4
===================================================================
--- c/src/exec/aclocal/enable-inlines.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,21 +1,0 @@
-dnl $Id$
-
-AC_DEFUN(RTEMS_ENABLE_INLINES,
-[AC_ARG_ENABLE(rtems-inlines,
-AC_HELP_STRING([--enable-rtems-inlines],[enable RTEMS inline functions (default:enabled, disable to use macros)]),
-[case "${enableval}" in
-  yes) RTEMS_USE_MACROS=no ;;
-  no) RTEMS_USE_MACROS=yes ;;
-  *)  AC_MSG_ERROR(bad value ${enableval} for disable-rtems-inlines option) ;;
-esac],[RTEMS_USE_MACROS=no])
-AC_SUBST(RTEMS_USE_MACROS)dnl
-
-if test x"${RTEMS_USE_MACROS}" = x"yes";
-then
-  AC_DEFINE_UNQUOTED(USE_MACROS,1,[if using macros])
-else
-  AC_DEFINE_UNQUOTED(USE_INLINES,1,[if using inlines])
-fi
-
-
-])
Index: src/exec/aclocal/enable-itron.m4
===================================================================
--- c/src/exec/aclocal/enable-itron.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,33 +1,0 @@
-dnl $Id$
-
-AC_DEFUN(RTEMS_ENABLE_ITRON,
-[
-## AC_BEFORE([$0], [RTEMS_CHECK_ITRON_API])dnl
-
-AC_ARG_ENABLE(itron,
-AC_HELP_STRING([--enable-itron],[enable itron interface]),
-[case "${enableval}" in 
-  yes) RTEMS_HAS_ITRON_API=yes ;;
-  no) RTEMS_HAS_ITRON_API=no ;;
-  *)  AC_MSG_ERROR(bad value ${enableval} for enable-itron option) ;;
-esac],[RTEMS_HAS_ITRON_API=yes]) 
-
-case "${host}" in
-  # hpux unix port should go here
-  i[[34567]]86-pc-linux*)         # unix "simulator" port
-	RTEMS_HAS_ITRON_API=no
-	;;
-  i[[34567]]86-*freebsd*) # unix "simulator" port
-	RTEMS_HAS_ITRON_API=no
-	;;
-  no_cpu-*rtems*)
-	RTEMS_HAS_ITRON_API=no
-	;;
-  sparc-sun-solaris*)             # unix "simulator" port
-	RTEMS_HAS_ITRON_API=no
-	;;
-  *) 
-	;;
-esac
-AC_SUBST(RTEMS_HAS_ITRON_API)
-])
Index: src/exec/aclocal/enable-multiprocessing.m4
===================================================================
--- c/src/exec/aclocal/enable-multiprocessing.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,12 +1,0 @@
-dnl $Id$
-
-AC_DEFUN(RTEMS_ENABLE_MULTIPROCESSING,
-[
-AC_ARG_ENABLE(multiprocessing,
-AC_HELP_STRING([--enable-multiprocessing],[enable multiprocessing interface]),
-[case "${enable_multiprocessing}" in 
-  yes) ;;
-  no) ;;
-  *)  AC_MSG_ERROR(bad value ${enableval} for enable-multiprocessing option) ;;
-esac],[enable_multiprocessing=no])
-])
Index: src/exec/aclocal/enable-networking.m4
===================================================================
--- c/src/exec/aclocal/enable-networking.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,15 +1,0 @@
-dnl $Id$
-
-AC_DEFUN(RTEMS_ENABLE_NETWORKING,
-[
-## AC_BEFORE([$0], [RTEMS_CHECK_NETWORKING])dnl
-
-AC_ARG_ENABLE(networking,
-AC_HELP_STRING([--enable-networking],[enable TCP/IP stack]),
-[case "${enableval}" in
-  yes) RTEMS_HAS_NETWORKING=yes ;;
-  no) RTEMS_HAS_NETWORKING=no ;;
-  *)  AC_MSG_ERROR(bad value ${enableval} for enable-networking option) ;;
-esac],[RTEMS_HAS_NETWORKING=yes])
-AC_SUBST(RTEMS_HAS_NETWORKING)dnl
-])
Index: src/exec/aclocal/enable-posix.m4
===================================================================
--- c/src/exec/aclocal/enable-posix.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,33 +1,0 @@
-dnl $Id$
-
-AC_DEFUN(RTEMS_ENABLE_POSIX,
-[
-## AC_BEFORE([$0], [RTEMS_CHECK_POSIX_API])dnl
-
-AC_ARG_ENABLE(posix,
-AC_HELP_STRING([--enable-posix],[enable posix interface]),
-[case "${enableval}" in 
-  yes) RTEMS_HAS_POSIX_API=yes ;;
-  no) RTEMS_HAS_POSIX_API=no ;;
-  *)  AC_MSG_ERROR(bad value ${enableval} for enable-posix option) ;;
-esac],[RTEMS_HAS_POSIX_API=yes]) 
-
-case "${host}" in
-  # hpux unix port should go here
-  i[[34567]]86-pc-linux*)         # unix "simulator" port
-	RTEMS_HAS_POSIX_API=no
-	;;
-  i[[34567]]86-*freebsd*) # unix "simulator" port
-	RTEMS_HAS_POSIX_API=no
-	;;
-  no_cpu-*rtems*)
-	RTEMS_HAS_POSIX_API=no
-	;;
-  sparc-sun-solaris*)             # unix "simulator" port
-	RTEMS_HAS_POSIX_API=no
-	;;
-  *) 
-	;;
-esac
-AC_SUBST(RTEMS_HAS_POSIX_API)
-])
Index: src/exec/aclocal/enable-rtemsbsp.m4
===================================================================
--- c/src/exec/aclocal/enable-rtemsbsp.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,16 +1,0 @@
-dnl $Id$
-
-dnl Override the set of BSPs to be built.
-dnl used by the toplevel configure script
-dnl RTEMS_ENABLE_RTEMSBSP(rtems_bsp_list)
-AC_DEFUN(RTEMS_ENABLE_RTEMSBSP,
-[
-AC_BEFORE([$0], [RTEMS_ENV_RTEMSBSP])dnl
-AC_ARG_ENABLE(rtemsbsp,
-AC_HELP_STRING([--enable-rtemsbsp="bsp1 bsp2 .."],
-[BSPs to include in build]),
-[case "${enableval}" in
-  yes|no) AC_MSG_ERROR([missing argument to --enable-rtemsbsp=\"bsp1 bsp2\"]);;
-  *) $1=$enableval;;
-esac],[$1=""])
-])
Index: src/exec/aclocal/env-rtemsbsp.m4
===================================================================
--- c/src/exec/aclocal/env-rtemsbsp.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,47 +1,0 @@
-dnl $Id$
-
-dnl Pass a single BSP via an environment variable
-dnl used by per BSP configure scripts
-AC_DEFUN(RTEMS_ENV_RTEMSBSP,
-[dnl
-AC_BEFORE([$0], [RTEMS_ENABLE_RTEMSBSP])dnl
-AC_BEFORE([$0], [RTEMS_PROJECT_ROOT])dnl
-AC_BEFORE([$0], [RTEMS_CHECK_CUSTOM_BSP])dnl
-
-AC_ARG_VAR([RTEMS_BSP],[RTEMS_BSP to build])
-AC_MSG_CHECKING([for RTEMS_BSP])
-AC_CACHE_VAL(rtems_cv_RTEMS_BSP,
-[dnl
-  test -n "${RTEMS_BSP}" && rtems_cv_RTEMS_BSP="$RTEMS_BSP";
-])dnl
-if test -z "$rtems_cv_RTEMS_BSP"; then
-  AC_MSG_ERROR([Missing RTEMS_BSP])
-fi
-RTEMS_BSP="$rtems_cv_RTEMS_BSP"
-AC_MSG_RESULT(${RTEMS_BSP})
-AC_SUBST(RTEMS_BSP)
-
-RTEMS_BSP_SPECS="-specs bsp_specs -qrtems"
-AC_SUBST(RTEMS_BSP_SPECS)
-
-GCC_SPECS="-B\$(PROJECT_ROOT)/lib/ -B\$(PROJECT_ROOT)/$RTEMS_BSP/lib/"
-AC_SUBST(GCC_SPECS)
-
-PROJECT_INCLUDE="\$(PROJECT_ROOT)/$RTEMS_BSP/lib/include"
-AC_SUBST(PROJECT_INCLUDE)
-
-PROJECT_RELEASE="\$(PROJECT_ROOT)/$RTEMS_BSP"   
-AC_SUBST(PROJECT_RELEASE)
-
-RTEMS_ROOT=$PROJECT_ROOT/c/$RTEMS_BSP
-AC_SUBST(RTEMS_ROOT)
-
-RTEMS_ENABLE_BARE
-AC_SUBST(BARE_CPU_MODEL)
-AC_SUBST(BARE_CPU_CFLAGS)
-
-AM_CONDITIONAL([RTEMS_CONFIG_PER_BSP],[true])
-AM_CONDITIONAL([MULTILIB],[false])
-
-includedir="\${exec_prefix}/${RTEMS_BSP}/lib/include"
-])
Index: src/exec/aclocal/env-rtemscpu.m4
===================================================================
--- c/src/exec/aclocal/env-rtemscpu.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,41 +1,0 @@
-dnl $Id$
-
-AC_DEFUN(RTEMS_ENV_RTEMSCPU,
-[AC_REQUIRE([RTEMS_ENABLE_MULTILIB])
-
-if test x"$multilib" = x"yes"; then
-## FIXME: There is no multilib BSP
-  RTEMS_BSP_SPECS=""
-  AC_SUBST(RTEMS_BSP_SPECS)
-
-  if test -n "$with_multisubdir"; then
-    MULTIBUILDTOP=`echo "/$with_multisubdir" | sed 's,/[[^\\/]]*,../,g'`
-  fi
-  AC_SUBST(MULTIBUILDTOP)
-
-  if test -n "$with_multisubdir"; then
-    MULTISUBDIR="/$with_multisubdir"
-  fi
-  AC_SUBST(MULTISUBDIR)
-
-  PROJECT_ROOT="../../${RTEMS_TOPdir}/\$(MULTIBUILDTOP)\$(top_builddir)"
-  GCC_SPECS="-isystem \$(PROJECT_ROOT)/lib/include"
-  AC_SUBST(GCC_SPECS)
-
-  PROJECT_INCLUDE="\$(PROJECT_ROOT)/lib/include"
-  AC_SUBST(PROJECT_INCLUDE)
-
-  PROJECT_RELEASE="\$(PROJECT_ROOT)"
-  AC_SUBST(PROJECT_RELEASE)
-
-  RTEMS_ROOT=${PROJECT_ROOT}
-  AC_SUBST(RTEMS_ROOT)
-
-  includedir="\${exec_prefix}/lib/include"
-  libdir="${libdir}\$(MULTISUBDIR)"
-  AM_CONDITIONAL([RTEMS_CONFIG_PER_BSP],[false])
-else
-  RTEMS_ENV_RTEMSBSP
-  RTEMS_CHECK_CUSTOM_BSP(RTEMS_BSP)
-fi
-])
Index: src/exec/aclocal/gcc-pipe.m4
===================================================================
--- c/src/exec/aclocal/gcc-pipe.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,21 +1,0 @@
-dnl
-dnl $Id$
-dnl
-dnl Check whether the target compiler accepts -pipe
-dnl
-
-AC_DEFUN(RTEMS_GCC_PIPE,
-[AC_REQUIRE([RTEMS_PROG_CC]) 
-AC_REQUIRE([AC_CANONICAL_HOST])
-AC_CACHE_CHECK(whether $CC accepts --pipe,rtems_cv_gcc_pipe,
-[
-rtems_cv_gcc_pipe=no
-if test x"$GCC" = x"yes"; then
-    echo 'void f(){}' >conftest.c
-    if test -z "`${CC} --pipe -c conftest.c 2>&1`";then
-      rtems_cv_gcc_pipe=yes
-    fi
-    rm -f conftest*
-fi
-])
-])
Index: src/exec/aclocal/gcc-specs.m4
===================================================================
--- c/src/exec/aclocal/gcc-specs.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,20 +1,0 @@
-dnl
-dnl $Id$
-dnl
-dnl Check whether the target compiler accepts -specs
-dnl
-
-AC_DEFUN(RTEMS_GCC_SPECS,
-[AC_REQUIRE([RTEMS_PROG_CC])
-AC_CACHE_CHECK(whether $CC accepts -specs,rtems_cv_gcc_specs,
-[
-rtems_cv_gcc_specs=no
-if test x"$GCC" = x"yes"; then
-  touch confspec
-  echo 'void f(){}' >conftest.c
-  if test -z "`${CC} -specs confspec -c conftest.c 2>&1`";then
-    rtems_cv_gcc_specs=yes
-  fi
-fi
-rm -f confspec conftest*
-])])
Index: src/exec/aclocal/multi.m4
===================================================================
--- c/src/exec/aclocal/multi.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,53 +1,0 @@
-#serial 99
-
-AC_DEFUN(AC_ENABLE_MULTILIB,
-[
-AC_ARG_ENABLE(multilib,
-AC_HELP_STRING([--enable-multilib],
-[build many library versions (default=no)]),
-[case "${enableval}" in
-  yes) multilib=yes ;;
-  no)  multilib=no ;;
-  *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
- esac], [multilib=no])dnl
-
-AM_CONDITIONAL(MULTILIB,test x"${multilib}" = x"yes")
-
-dnl We may get other options which we don't document:
-dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
-
-if test "[$]{srcdir}" = "."; then
-  if test "[$]{with_target_subdir}" != "."; then
-    multilib_basedir="[$]{srcdir}/[$]{with_multisrctop}../ifelse([$2],,,[$2])"
-  else
-    multilib_basedir="[$]{srcdir}/[$]{with_multisrctop}ifelse([$2],,,[$2])"
-  fi
-else
-  multilib_basedir="[$]{srcdir}/ifelse([$2],,,[$2])"
-fi
-AC_SUBST(multilib_basedir)
-
-if test "${multilib}" = "yes"; then
-  multilib_arg="--enable-multilib"
-else
-  multilib_arg=
-fi
-
-AC_OUTPUT_COMMANDS(
-[case " $CONFIG_FILES " in
- *" ]m4_if([$1],,Makefile,[$1])[ "*)
-    ac_file=]m4_if([$1],,Makefile,[$1])[ . ${multilib_basedir}/config-ml.in
-esac],
-[
-  srcdir=${srcdir}
-  host=${host}
-  target=${target}
-  with_multisrctop="${with_multisrctop}"
-  with_target_subdir="${with_target_subdir}"
-  with_multisubdir="${with_multisubdir}"
-  ac_configure_args="${multilib_arg} ${ac_configure_args}"
-  CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
-  multilib_basedir=${multilib_basedir}
-  CC="${CC}"]
-)
-])
Index: src/exec/aclocal/multilib.m4
===================================================================
--- c/src/exec/aclocal/multilib.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,59 +1,0 @@
-dnl This provides configure definitions used for multilib support
-
-dnl parts of these macros are derived from newlib-1.8.2's multilib support
-
-AC_DEFUN(RTEMS_ENABLE_MULTILIB,
-[
-AC_ARG_ENABLE(multilib,
-AC_HELP_STRING([--enable-multilib],
-[build many library versions (default=no)]),
-[case "${enableval}" in
-  yes) multilib=yes ;;
-  no)  multilib=no ;;
-  *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
- esac], [multilib=no])dnl
-
-AM_CONDITIONAL(MULTILIB,test x"${multilib}" = x"yes")
-])
-
-AC_DEFUN([RTEMS_ENABLE_MULTILIB_MASTER],
-[
-AC_REQUIRE([RTEMS_ENABLE_MULTILIB])
-
-dnl We may get other options which we don't document:
-dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
-
-if test "[$]{srcdir}" = "."; then
-  if test "[$]{with_target_subdir}" != "."; then
-    multilib_basedir="[$]{srcdir}/[$]{with_multisrctop}../ifelse([$2],,,[$2])"
-  else
-    multilib_basedir="[$]{srcdir}/[$]{with_multisrctop}ifelse([$2],,,[$2])"
-  fi
-else
-  multilib_basedir="[$]{srcdir}/ifelse([$2],,,[$2])"
-fi
-AC_SUBST(multilib_basedir)
-
-if test "${multilib}" = "yes"; then
-  multilib_arg="--enable-multilib"
-else
-  multilib_arg=
-fi
-
-AC_OUTPUT_COMMANDS(
-[case " $CONFIG_FILES " in
- *" ]m4_if([$1],,Makefile,[$1])[ "*)
-    ac_file=]m4_if([$1],,Makefile,[$1])[ . ${multilib_basedir}/config-ml.in
-esac],
-[
-  srcdir=${srcdir}
-  host=${host}
-  target=${target}
-  with_multisrctop="${with_multisrctop}"
-  with_target_subdir="${with_target_subdir}"
-  with_multisubdir="${with_multisubdir}"
-  ac_configure_args="${multilib_arg} ${ac_configure_args}"
-  CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
-  multilib_basedir=${multilib_basedir}
-  CC="${CC}"])
-])
Index: src/exec/aclocal/prog-cc.m4
===================================================================
--- c/src/exec/aclocal/prog-cc.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,45 +1,0 @@
-dnl
-dnl $Id$
-dnl 
-dnl Check for target gcc
-dnl
-
-AC_DEFUN(RTEMS_PROG_CC,
-[
-AC_BEFORE([$0], [AC_PROG_CPP])dnl
-AC_BEFORE([$0], [AC_PROG_CC])dnl
-AC_BEFORE([$0], [RTEMS_CANONICALIZE_TOOLS])dnl
-
-RTEMS_CHECK_TOOL(CC,gcc)
-test -z "$CC" && \
-  AC_MSG_ERROR([no acceptable cc found in \$PATH])
-AC_PROG_CC
-AC_PROG_CPP
-
-AM_CONDITIONAL(RTEMS_USE_GCC,test x"$GCC" = x"yes")
-])
-
-AC_DEFUN(RTEMS_PROG_CC_FOR_TARGET,
-[
-dnl check target cc
-RTEMS_PROG_CC
-dnl check if the compiler supports --specs
-RTEMS_GCC_SPECS
-dnl check if the target compiler may use --pipe
-RTEMS_GCC_PIPE
-test "$rtems_cv_gcc_pipe" = "yes" && CC="$CC --pipe"
-
-if test "$GCC" = yes; then
-]
-m4_if([$1],,[],[CPPFLAGS="$CPPFLAGS $1"])
-[
-CFLAGS="-g -Wall"
-fi
-
-dnl FIXME: HACK for egcs/cygwin mixing '\\' and '/' in gcc -print-*
-#case $build_os in
-#*cygwin*)     GCCSED="| sed 's%\\\\%/%g'" ;;
-#*) ;;
-#esac
-AC_SUBST(GCCSED)
-])
Index: src/exec/aclocal/prog-ccas.m4
===================================================================
--- c/src/exec/aclocal/prog-ccas.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,8 +1,0 @@
-## $Id$
-
-AC_DEFUN([RTEMS_PROG_CCAS],
-[
-AC_REQUIRE([RTEMS_PROG_CC])
-AC_SUBST(CCAS,["$CC \$(GCCSPECS)"])
-AC_SUBST(CCASFLAGS,["-DASM \$(CFLAGS) \$(INCLUDES)"])
-])
Index: src/exec/aclocal/rtems-cpu-subdirs.m4
===================================================================
--- c/src/exec/aclocal/rtems-cpu-subdirs.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,32 +1,0 @@
-AC_DEFUN([_RTEMS_CPU_SUBDIR],
-[
-$1 )	if test -d ${srcdir}/ifelse([$2],,[$1],[$2/$1]) ; then
-  AC_CONFIG_SUBDIRS(ifelse([$2],,[$1],[$2/$1]))
-  fi
-])
-
-## RTEMS_CPU_SUBDIRS([PREFIX])
-AC_DEFUN([RTEMS_CPU_SUBDIRS],
-[
-## EDIT: If adding a new cpu to RTEMS, add it to the case block below.
-case $RTEMS_CPU in
-_RTEMS_CPU_SUBDIR([a29k],[$1]);;
-_RTEMS_CPU_SUBDIR([arm],[$1]);;
-_RTEMS_CPU_SUBDIR([c4x],[$1]);;
-_RTEMS_CPU_SUBDIR([h8300],[$1]);;
-_RTEMS_CPU_SUBDIR([hppa1.1],[$1]);;
-_RTEMS_CPU_SUBDIR([i386],[$1]);;
-_RTEMS_CPU_SUBDIR([i960],[$1]);;
-_RTEMS_CPU_SUBDIR([m68k],[$1]);;
-_RTEMS_CPU_SUBDIR([mips],[$1]);;
-_RTEMS_CPU_SUBDIR([mips64orion],[$1]);;
-_RTEMS_CPU_SUBDIR([no_cpu],[$1]);;
-_RTEMS_CPU_SUBDIR([or16],[$1]);;
-_RTEMS_CPU_SUBDIR([or32],[$1]);;
-_RTEMS_CPU_SUBDIR([powerpc],[$1]);;
-_RTEMS_CPU_SUBDIR([sh],[$1]);;
-_RTEMS_CPU_SUBDIR([sparc],[$1]);;
-_RTEMS_CPU_SUBDIR([unix],[$1]);;
-*) AC_MSG_ERROR([Invalid RTEMS_CPU])
-esac
-])
Index: src/exec/aclocal/rtems-debug.m4
===================================================================
--- c/src/exec/aclocal/rtems-debug.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,19 +1,0 @@
-## $Id$
-
-AC_DEFUN(RTEMS_ENABLE_RTEMS_DEBUG,
-[
-AC_ARG_ENABLE(rtems-debug,
-AC_HELP_STRING([--enable-rtems-debug],[enable RTEMS_DEBUG]),
-[case "${enable_rtems_debug}" in
-  yes) enable_rtems_debug=yes ;;
-  no)  enable_rtems_debug=no ;;
-  *) AC_MSG_ERROR([bad value ${enable_rtems_debug} for RTEMS_DEBUG]) ;;
-esac],[enable_rtems_debug=no])
-])
-
-AC_DEFUN(RTEMS_CHECK_RTEMS_DEBUG,
-[AC_REQUIRE([RTEMS_ENABLE_RTEMS_DEBUG])
-AS_IF([test x"${enable_rtems_debug}" = x"yes"]
-  [AC_DEFINE_UNQUOTED(RTEMS_DEBUG,1,[if RTEMS_DEBUG is enabled])])
-])
-
Index: src/exec/aclocal/rtems-top.m4
===================================================================
--- c/src/exec/aclocal/rtems-top.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,48 +1,0 @@
-dnl $Id$
-
-dnl
-dnl RTEMS_TOP($1)
-dnl 
-dnl $1 .. relative path from this configure.in to the toplevel configure.in
-dnl
-AC_DEFUN(RTEMS_TOP,
-[dnl
-AC_REQUIRE([RTEMS_VERSIONING])
-AC_CHECK_PROGS(MAKE, gmake make)
-AC_BEFORE([$0], [AC_CONFIG_AUX_DIR])dnl
-AC_BEFORE([$0], [AM_INIT_AUTOMAKE])dnl
-
-AC_PREFIX_DEFAULT([/opt/rtems])
-
-## HACK to allow gnu-make conditionals in automake-Makefiles.
-ENDIF=endif
-AC_SUBST(ENDIF)
-
-RTEMS_TOPdir="$1";
-AC_SUBST(RTEMS_TOPdir)
-
-## with_target_subdirs is handled implicitly by autoconf
-test -n "$with_target_subdir" || with_target_subdir="."
-
-if test "$with_target_subdir" = "." ; then
-# Native
-PROJECT_TOPdir=${RTEMS_TOPdir}/'$(top_builddir)'
-else
-# Cross
-dots=`echo $with_target_subdir|\
-sed -e 's%^\./%%' -e 's%[[^/]]$%&/%' -e 's%[[^/]]*/%../%g'`
-PROJECT_TOPdir=${dots}${RTEMS_TOPdir}/'$(top_builddir)'
-fi
-AC_SUBST(PROJECT_TOPdir)
-
-AS_IF([test "${with_project_root+set}" = set],
-  [PROJECT_ROOT="${with_project_root}${RTEMS_TOPdir}/\$(top_builddir)"],
-  [PROJECT_ROOT="../../${RTEMS_TOPdir}/\$(top_builddir)"])
-AC_SUBST(PROJECT_ROOT)
-
-AC_MSG_CHECKING([for RTEMS Version])
-AS_IF([test -r "${srcdir}/${RTEMS_TOPdir}/exec/aclocal/version.m4"],
-[],
-[AC_MSG_ERROR([Unable to find ${RTEMS_TOPdir}/exec/aclocal/version.m4])])
-AC_MSG_RESULT([_RTEMS_VERSION])
-])dnl
Index: src/exec/aclocal/sysv-ipc.m4
===================================================================
--- c/src/exec/aclocal/sysv-ipc.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,133 +1,0 @@
-dnl
-dnl $Id$
-dnl
-dnl Check for System V IPC calls used by Unix simulators
-dnl
-dnl 98/07/17 Dario Alcocer     alcocer@netcom.com
-dnl 	     Ralf Corsepius    corsepiu@faw.uni-ulm.de
-dnl
-dnl Note: $host_os should probably *not* ever be used here to
-dnl determine if host supports System V IPC calls, since some
-dnl (e.g. FreeBSD 2.x) are configured by default to include only
-dnl a subset of the System V IPC calls.  Therefore, to make sure
-dnl all of the required calls are found, test for each call explicitly.
-dnl
-dnl All of the calls use IPC_PRIVATE, so tests will not unintentionally
-dnl modify any existing key sets.  See the man pages for semget, shmget, 
-dnl msgget, semctl, shmctl and msgctl for details.
-
-AC_DEFUN(RTEMS_UNION_SEMUN,
-[
-AC_CACHE_CHECK([whether $host defines union semun],
-  rtems_cv_HAS_UNION_SEMUN,
-  [AC_TRY_COMPILE([
-#include <sys/types.h>
-#include <sys/ipc.h>
-#include <sys/sem.h>],
-[union semun arg ;],
-[rtems_cv_HAS_UNION_SEMUN="yes"],
-[rtems_cv_HAS_UNION_SEMUN="no"])
-])
-if test "$rtems_cv_HAS_UNION_SEMUN" = "yes"; then
-    AC_DEFINE(HAS_UNION_SEMUN,[1],[if having union semum])
-fi
-])
-
-AC_DEFUN(RTEMS_SYSV_SEM,
-[AC_REQUIRE([AC_PROG_CC]) 
-# AC_REQUIRE([RTEMS_CANONICAL_HOST])
-AC_CACHE_CHECK(whether $host supports System V semaphores,
-rtems_cv_sysv_sem,
-[
-AC_TRY_RUN(
-[
-#include <sys/types.h>
-#include <sys/ipc.h>
-#include <sys/sem.h>
-#if !HAS_UNION_SEMUN
-  union semun {
-    int val;
-    struct semid_ds *buf;
-    ushort *array;
-  } ;
-#endif
-int main () {
-  union semun arg ;
-
-  int id=semget(IPC_PRIVATE,1,IPC_CREAT|0400);
-  if (id == -1)
-    exit(1);
-  arg.val = 0; /* avoid implicit type cast to union */
-  if (semctl(id, 0, IPC_RMID, arg) == -1)
-    exit(1);
-  exit(0);
-}
-],
-rtems_cv_sysv_sem="yes", rtems_cv_sysv_sem="no", :)
-])
-])
-
-AC_DEFUN(RTEMS_SYSV_SHM,
-[AC_REQUIRE([AC_PROG_CC]) 
-# AC_REQUIRE([RTEMS_CANONICAL_HOST])
-AC_CACHE_CHECK(whether $host supports System V shared memory,
-rtems_cv_sysv_shm,
-[
-AC_TRY_RUN([
-#include <sys/types.h>
-#include <sys/ipc.h>
-#include <sys/shm.h>
-int main () {
-  int id=shmget(IPC_PRIVATE,1,IPC_CREAT|0400);
-  if (id == -1)
-    exit(1);
-  if (shmctl(id, IPC_RMID, 0) == -1)
-    exit(1);
-  exit(0);
-}
-],
-rtems_cv_sysv_shm="yes", rtems_cv_sysv_shm="no", :)
-])
-])
-
-AC_DEFUN(RTEMS_SYSV_MSG,
-[AC_REQUIRE([AC_PROG_CC]) 
-# AC_REQUIRE([RTEMS_CANONICAL_HOST])
-AC_CACHE_CHECK(whether $host supports System V messages,
-rtems_cv_sysv_msg,
-[
-AC_TRY_RUN([
-#include <sys/types.h>
-#include <sys/ipc.h>
-#include <sys/msg.h>
-int main () {
-  int id=msgget(IPC_PRIVATE,IPC_CREAT|0400);
-  if (id == -1)
-    exit(1);
-  if (msgctl(id, IPC_RMID, 0) == -1)
-    exit(1);
-  exit(0);
-}
-],
-rtems_cv_sysv_msg="yes", rtems_cv_sysv_msg="no", :)
-])
-])
-
-AC_DEFUN(RTEMS_CHECK_SYSV_UNIX,
-[# AC_REQUIRE([RTEMS_CANONICAL_HOST])
-if test "$RTEMS_CPU" = "unix" ; then
-  RTEMS_UNION_SEMUN
-  RTEMS_SYSV_SEM
-  if test "$rtems_cv_sysv_sem" != "yes" ; then
-    AC_MSG_ERROR([System V semaphores don't work, required by simulator])
-  fi
-  RTEMS_SYSV_SHM
-  if test "$rtems_cv_sysv_shm" != "yes" ; then
-    AC_MSG_ERROR([System V shared memory doesn't work, required by simulator])
-  fi
-  RTEMS_SYSV_MSG
-  if test "$rtems_cv_sysv_msg" != "yes" ; then
-    AC_MSG_ERROR([System V messages don't work, required by simulator])
-  fi
-fi
-])
Index: src/exec/aclocal/tool-paths.m4
===================================================================
--- c/src/exec/aclocal/tool-paths.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,23 +1,0 @@
-AC_DEFUN(RTEMS_TOOLPATHS,
-[
-# tooldir='$(exec_prefix)/'$target_alias
-# Temporary work-around until building in source tree is supported
-AC_REQUIRE([RTEMS_PROJECT_ROOT])
-
-tooldir='$(PROJECT_ROOT)'
-AC_SUBST(tooldir)
-
-project_includedir='$(tooldir)'/include
-AC_SUBST(project_includedir)
-
-project_libdir='$(tooldir)/lib$(MULTISUBDIR)'
-AC_SUBST(project_libdir)
-
-project_bindir='$(tooldir)/bin'
-AC_SUBST(project_bindir)
-
-rtems_bspdir='$(prefix)/${RTEMS_BSP}'
-AC_SUBST(rtems_bspdir)
-rtems_makedir='$(prefix)/make'
-AC_SUBST(rtems_makedir)
-])
Index: src/exec/aclocal/version.m4
===================================================================
--- c/src/exec/aclocal/version.m4	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,2 +1,0 @@
-AC_DEFUN([RTEMS_VERSIONING],
-m4_define([_RTEMS_VERSION],[ss-20020528]))
Index: src/exec/automake/compile.am
===================================================================
--- c/src/exec/automake/compile.am	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,209 +1,0 @@
-##
-## $Id$
-##
-
-## -------------------------------------------------------------------------
-## NOTE: This file is rather immature and has to be considered to be 
-## almost experimental.
-##
-## Expect frequent changes -- It deserves to be cleaned up :(
-## -------------------------------------------------------------------------
-
-## The section below is based on make/compilers/gcc-target-default.cfg
-## used in former versions of RTEMS.
-
-## 
-## Set up the flags for the toolchains:
-##
-## We are considering 3 different building schemes here:
-## * Using gcc's being able to accept -specs (aka gcc-2.8 building scheme)
-## * Using gcc's not being able to accept -specs (aka gcc-2.7.2 building
-##   scheme)
-## * Using third party toolchains (aka non-gcc building scheme)
-##
-## Automake conditionals in use:
-## RTEMS_USE_GCC     .. if we are using GCC
-
-## NOTES: 
-## * The gcc-2.8 building scheme is the nominal building scheme and
-##   is actively supported.
-## * The non-gcc building scheme requires manually setting up environment 
-##   variables and is hardly tested at all
-
-## CFLAGS_OPTIMIZE_V, CFLAGS_DEBUG_V, CFLAGS_PROFILE_V are the values we
-## would want the corresponding macros to be set to.
-##
-## CFLAGS_OPTIMIZE, CFLAGS_DEBUG, CFLAGS_PROFILE are set by the 
-## 'VARIANT=<OPTIMIZE|DEBUG|PROFILE>' targets to their _V values.
-
-## XCPPFLAGS, XCFLAGS, XASFLAGS 
-## are used to add flags from the shell
-## cf. make.info ("Implicit rules/variables" for details)
-
-if RTEMS_USE_GCC
-## All the stuff below is specific to gcc
-
-CFLAGS_DEFAULT=-g -Wall
-## gcc >= 2.8.x
-GCCSPECS = $(GCC_SPECS) $(RTEMS_BSP_SPECS)
-else
-## fall back to the old style compilers/*.cfg
-## CONFIG.CC is supposed to be provided by <BSP>.cfg
-include $(CONFIG.CC)
-endif # RTEMS_USE_GCC
-
-DEFS = @DEFS@
-
-CPPFLAGS = @CPPFLAGS@ $(CPU_DEFINES) \
-   $(DEFINES) $(XCPPFLAGS) $(CPPFLAGS_GCC)
-CFLAGS   = $(CFLAGS_DEFAULT) $(CPU_CFLAGS) $(XCFLAGS)
-ASFLAGS  = $(CPU_ASFLAGS) $(CPU_CFLAGS) $(XASFLAGS)
-
-## FIXME: This doesn't seem to be correct
-# when debugging, optimize flag: typically empty
-# some compilers do allow optimization with their "-g"
-CFLAGS_DEBUG_OPTIMIZE_V=-g
-LDFLAGS_DEBUG_V =
-
-# profile flag; use gprof(1)
-CFLAGS_PROFILE_V=-pg
-LDFLAGS_PROFILE_V =
-
-# List of library paths without -L
-LD_PATHS= $(PROJECT_RELEASE)/lib
-
-# ld flag for incomplete link
-LDFLAGS_INCOMPLETE = -r
-
-# ld flags for profiling, debugging
-LDFLAGS=$(LDFLAGS_PROFILE) $(LDFLAGS_DEBUG) $(LD_PATHS:%=-L %)
-
-#
-# How to compile stuff into ${ARCH} subdirectory
-#
-
-COMPILE = $(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) \
-	$(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)
-CCLD = $(CC)
-LINK = $(CCLD) $(AM_CFLAGS) $(CFLAGS) \
-        $(AM_LDFLAGS) $(LDFLAGS) -o $@
-
-CCASCOMPILE = $(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)
-
-${ARCH}/%.o: %.c
-	${COMPILE} -o $@ -c $<
-
-${ARCH}/%.o: %.S
-	${CCASCOMPILE} -o $@ -c $<
-
-# Make foo.rel from foo.o
-${ARCH}/%.rel: ${ARCH}/%.o
-	${make-rel}
-
-# Dependency files for use by gmake
-# NOTE: we don't put them into $(ARCH)
-#       so that 'make clean' doesn't blow it away
-
-DEPEND=Depends-${ARCH}
-
-CLEAN_DEPEND=$(DEPEND).tmp
-CLOBBER_DEPEND=$(DEPEND)
-
-# We deliberately don't have anything depend on the
-# $(DEPEND) file; otherwise it will get rebuilt even
-# on 'make clean'
-#
-
-## HACK: Specific to gcc
-## FIXME: The approach below is known to be conceptionally broken.
-depend-am: $(C_FILES) $(CC_FILES) $(S_FILES)
-##       Use gcc -M to generate dependencies
-##       Replace foo.o with $(ARCH)/foo.o
-##       Replace $(ARCH) value with string $(ARCH)
-##           so that it will for debug and profile cases
-	$(COMPILE) -M   $^    |  \
-	sed -e 's?^\(.*\)\.o[ ]*:?$$(ARCH)/\1.o:?' \
-	    -e 's?$(ARCH)/?$$(ARCH)/?'   >$(DEPEND).tmp
-	mv $(DEPEND).tmp $(DEPEND)
-depend: depend-am
-
-# pull in dependencies if they exist  
-ifeq (${DEPEND},$(wildcard ${DEPEND}))
-include ${DEPEND}
-@ENDIF@
-
-if RTEMS_USE_GCC
-## gcc >= 2.8
-define make-rel
-	$(LINK) -qnolinkcmds -nostdlib -Wl,-r $(XLDFLAGS) $^
-endef
-else
-## non-gcc
-define make-rel
-	$(LINK) $(XLDFLAGS) $^
-endef
-endif
-
-## -------------------------------------------------------------------------
-
-## translate VARIANT into VARIANT_V
-VARIANT = OPTIMIZE
-
-VARIANT_OPTIMIZE_V = OPTIMIZE
-VARIANT_DEBUG_V = DEBUG
-VARIANT_PROFILE_V = PROFILE
-VARIANT_optimize_V = OPTIMIZE
-VARIANT_debug_V = DEBUG
-VARIANT_profile_V = PROFILE
-
-VARIANT_V = $(VARIANT_$(VARIANT)_V)
-
-## Setup the variant build subdirectory
-ARCH_OPTIMIZE_V = o-optimize
-ARCH_DEBUG_V = o-debug
-ARCH_PROFILE_V = o-profile
-
-ARCH__V = $(ARCH_OPTIMIZE_V)
-ARCH = $(ARCH_$(VARIANT_V)_V)
-
-## Setup the library suffix
-LIBSUFFIX_OPTIMIZE_V =
-LIBSUFFIX_DEBUG_V = _g
-LIBSUFFIX_PROFILE_V = _p
-LIBSUFFIX__V = $(LIBSUFFIX_OPTIMIZE_V)
-
-LIB_VARIANT = $(LIBSUFFIX_$(VARIANT_V)_V)
-LIBSUFFIX_VA = $(LIB_VARIANT).a
-
-## These are supposed to be set in make/custom/<bsp>.cfg
-## CFLAGS_OPTIMIZE_V = 
-## CFLAGS_DEBUG_V =
-## CFLAGS_PROFILE_V =
-CFLAGS__V = $(CFLAGS_OPTIMIZE_V)
-
-## ------------------------------------------------------------------------
-## Setup hard-coded flags
-if RTEMS_USE_GCC
-## gcc >= gcc-2.8
-RTEMS_CFLAGS_OPTIMIZE_V =
-RTEMS_CFLAGS_DEBUG_V = -qrtems_debug -Wno-unused
-RTEMS_CFLAGS_PROFILE_V =
-
-## non-gcc
-## We can't guess what flags might be required here.
-## Pass the values from the environment if you want to apply them.
-endif
-RTEMS_CFLAGS__V = $(RTEMS_CFLAGS_OPTIMIZE_V)
-
-## -------------------------------------------------------------------------
-
-CC = @CC@ $(GCCSPECS)
-CPP = @CPP@ $(GCCSPECS)
-
-##
-AM_CPPFLAGS = $(RTEMS_CPPFLAGS)
-
-AM_CFLAGS = $(RTEMS_CFLAGS_$(VARIANT_V)_V) $(CFLAGS_$(VARIANT_V)_V)
-
-# AM_CFLAGS = $(RTEMS_BSP_CFLAGS) $(RTEMS_CFLAGS)
-AM_CCASFLAGS = $(RTEMS_BSP_CFLAGS) $(RTEMS_CPPFLAGS) $(RTEMS_ASFLAGS)
Index: src/exec/automake/lib.am
===================================================================
--- c/src/exec/automake/lib.am	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,22 +1,0 @@
-##
-##  $Id$
-##
-
-## LD = @LD@
-AR = @AR@
-RANLIB = @RANLIB@
-
-ARFLAGS = ruv
-
-define make-library
-$(RM) $@
-$(AR) $(ARFLAGS) $@ $^
-$(RANLIB) $@
-endef
-
-$(PROJECT_RELEASE)/lib$(MULTISUBDIR):
-	@$(mkinstalldirs) $@
-
-TMPINSTALL_FILES = $(PROJECT_RELEASE)/lib$(MULTISUBDIR)
-
-.PRECIOUS: $(LIB)
Index: src/exec/automake/local.am
===================================================================
--- c/src/exec/automake/local.am	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,38 +1,0 @@
-## $Id$
-
-debug:
-	@echo
-	@echo "\"make debug\" is obsolete, instead use:"
-	@echo "	make VARIANT=DEBUG"
-	@echo
-
-.PHONY: debug
-
-profile:
-	@echo
-	@echo "\"make profile\" is obsolete, instead use:"
-	@echo "	make VARIANT=PROFILE"
-	@echo
-
-.PHONY: profile
-
-preinstall-am: $(PREINSTALL_FILES)
-preinstall: preinstall-am
-.PHONY: preinstall preinstall-am
-
-depend-am:
-depend: depend-am
-.PHONY: depend depend-am
-
-${ARCH}:
-	mkdir ${ARCH}
-
-clean-local:
-	$(RM) -r o-optimize o-debug o-profile $(CLEANDIRS)
-	$(RM) Depends-o-optimize.tmp Depends-o-debug.tmp Depends-o-profile.tmp
-
-distclean-local:
-	$(RM) Depends-o-optimize Depends-o-debug Depends-o-profile
-
-PROJECT_TOOLS = $(PROJECT_RELEASE)/build-tools
-
Index: src/exec/automake/multilib.am
===================================================================
--- c/src/exec/automake/multilib.am	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,38 +1,0 @@
-## $Id$
-
-if MULTILIB
-MULTISRCTOP =
-MULTIDIRS =
-MULTIDO = true
-MULTICLEAN = true
-endif
-
-# Multilib support rules
-.PHONY: all-multi install-multi mostlyclean-multi clean-multi distclean-multi \
-	maintainer-clean-multi
-
-if MULTILIB
-all-recursive: all-multi
-install-recursive: install-multi
-
-mostlyclean-recursive: mostlyclean-multi
-clean-recursive: clean-multi
-distclean-recursive: distclean-multi
-maintainer-clean-recursive: maintainer-clean-multi
-
-all-multi:
-	$(MULTIDO) $(AM_MAKEFLAGS) DO=all multi-do
-install-multi:
-	$(MULTIDO) $(AM_MAKEFLAGS) DO=install multi-do
-
-mostlyclean-multi:
-	$(MULTICLEAN) $(AM_MAKEFLAGS) DO=mostlyclean multi-clean
-clean-multi:
-	$(MULTICLEAN) $(AM_MAKEFLAGS) DO=clean multi-clean
-distclean-multi:
-	$(MULTICLEAN) $(AM_MAKEFLAGS) DO=distclean multi-clean
-maintainer-clean-multi:
-	$(MULTICLEAN) $(AM_MAKEFLAGS) DO=maintainer-clean multi-clean
-else
-include $(RTEMS_ROOT)/make/custom/@RTEMS_BSP@.cfg
-endif
Index: src/exec/automake/subdirs.am
===================================================================
--- c/src/exec/automake/subdirs.am	(revision b9292646dc8ca05f4bb170f96688e01562ccd5c4)
+++ 	(revision )
@@ -1,36 +1,0 @@
-## $Id$
-
-## Borrowed from automake-1.4 and adapted to RTEMS 
-
-## NOTE: This is a temporary work-around to keep 
-## RTEMS's non automake standard make targets working.
-## Once automake is fully integrated these make targets 
-## and this file will probably be removed
-
-depend-recursive \
-preinstall-recursive:
-	@set fnord $(MAKEFLAGS); amf=$$2; \
-	dot_seen=no; \
-	target=`echo $@ | sed s/-recursive//`; \
-	list='$(SUBDIRS)'; for subdir in $$list; do \
-	  echo "Making $$target in $$subdir"; \
-	  if test "$$subdir" = "."; then \
-	    dot_seen=yes; \
-	    local_target="$$target-am"; \
-	  else \
-	    local_target="$$target"; \
-	  fi; \
-	  (cd $$subdir && $(MAKE) $(AM_MAKEFLAGS) $$local_target) \
-## This trick allows "-k" to keep its natural meaning when running a
-## recursive rule.
-	   || case "$$amf" in *=*) exit 1;; *k*) fail=yes;; *) exit 1;; esac; \
-	done; \
-	if test "$$dot_seen" = "no"; then \
-	  $(MAKE) $(AM_MAKEFLAGS) "$$target-am" || exit 1; \
-	fi; test -z "$$fail"
-
-preinstall: preinstall-recursive
-.PHONY: preinstall-recursive
-
-depend: depend-recursive
-.PHONY: depend-recursive
