source: rtems/cpukit/configure.ac @ fefd593

4.104.114.84.9
Last change on this file since fefd593 was fefd593, checked in by Ralf Corsepius <ralf.corsepius@…>, on Feb 12, 2005 at 6:21:23 AM

2005-02-12 Ralf Corsepius <ralf.corsepius@…>

  • configure.ac: Remove LIBSCORECPU.
  • wrapup/Makefile.am: Reflect changes above.
  • Property mode set to 100644
File size: 8.1 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id$
4
5AC_PREREQ(2.59)
6AC_INIT([rtems-cpukit],[_RTEMS_VERSION],[rtems-bugs@rtems.com])
7AC_CONFIG_SRCDIR([score])
8RTEMS_TOP([..],[])
9
10RTEMS_CANONICAL_TARGET_CPU
11
12AM_INIT_AUTOMAKE([no-define nostdinc subdir-objects foreign 1.9])
13AM_MAINTAINER_MODE
14
15RTEMS_ENABLE_MULTILIB
16RTEMS_ENABLE_MULTIPROCESSING
17RTEMS_ENABLE_POSIX
18RTEMS_ENABLE_ITRON
19RTEMS_ENABLE_INLINES
20RTEMS_ENABLE_RTEMS_DEBUG
21RTEMS_ENABLE_NETWORKING
22
23RTEMS_ENV_RTEMSCPU
24RTEMS_CHECK_RTEMS_DEBUG
25
26# Is this a supported CPU?
27AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
28if test -d "$srcdir/score/cpu/$RTEMS_CPU"; then
29  AC_MSG_RESULT(yes)
30else
31  AC_MSG_ERROR(no)
32fi
33
34RTEMS_PROG_CC_FOR_TARGET([-fasm])
35RTEMS_PROG_CCAS
36RTEMS_CANONICALIZE_TOOLS
37AM_PROG_CC_C_O
38AC_PROG_RANLIB
39
40# FIXME: For the moment, no reason to check for ada
41# RTEMS_PROG_GNAT
42
43RTEMS_CHECK_NEWLIB
44
45RTEMS_CHECK_MULTIPROCESSING
46RTEMS_CHECK_POSIX_API
47RTEMS_CHECK_ITRON_API
48RTEMS_CHECK_NETWORKING
49
50AS_IF([test x"$HAS_NETWORKING" = x"yes"],[
51## FIXME: Should better use a feature-based test
52AC_MSG_CHECKING([whether CPU supports librpc])
53  case "$RTEMS_CPU" in
54  c4x )  LIBRPC=no;;
55  or32 ) LIBRPC=no;;
56  * )    LIBRPC=yes;;
57  esac
58AC_MSG_RESULT([$LIBRPC])
59])
60
61AC_ARG_ENABLE([ada],
62[AS_HELP_STRING(--enable-ada,enable ada support)],
63[case "${enable_ada}" in
64  yes) ;;
65  no) ;;
66  *)  AC_MSG_ERROR([bad value ${enable_ada} for --enable-ada]) ;;
67esac],[enable_ada=no])
68
69AC_ARG_ENABLE([deprecated],
70[AS_HELP_STRING(--enable-deprecated,allow using deprecated files)],
71[case "${enable_deprecated}" in
72  yes) ;;
73  no) ;;
74  *) enable_deprecated=yes ;;
75esac],[enable_deprecated=yes])
76AM_CONDITIONAL([DEPRECATED],[test "$enable_deprecated" = "yes"])
77
78# HACK: We should use a feature-based configuration.
79AS_IF([test x"${RTEMS_CPU}" = x"unix"],[
80# HACK: silently accept --enable-unixlib
81  test -n "${enable_unixlib}" || enable_unixlib="yes"
82])
83
84# BSD-isms, used throughout the sources
85# Not really used by this configure script
86# FIXME: They should be eliminated if possible.
87AC_CHECK_FUNCS([strsep strcasecmp snprintf])
88AC_CHECK_FUNCS([bcopy bcmp])
89AC_CHECK_FUNCS([isascii fileno])
90
91## Check if the installed toolchain has these headers
92AC_CHECK_HEADER([stdint.h])
93AC_CHECK_HEADER([inttypes.h])
94AC_CHECK_HEADER([tar.h])
95
96## if using newlib, we provide stdint.h and inttypes.h
97AM_CONDITIONAL([RTEMS_PROVIDES_STDINT_H],[test x"${RTEMS_USE_NEWLIB}" = xyes])
98AM_CONDITIONAL([RTEMS_PROVIDES_INTTYPES_H],[test x"${RTEMS_USE_NEWLIB}" = xyes])
99
100## if using newlib, force using stdint.h
101AS_IF([test x"${RTEMS_USE_NEWLIB}" = xyes],
102[RTEMS_USES_STDINT_H=yes],
103[RTEMS_USES_STDINT_H=$ac_cv_header_stdint_h])
104
105AS_IF([test x"${RTEMS_USE_NEWLIB}" = xyes],
106[RTEMS_USES_TAR_H=yes],
107[RTEMS_USES_TAR_H=$ac_cv_header_tar_h])
108
109AS_IF([test x"${RTEMS_CPU}" = x"unix"],[
110## FIXME: This check is doubtful
111AS_IF([test "$HAS_MP" = "yes"],
112  [RTEMS_CHECK_SYSV_UNIX])
113
114## The code fragment below had been used in tools/cpu/unix/gensize.c.
115## FIXME:
116## * The pad very likely is not necessary.
117AC_CHECK_SIZEOF([CPU_CONTEXT],[],[
118#include <stdio.h>
119#include <setjmp.h>
120
121typedef struct {
122  jmp_buf     regs;
123  int         isr_level;
124  int         pad[4]; /* just in case */
125} CPU_CONTEXT;
126])
127])
128
129cat >>cpuopts.tmp <<\_ACEOF
130/**
131 * @file rtems/score/cpuopts.h
132 */
133/* target cpu dependent options file */
134/* automatically generated -- DO NOT EDIT!! */
135#ifndef _CPU_OPTIONS_H
136#define _CPU_OPTIONS_H
137_ACEOF
138
139RTEMS_CPUOPT([RTEMS_DEBUG],
140  [test x"${enable_rtems_debug}" = x"yes"],
141  [1],
142  [if RTEMS_DEBUG is enabled])
143
144RTEMS_CPUOPT([RTEMS_INLINES],
145  [test x"${enable_rtems_inlines}" = x"yes"],
146  [1],
147  [if using inlines])
148
149RTEMS_CPUOPT([RTEMS_ITRON_API],
150  [test x"$rtems_cv_HAS_ITRON_API" = x"yes"],
151  [1],
152  [if itron api is supported])
153
154RTEMS_CPUOPT([RTEMS_MULTIPROCESSING],
155  [test x"$enable_multiprocessing" = x"yes"],
156  [1],
157  [if multiprocessing is enabled])
158
159RTEMS_CPUOPT([RTEMS_NEWLIB],
160  [test x"$RTEMS_USE_NEWLIB" = x"yes"],
161  [1],
162  [if using newlib])
163
164RTEMS_CPUOPT([RTEMS_POSIX_API],
165  [test x"$rtems_cv_HAS_POSIX_API" = x"yes"],
166  [1],
167  [if posix api is supported])
168
169RTEMS_CPUOPT([RTEMS_UNIX],
170  [test x"$RTEMS_CPU" = x"unix"],
171  [1],
172  [to indicate RTEMS unix])
173
174RTEMS_CPUOPT([RTEMS_UNIXLIB],
175  [test x"${enable_unixlib}" = x"yes"],
176  [1],
177  [to indicate RTEMS using RTEMS's unixlib])
178
179RTEMS_CPUOPT([RTEMS_USES_STDINT_H],
180  [test x"${RTEMS_USES_STDINT_H}" = x"yes"],
181  [1],
182  [if RTEMS uses stdint.h])
183
184RTEMS_CPUOPT([RTEMS_USES_TAR_H],
185  [test x"${RTEMS_USES_TAR_H}" = x"yes"],
186  [1],
187  [if RTEMS uses tar.h])
188
189RTEMS_CPUOPT([RTEMS_VERSION],
190  [true],
191  ["]_RTEMS_VERSION["],
192  [RTEMS version string])
193
194RTEMS_CPUOPT([SIZEOF_CPU_CONTEXT],
195  [test x"$RTEMS_CPU" = x"unix"],
196  [$ac_cv_sizeof_CPU_CONTEXT],
197  [The size of a 'CPU_CONTEXT', as computed by sizeof])
198
199cat >>cpuopts.tmp <<\_ACEOF
200
201#endif
202_ACEOF
203
204AS_MKDIR_P(score/include/rtems/score)
205AS_IF([test -f score/include/rtems/score/cpuopts.h],
206[
207  AS_IF([cmp -s score/include/rtems/score/cpuopts.h cpuopts.tmp 2>/dev/null],
208  [
209    AC_MSG_NOTICE([score/include/rtems/score/cpuopts.h is unchanged])
210    rm -f cpuopts.tmp
211  ],[
212    AC_MSG_NOTICE([creating score/include/rtems/score/cpuopts.h])
213    rm -f score/include/rtems/score/cpuopts.h
214    mv cpuopts.tmp score/include/rtems/score/cpuopts.h
215  ])
216],[
217    AC_MSG_NOTICE([creating score/include/rtems/score/cpuopts.h])
218    rm -f score/include/rtems/score/cpuopts.h
219    mv cpuopts.tmp score/include/rtems/score/cpuopts.h
220])
221
222AC_ENABLE_MULTILIB([Makefile],[..])
223
224# libmisc/shell/* wants to assign file descriptors to stdio file descriptors.
225AC_MSG_CHECKING([for assignable stdio])
226AC_COMPILE_IFELSE(
227  [AC_LANG_PROGRAM(
228    [#include <stdio.h>],
229    [stdin = fopen("/tmp", "r")])],
230  [HAVE_ASSIGNABLE_STDIO=yes],
231  [HAVE_ASSIGNABLE_STDIO=no])
232AC_MSG_RESULT([$HAVE_ASSIGNABLE_STDIO])
233
234# libmisc/serdbg exploits weak symbols
235RTEMS_CHECK_GCC_WEAK
236
237AC_CHECK_HEADERS([sys/cdefs.h],[NEED_SYS_CDEFS_H=no],[NEED_SYS_CDEFS_H=yes])
238AC_CHECK_HEADERS([sys/queue.h],[NEED_SYS_QUEUE_H=no],[NEED_SYS_QUEUE_H=yes])
239
240# FIXME: These checks are only in here to provide
241# configuration-time diagnostics and are not really used.
242AC_CHECK_DECLS([_POSIX_LOGIN_NAME_MAX],,,[#include <limits.h>])
243AC_CHECK_DECLS([CHAR_BIT],,,[#include <limits.h>])
244
245## BSD-ism, excluded from POSIX, but available on most platforms
246AC_CHECK_DECLS([sbrk],,,[#include <unistd.h>])
247
248## Check if libc provides BSD's strlcpy/strlcat
249AC_CHECK_FUNCS(strlcpy strlcat)
250
251
252# ... far too many conditionals ...
253AM_CONDITIONAL(LIBRPC,[test "$LIBRPC" = "yes"])
254AM_CONDITIONAL(UNIX,[test x"${RTEMS_CPU}" = x"unix"])
255AM_CONDITIONAL(NEWLIB,test x"$RTEMS_USE_NEWLIB" = x"yes")
256
257AM_CONDITIONAL(INLINE,test x"$enable_rtems_inlines" = x"yes" )
258AM_CONDITIONAL(MACROS,test x"$enable_rtems_inlines" = x"no" )
259AM_CONDITIONAL(HAS_MP,test x"$enable_multiprocessing" = x"yes" )
260
261AM_CONDITIONAL(HAS_POSIX,test x"$rtems_cv_HAS_POSIX_API" = x"yes")
262AM_CONDITIONAL(HAS_ITRON,test x"$rtems_cv_HAS_ITRON_API" = x"yes")
263AM_CONDITIONAL(HAS_NETWORKING,test x"$HAS_NETWORKING" = x"yes")
264
265AM_CONDITIONAL(RTEMS_ADA,[test x"$enable_ada" = x"yes" \
266  && test x"$HAS_POSIX_API" = x"yes"])
267
268AM_CONDITIONAL([NEED_SYS_CDEFS_H],[test x"$NEED_SYS_CDEFS_H" = x"yes"])
269AM_CONDITIONAL([NEED_SYS_QUEUE_H],[test x"$NEED_SYS_QUEUE_H" = x"yes"])
270
271AM_CONDITIONAL([LIBSHELL],[test x"$HAVE_ASSIGNABLE_STDIO" = x"yes"])
272AM_CONDITIONAL([LIBSERDBG],[test x"$rtems_cv_cc_attribute_weak" = x"yes"])
273
274AM_CONDITIONAL([AMPOLISH3],[test x"$USE_MAINTAINER_MODE" = x"yes" \
275  && test -f "${srcdir}/ampolish3.in"])
276
277AC_CONFIG_HEADER(config.h)
278
279# Explicitly list all Makefiles here
280AC_CONFIG_FILES([
281Makefile
282ada/Makefile
283rtems/Makefile
284sapi/Makefile
285score/Makefile
286score/cpu/Makefile
287score/cpu/arm/Makefile
288score/cpu/avr/Makefile
289score/cpu/c4x/Makefile
290score/cpu/h8300/Makefile
291score/cpu/i386/Makefile
292score/cpu/m68k/Makefile
293score/cpu/mips/Makefile
294score/cpu/or32/Makefile
295score/cpu/powerpc/Makefile
296score/cpu/sh/Makefile
297score/cpu/sparc/Makefile
298score/cpu/unix/Makefile
299score/cpu/no_cpu/Makefile
300posix/Makefile
301itron/Makefile
302libblock/Makefile
303libfs/Makefile
304libcsupport/Makefile
305libnetworking/Makefile
306librpc/Makefile
307libmisc/Makefile
308httpd/Makefile
309ftpd/Makefile
310wrapup/Makefile
311])
312
313AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.