source: rtems/scripts/configure.in @ df25c998

## $Id$

AC_INIT(binutils)

AM_INIT_AUTOMAKE(rtems-scripts,20010516,no)

AC_CANONICAL_HOST

# Check for .exe suffix.
# With autoconf > 2.13 AC_EXEEXT is not what we want to use.
AC_MSG_CHECKING([for executable suffix])
case "$host" in
i?86-*cygwin*)
  EXEEXT=.exe ;;
esac
AC_SUBST(EXEEXT)
AC_MSG_RESULT([$EXEEXT])

test -f ./setup.cache || cp ${srcdir}/setup.def ./setup.cache
. ./setup.cache

# Some linux distributions use /usr/src/packages
# redhat uses /usr/src/redhat
# others might use /usr/src
AC_MSG_CHECKING(for rpm SPECS directory)
if test -d /usr/src/packages/SPECS;
then
  RPM_SPECSdir=/usr/src/packages/SPECS;
elif test -d /usr/src/redhat/SPECS;
then
  RPM_SPECSdir=/usr/src/redhat/SPECS;
elif test -d /usr/src/SPECS;
then
  RPM_SPECSdir=/usr/src/SPECS;
elif test -d /usr/local/src/redhat/SPECS;
then
  RPM_SPECSdir=/usr/local/src/redhat/SPECS;
fi
if test x"$RPM_SPECSdir" = x"" ; then
AC_MSG_ERROR(not found)
fi
AC_MSG_RESULT($RPM_SPECSdir)
AC_SUBST(RPM_SPECSdir)

AC_MSG_CHECKING(for RPM CPU type)
case "$host" in
  i?86-*linux*)         RPM_CPU=i386 ;;
  i?86-*cygwin*)        RPM_CPU=i386 ;;
  sparc-sun-solaris*)   RPM_CPU=sparc ;;
  *)
    AC_MSG_ERROR([RPM CPU for ${host} is unknown])
    ;;
esac
AC_MSG_RESULT($RPM_CPU)

GCCNEWLIBVERS="gcc-${gcc_version}-newlib-${newlib_version}"
AC_SUBST(GCCNEWLIBVERS)
BINUTILSVERS="binutils-${binutils_version}"
AC_SUBST(BINUTILSVERS)
GDBVERS="gdb-${gdb_version}"
AC_SUBST(GDBVERS)
BSPVERS="${rtems_version}"
AC_SUBST(RTEMS_VERSION)
AC_SUBST(BSPVERS)
AC_SUBST(RPM_CPU)

AC_OUTPUT(
Makefile
buildall
buildalltar
mkbinutilspec
mkgccnewlibspec
mkgdbspec
mkbspspec
binutils/Makefile
gccnewlib/Makefile
gdb/Makefile
rtems/Makefile
autotools/Makefile,
chmod 755 buildall
chmod 755 buildalltar
)