source: rtems/cpukit/score/cpu/m68k/cpu_asm.S @ d0279f6e

4.9
Last change on this file since d0279f6e was e0b8176, checked in by Thomas Doerfler <Thomas.Doerfler@…>, on Jul 11, 2008 at 10:05:13 AM

added support for mcf548x

  • Property mode set to 100644
File size: 16.6 KB
Line 
1/*  cpu_asm.s
2 *
3 *  This file contains all assembly code for the MC68020 implementation
4 *  of RTEMS.
5 *
6 *  COPYRIGHT (c) 1989-2008.
7 *  On-Line Applications Research Corporation (OAR).
8 *
9 *  The license and distribution terms for this file may be
10 *  found in the file LICENSE in this distribution or at
11 *  http://www.rtems.com/license/LICENSE.
12 *
13 *  $Id$
14 */
15
16
17#include <rtems/asm.h>
18        .data
19
20#if (defined(__mcoldfire__))
21#if ( M68K_HAS_FPU == 1 )
22PUBLIC (_CPU_cacr_shadow)     
23SYM (_CPU_cacr_shadow):   
24         .long 1
25#endif
26#endif
27
28        .text
29
30/*  void _CPU_Context_switch( run_context, heir_context )
31 *
32 *  This routine performs a normal non-FP context.
33 */
34
35        .align  4
36        .global SYM (_CPU_Context_switch)
37
38.set RUNCONTEXT_ARG,   4                 | save context argument
39.set HEIRCONTEXT_ARG,  8                 | restore context argument
40
41SYM (_CPU_Context_switch):
42          moval    a7@(RUNCONTEXT_ARG),a0| a0 = running thread context
43          movw     sr,d1                 | d1 = status register
44          movml    d1-d7/a2-a7,a0@       | save context
45
46          moval    a7@(HEIRCONTEXT_ARG),a0| a0 = heir thread context
47
48#if (defined(__mcoldfire__))
49#if ( M68K_HAS_FPU == 1 )         
50          moveb    a0@(13*4),d0                 | get context specific DF bit info in d0   
51          btstb    #4,d0                        | test context specific DF bit info
52          beq      fpu_on                       | branch if FPU needs to be switched on
53         
54fpu_off:  movl     _CPU_cacr_shadow,d0          | get content of _CPU_cacr_shadow in d0     
55          btstl    #4,d0                        | test DF bit info in d0
56          bne      restore                      | branch if FPU is already switched off     
57          bsetl    #4,d0                        | set DF bit in d0
58          bra      cacr_set                     | branch to set the new FPU setting in cacr and _CPU_cacr_shadow   
59         
60fpu_on:   movl     _CPU_cacr_shadow,d0          | get content of _CPU_cacr_shadow in d1       
61          btstl    #4,d0                        | test context specific DF bit info
62          beq      restore                      | branch if FPU is already switched on   
63          bclrl    #4,d0                        | clear DF bit info in d0
64         
65cacr_set: movew    sr,d1                        | get content of sr in d1
66          oril     #0x00000700,d1               | mask d1
67          movew    d1,sr                        | disable all interrupts
68          movl     d0,_CPU_cacr_shadow          | move _CPU_cacr_shadow to d1
69          movec    d0,cacr                      | enable FPU in cacr             
70#endif
71#endif
72
73restore:  movml    a0@,d1-d7/a2-a7       | restore context
74          movw     d1,sr                 | restore status register
75          rts
76
77/*PAGE
78 *  void __CPU_Context_save_fp_context( &fp_context_ptr )
79 *  void __CPU_Context_restore_fp_context( &fp_context_ptr )
80 *
81 *  These routines are used to context switch a MC68881 or MC68882.
82 *
83 *  NOTE:  Context save and restore code is based upon the code shown
84 *         on page 6-38 of the MC68881/68882 Users Manual (rev 1).
85 *
86 *         CPU_FP_CONTEXT_SIZE is higher than expected to account for the
87 *         -1 pushed at end of this sequence.
88 *
89 *         Neither of these entries is required if we have software FPU
90 *         emulation.  But if we don't have an FPU or emulation, then
91 *         we need the stub versions of these routines.
92 */
93
94#if (CPU_SOFTWARE_FP == FALSE)
95
96.set FPCONTEXT_ARG,   4                   | save FP context argument
97.set FP_STATE_SAVED,  (4*4)               | FPU state is 4 longwords
98.set FP_REGS_SAVED,   (8*8)               | FPU regs is 8 64bit values
99
100        .align  4
101        .global SYM (_CPU_Context_save_fp)
102SYM (_CPU_Context_save_fp):
103#if ( M68K_HAS_FPU == 1 )
104#if (defined(__mcoldfire__))
105       
106        moval    a7@(FPCONTEXT_ARG),a1    | a1 = &ptr to context area
107        moval    a1@,a0                   | a0 = Save context area
108        leal     a0@(-16),a0              | open context frame for coldfire state frame
109        fsave    a0@                      | save coldfire state frame   
110        tstb     a0@                      | check for a null frame
111        beq.b    nosave                   | Yes, skip save of user model
112        leal     a0@(-64),a0              | open context frame for coldfire data registers (fp0-fp7)
113        fmovem   fp0-fp7,a0@              | save coldfire data registers (fp0-fp7)                     
114        movl     #-1,a0@-                 | place not-null flag on stack
115nosave: movl     a0,a1@                   | save pointer to saved context
116
117#if ( M68K_HAS_EMAC == 1 )
118
119        movel    macsr,d0                 | store content of macsr in d0
120        clrl     d1                       | clear d1
121        movl     d1,macsr                 | disable rounding in macsr
122        movl     acc0,d1                  | store content of acc0 in d1
123        moveml   d0-d1,a0@(-8)            | save EMAC macsr/acc0
124        movl     acc1,d0                  | store acc1 in d0
125        movl     acc2,d1                  | store acc2 in d1
126        moveml   d0-d1,a0@(-16)           | save EMAC acc1/acc2 with offset
127        movl     acc3,d0                  | store acc3 in d0
128        movl     accext01,d1              | store acc2 in d1
129        moveml   d0-d1,a0@(-24)           | save EMAC acc3/accext01 with offset
130        movl     accext23,d0              | store accext23 in d0
131        movl     mask,d1                  | store mask in d1
132        moveml   d0-d1,a0@(-32)           | save EMAC accext23/mask with offset
133        leal     a0@(-32),a0              | set a0 to the begin of coldfire data registers frame (fp0-fp7)
134        movl     a0,a1@                   | save pointer to saved context
135
136#endif
137     
138#else
139
140        moval    a7@(FPCONTEXT_ARG),a1    | a1 = &ptr to context area
141        moval    a1@,a0                   | a0 = Save context area
142#if ( !defined(__mcoldfire__) && !__mc68060__ )
143        fsave    a0@-                     | save 68881/68882 state frame
144#else
145        lea      a0@(-FP_STATE_SAVED),a0  | save the state of the FPU
146        fsave    a0@                      | on a Coldfire and 68060.
147#endif
148        tstb     a0@                      | check for a null frame
149        beq.b    nosv                     | Yes, skip save of user model
150#if ( !defined(__mcoldfire__) )
151        fmovem   fp0-fp7,a0@-             | save data registers (fp0-fp7)
152        fmovem   fpc/fps/fpi,a0@-         | and save control registers
153#else
154        lea      a0@(-FP_REGS_SAVED),a0
155        fmovem   fp0-fp7,a0@              | save data registers (fp0-fp7)
156        fmove.l  fpc,a0@-                 | and save control registers
157        fmove.l  fps,a0@-
158        fmove.l  fpi,a0@-
159#endif
160        movl     #-1,a0@-                 | place not-null flag on stack
161nosv:   movl     a0,a1@                   | save pointer to saved context
162
163#endif
164#endif
165        rts
166
167        .align  4
168        .global SYM (_CPU_Context_restore_fp)
169SYM (_CPU_Context_restore_fp):
170#if ( M68K_HAS_FPU == 1 )
171
172#if (defined(__mcoldfire__))
173
174        moval    a7@(FPCONTEXT_ARG),a1    | a1 = &ptr to context area
175        moval    a1@,a0                   | a0 = address of saved context
176       
177#if ( M68K_HAS_EMAC == 1 )
178
179        clrl     d0                       | clear d0
180        movl     d0,macsr                 | disable roundrounding in macsr
181        moveml   a0@(0),d0-d1             | get mask/accext23 in d0/d1
182        movl     d0,mask                  | restore mask
183        movl     d1,accext23              | restore accext23
184        moveml   a0@(8),d0-d1             | get accext01/acc3 in d0/d1
185        movl     d0,accext01              | restore accext01
186        movl     d1,acc3                  | restore acc3
187        moveml   a0@(16),d0-d1            | get acc2/acc1 in d0/d1
188        movl     d0,acc2                  | restore acc2
189        movl     d1,acc1                  | restore acc1
190        moveml   a0@(24),d0-d1            | get acc0/macsr in d0/d1
191        movl     d0,acc0                  | restore acc0
192        movl     d1,macsr                 | restore macsr
193        leal     a0@(32),a0               | set a0 to the begin of coldfire FPU frame
194 
195#endif
196               
197        tstb     a0@                      | Null context frame?
198        beq.b    norest                   | Yes, skip fp restore
199        addql    #4,a0                    | throwaway non-null flag
200        fmovem   a0@,fp0-fp7              | restore data regs (fp0-fp7)
201        leal     a0@(+64),a0              | close context frame for coldfire data registers (fp0-fp7)
202norest: frestore a0@                      | restore the fp state frame
203        leal     a0@(+16),a0              | close context frame for coldfire state frame
204        movl     a0,a1@                   | save pointer to saved context
205
206#else
207
208        moval    a7@(FPCONTEXT_ARG),a1    | a1 = &ptr to context area
209        moval    a1@,a0                   | a0 = address of saved context
210        tstb     a0@                      | Null context frame?
211        beq.b    norst                    | Yes, skip fp restore
212        addql    #4,a0                    | throwaway non-null flag
213#if ( !defined(__mcoldfire__) )
214        fmovem   a0@+,fpc/fps/fpi         | restore control registers
215        fmovem   a0@+,fp0-fp7             | restore data regs (fp0-fp7)
216norst:  frestore a0@+                     | restore the fp state frame
217#else
218        fmove.l  a0@+,fpc                 | restore control registers
219        fmove.l  a0@+,fps   
220        fmove.l  a0@+,fpi
221        fmovem   a0@,fp0-fp7              | restore data regs (fp0-fp7)
222        lea      a0@(FP_REGS_SAVED),a0
223norst:  frestore a0@                      | restore the fp state frame
224        lea      a0@(FP_STATE_SAVED),a0
225#endif
226        movl     a0,a1@                   | save pointer to saved context
227
228#endif
229#endif
230        rts
231#endif
232
233/*PAGE
234 *  void _ISR_Handler()
235 *
236 *  This routine provides the RTEMS interrupt management.
237 *
238 *  NOTE:
239 *    Upon entry, the master stack will contain an interrupt stack frame
240 *    back to the interrupted thread and the interrupt stack will contain
241 *    a throwaway interrupt stack frame.  If dispatching is enabled, and this
242 *    is the outer most interrupt, and a context switch is necessary or
243 *    the current thread has pending signals, then set up the master stack to
244 *    transfer control to the interrupt dispatcher.
245 */
246
247#if ( defined(__mcoldfire__) )
248.set SR_OFFSET,    2                     | Status register offset
249.set PC_OFFSET,    4                     | Program Counter offset
250.set FVO_OFFSET,   0                     | Format/vector offset
251#elif ( M68K_HAS_VBR == 1)
252.set SR_OFFSET,    0                     | Status register offset
253.set PC_OFFSET,    2                     | Program Counter offset
254.set FVO_OFFSET,   6                     | Format/vector offset
255#else
256.set SR_OFFSET,    2                     | Status register offset
257.set PC_OFFSET,    4                     | Program Counter offset
258.set FVO_OFFSET,   0                     | Format/vector offset placed in the stack
259#endif /* M68K_HAS_VBR */
260 
261.set SAVED,        16                    | space for saved registers
262
263        .align  4
264        .global SYM (_ISR_Handler)
265
266SYM (_ISR_Handler):
267                                         | disable multitasking
268        addql   #1,SYM (_Thread_Dispatch_disable_level)
269#if ( !defined(__mcoldfire__) )
270        moveml  d0-d1/a0-a1,a7@-         | save d0-d1,a0-a1
271#else
272        lea     a7@(-SAVED),a7
273        movm.l  d0-d1/a0-a1,a7@          | save d0-d1,a0-a1
274#endif
275        movew   a7@(SAVED+FVO_OFFSET),d0 | d0 = F/VO
276        andl    #0x03fc,d0               | d0 = vector offset in vbr
277
278
279#if ( CPU_HAS_SOFTWARE_INTERRUPT_STACK == 1 )
280        | Make a0 point just above interrupt stack
281        movel   _CPU_Interrupt_stack_high,a0
282        cmpl    _CPU_Interrupt_stack_low,a7  | stack below interrupt stack?
283        bcs.b   1f                      | yes, switch to interrupt stack
284        cmpl    a0,a7                   | stack above interrupt stack?
285        bcs.b   2f                      | no, do not switch stacks
2861:
287        movel   a7,a1                   | copy task stack pointer
288        movel   a0,a7                   | switch to interrupt stack
289        movel   a1,a7@-                 | store task stack pointer
290                                        |     on interrupt stack
2912:
292#endif /* CPU_HAS_SOFTWARE_INTERRUPT_STACK == 1 */
293
294        addql   #1,SYM(_ISR_Nest_level) | one nest level deeper
295       
296        movel   SYM (_ISR_Vector_table),a0 | a0= base of RTEMS table
297#if ( M68K_HAS_PREINDEXING == 1 )
298        movel   (a0,d0:w:1),a0           | a0 = address of user routine
299#else
300        addal   d0,a0                    | a0 = address of vector
301        movel   (a0),a0                  | a0 = address of user routine
302#endif
303
304        lsrl    #2,d0                    | d0 = vector number
305        movel   d0,a7@-                  | push vector number
306        jbsr    a0@                      | invoke the user ISR
307        addql   #4,a7                    | remove vector number
308        subql   #1,SYM(_ISR_Nest_level)  | Reduce interrupt-nesting count
309
310#if ( CPU_HAS_SOFTWARE_INTERRUPT_STACK == 1 )
311        movel   _CPU_Interrupt_stack_high,a0
312        subql   #4,a0
313        cmpl    a0,a7                   | At top of interrupt stack?
314        bne.b   1f                      | No, do not restore task stack pointer
315        movel   (a7),a7                 | Restore task stack pointer
3161:
317#endif /* CPU_HAS_SOFTWARE_INTERRUPT_STACK == 1 */
318        subql   #1,SYM (_Thread_Dispatch_disable_level)
319                                         | unnest multitasking
320        bne.b    exit                    | If dispatch disabled, exit
321
322#if ( M68K_HAS_SEPARATE_STACKS == 1 )
323        movew   #0xf000,d0               | isolate format nibble
324        andw    a7@(SAVED+FVO_OFFSET),d0 | get F/VO
325        cmpiw   #0x1000,d0               | is it a throwaway isf?
326        bne.b   exit                     | NOT outer level, so branch
327#else
328/*
329 * If we have a CPU which allows a higher-priority interrupt to preempt a
330 * lower priority handler before the lower-priority handler can increment
331 * _Thread_Dispatch_disable_level then we must check the PC on the stack to
332 * see if it is _ISR_Handler.  If it is we have the case of nesting interrupts
333 * without the dispatch level being incremented.
334 */
335  #if ( !defined(__mcoldfire__) && !__mc68060__ )
336        cmpl    #_ISR_Handler,a7@(SAVED+PC_OFFSET)
337        beq.b   exit       
338  #endif
339#endif
340        tstl    SYM (_Context_Switch_necessary)
341                                         | Is thread switch necessary?
342        bne.b   bframe                   | Yes, invoke dispatcher
343
344        tstl    SYM (_ISR_Signals_to_thread_executing)
345                                         | signals sent to Run_thread
346                                         |   while in interrupt handler?
347        beq.b   exit                     | No, then exit
348
349bframe: clrl    SYM (_ISR_Signals_to_thread_executing)
350                                         | If sent, will be processed
351#if ( M68K_HAS_SEPARATE_STACKS == 1 )
352        movec   msp,a0                   | a0 = master stack pointer
353        movew   #0,a0@-                  | push format word
354        movel   #SYM(_ISR_Dispatch),a0@- | push return addr
355        movew   a0@(6),a0@-              | push saved sr
356        movec   a0,msp                   | set master stack pointer
357#else
358        jsr SYM (_Thread_Dispatch)       | Perform context switch
359#endif
360
361#if ( !defined(__mcoldfire__) )
362exit:   moveml  a7@+,d0-d1/a0-a1         | restore d0-d1,a0-a1
363#else
364exit:   moveml  a7@,d0-d1/a0-a1          | restore d0-d1,a0-a1
365        lea     a7@(SAVED),a7
366#endif
367
368#if ( M68K_HAS_VBR == 0 )
369        addql   #2,a7                    | pop format/id
370#endif /* M68K_HAS_VBR */
371        rte                              | return to thread
372                                         |   OR _Isr_dispatch
373
374/*PAGE
375 *  void _ISR_Dispatch()
376 *
377 *  Entry point from the outermost interrupt service routine exit.
378 *  The current stack is the supervisor mode stack if this processor
379 *  has separate stacks.
380 *
381 *    1.  save all registers not preserved across C calls.
382 *    2.  invoke the _Thread_Dispatch routine to switch tasks
383 *        or a signal to the currently executing task.
384 *    3.  restore all registers not preserved across C calls.
385 *    4.  return from interrupt
386 */
387
388        .global SYM (_ISR_Dispatch)
389SYM (_ISR_Dispatch):
390#if ( !defined(__mcoldfire__) )
391        movml   d0-d1/a0-a1,a7@-
392        jsr     SYM (_Thread_Dispatch)
393        movml   a7@+,d0-d1/a0-a1
394#else
395        lea     a7@(-SAVED),a7
396        movml   d0-d1/a0-a1,a7@
397        jsr     SYM (_Thread_Dispatch)
398        movml   a7@,d0-d1/a0-a1
399        lea     a7@(SAVED),a7
400#endif
401
402#if ( M68K_HAS_VBR == 0 )
403        addql   #2,a7                    | pop format/id
404#endif /* M68K_HAS_VBR */
405        rte
Note: See TracBrowser for help on using the repository browser.