source: rtems/cpukit/configure.ac @ f6a1ef9

Last change on this file since f6a1ef9 was f6a1ef9, checked in by Sebastian Huber <sebastian.huber@…>, on Nov 24, 2015 at 2:58:26 PM

posix: Require struct _pthread_cleanup_context

This structure is available in Newlib since 2013-11-29 (Git commit
a534dfd26e765047621acd0eda656ded886e7108).

  • Property mode set to 100644
File size: 14.8 KB
Line 
1## Process this file with autoconf to produce a configure script.
2
3AC_PREREQ([2.69])
4AC_INIT([rtems-cpukit],[_RTEMS_VERSION],[https://devel.rtems.org/newticket])
5AC_CONFIG_SRCDIR([score])
6RTEMS_TOP([..],[])
7
8RTEMS_CANONICAL_TARGET_CPU
9
10AM_INIT_AUTOMAKE([no-define nostdinc subdir-objects foreign 1.12.2])
11AM_MAINTAINER_MODE
12
13RTEMS_ENABLE_MULTILIB
14RTEMS_ENABLE_MULTIPROCESSING
15RTEMS_ENABLE_POSIX
16RTEMS_ENABLE_RTEMS_DEBUG
17RTEMS_ENABLE_NETWORKING
18RTEMS_ENABLE_PARAVIRT
19RTEMS_ENABLE_PROFILING
20RTEMS_ENABLE_DRVMGR
21
22RTEMS_ENV_RTEMSCPU
23RTEMS_CHECK_RTEMS_DEBUG
24
25# Is this a supported CPU?
26AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
27if test -d "$srcdir/score/cpu/$RTEMS_CPU"; then
28  AC_MSG_RESULT(yes)
29else
30  AC_MSG_ERROR(no)
31fi
32
33RTEMS_PROG_CC_FOR_TARGET
34RTEMS_PROG_CCAS
35RTEMS_CANONICALIZE_TOOLS
36AM_PROG_CC_C_O
37AC_PROG_RANLIB
38
39RTEMS_CHECK_NEWLIB
40
41# BSD-isms, used throughout the sources
42# Not really used by this configure script
43# FIXME: They should be eliminated if possible.
44AC_CHECK_FUNCS([strsep strcasecmp snprintf])
45AC_CHECK_FUNCS([strdup strndup strncasecmp])
46AC_CHECK_FUNCS([bcopy bcmp])
47AC_CHECK_FUNCS([isascii fileno])
48
49# <FIXME>
50#   Check for functions supplied by newlib >= 1.17.0
51# Newlib's posix/ directory
52AC_CHECK_FUNCS([readdir_r isatty])
53AC_CHECK_FUNCS([creat \
54  opendir closedir readdir rewinddir scandir seekdir \
55  sleep \
56  telldir \
57  usleep],,
58  [rtems_missing_func="$ac_func";break])
59AS_IF([test -n "$rtems_missing_func"],
60  AC_MSG_ERROR([Missing function $rtems_missing_func in libc])])
61AC_CHECK_FUNCS([__assert])
62AC_CHECK_FUNCS([execl execlp execle execv execvp execve])
63AC_CHECK_FUNCS([regcomp regexec regerror regfree])
64
65# Mandated by POSIX, decls not present in some versions of newlib
66AC_CHECK_DECLS([flockfile],[AC_CHECK_FUNCS([flockfile])],,[#include <stdio.h>])
67AC_CHECK_DECLS([funlockfile],[AC_CHECK_FUNCS([funlockfile])],,[#include <stdio.h>])
68AC_CHECK_DECLS([ftrylockfile],[AC_CHECK_FUNCS([ftrylockfile])],,[#include <stdio.h>])
69
70# Newlib proprietary
71AC_CHECK_HEADERS([envlock.h])
72AC_CHECK_DECLS([__env_lock],,,[#include <envlock.h>])
73AC_CHECK_DECLS([__env_unlock],,,[#include <envlock.h>])
74AC_CHECK_TYPES([struct _Thread_queue_Queue],[],[],[#include <sys/lock.h>])
75
76# Mandated by POSIX, older newlibs bogusly provided CLOCK_PROCESS_CPUTIME+CLOCK_THREAD_CPUTIME
77AC_CHECK_DECL([CLOCK_PROCESS_CPUTIME_ID],[],[AC_MSG_ERROR([missing define CLOCK_PROCESS_CPUTIME_ID])],[#include <time.h>])
78AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID],[],[AC_MSG_ERROR([missing define CLOCK_THREAD_CPUTIME_ID])],[#include <time.h>])
79
80# Mandated by POSIX, decls not present in some versions of newlib,
81# some versions stubbed in newlib's rtems crt0
82RTEMS_CHECK_FUNC([seteuid],[#include <unistd.h>])
83RTEMS_CHECK_FUNC([geteuid],[#include <unistd.h>])
84RTEMS_CHECK_FUNC([setegid],[#include <unistd.h>])
85RTEMS_CHECK_FUNC([getegid],[#include <unistd.h>])
86RTEMS_CHECK_FUNC([setuid],[#include <unistd.h>])
87RTEMS_CHECK_FUNC([getuid],[#include <unistd.h>])
88RTEMS_CHECK_FUNC([setgid],[#include <unistd.h>])
89RTEMS_CHECK_FUNC([getgid],[#include <unistd.h>])
90RTEMS_CHECK_FUNC([setsid],[#include <unistd.h>])
91RTEMS_CHECK_FUNC([getsid],[#include <unistd.h>])
92RTEMS_CHECK_FUNC([setpgid],[#include <unistd.h>])
93RTEMS_CHECK_FUNC([getpgid],[#include <unistd.h>])
94RTEMS_CHECK_FUNC([setpgrp],[#include <unistd.h>])
95RTEMS_CHECK_FUNC([getpgrp],[#include <unistd.h>])
96
97# pthread-functions not declared in some versions of newlib.
98RTEMS_CHECK_FUNC([pthread_attr_getguardsize],[#include <pthread.h>])
99RTEMS_CHECK_FUNC([pthread_attr_setguardsize],[#include <pthread.h>])
100RTEMS_CHECK_FUNC([pthread_attr_setstack],[#include <pthread.h>])
101RTEMS_CHECK_FUNC([pthread_attr_getstack],[#include <pthread.h>])
102
103# These are SMP related and were added to newlib by RTEMS.
104RTEMS_CHECK_FUNC([pthread_attr_setaffinity_np],[
105  #define _GNU_SOURCE
106  #include <pthread.h>])
107RTEMS_CHECK_FUNC([pthread_attr_getaffinity_np],[
108  #define _GNU_SOURCE
109  #include <pthread.h>])
110RTEMS_CHECK_FUNC([pthread_setaffinity_np],[
111  #define _GNU_SOURCE
112  #include <pthread.h>])
113RTEMS_CHECK_FUNC([pthread_getaffinity_np],[
114  #define _GNU_SOURCE
115  #include <pthread.h>])
116RTEMS_CHECK_FUNC([pthread_getattr_np],[
117  #define _GNU_SOURCE
118  #include <pthread.h>])
119AC_CHECK_HEADERS([sys/cpuset.h])
120
121# This was added to newlib in August 2014 to improve conformance.
122# Disable use of internal definition if it is present.
123RTEMS_CHECK_FUNC([sigaltstack],[
124  #define _GNU_SOURCE
125  #include <signal.h>])
126
127# Mandated by POSIX, not declared in some versions of newlib.
128AC_CHECK_DECLS([getrusage],,,[#include sys/resource.h])
129
130# Newlib's unix/ directory
131AC_CHECK_FUNCS([ttyname getcwd])
132# </FIXME>
133
134# Check if the installed toolchain provides these headers
135# and error out if not.
136AC_CHECK_HEADERS([tar.h errno.h sched.h sys/cdefs.h sys/queue.h],,
137  [rtems_missing_header="$ac_header";break])
138AS_IF([test -n "$rtems_missing_header"],
139  AC_MSG_ERROR([Missing required header $rtems_missing_header])])
140
141AC_CHECK_HEADERS([semaphore.h])
142AM_CONDITIONAL([HAVE_SEMAPHORE_H],[test x"$ac_cv_header_semaphore_h" = x"yes"])
143
144AC_CHECK_HEADERS([threads.h])
145AM_CONDITIONAL([HAVE_THREADS_H],[test x"$ac_cv_header_threads_h" = x"yes"])
146
147## error out if libc doesn't provide stdint.h
148AS_IF([test x"${ac_cv_header_stdint_h}" != xyes],
149[AC_MSG_ERROR([Required header stdint.h not found])])
150
151## error out if libc doesn't provide inttypes.h
152AS_IF([test x"${ac_cv_header_inttypes_h}" != xyes],
153[AC_MSG_ERROR([Required header inttypes.h not found])])
154
155AC_HEADER_STDBOOL
156AS_IF([test x"${ac_cv_header_stdbool_h}" != xyes],
157[AC_MSG_ERROR([No sufficient stdbool.h found])])
158
159AC_CHECK_TYPES([ uint8_t,  int8_t])
160AC_CHECK_TYPES([uint16_t, int16_t])
161AC_CHECK_TYPES([uint32_t, int32_t])
162AC_CHECK_TYPES([uint64_t, int64_t])
163AC_CHECK_TYPES([uintmax_t, intmax_t])
164AC_CHECK_TYPES([uintptr_t, intptr_t])
165
166# Some toolchain sanity checks and diagnostics
167RTEMS_CHECK_GCC_SANITY
168
169# These are conditionally defined by the toolchain
170# FIXME: we should either conditionally compile those parts in
171# RTEMS depending on them, or abort - For now, simply check.
172AC_CHECK_HEADER([pthread.h],[
173  AC_CHECK_TYPES([pthread_rwlock_t])
174  AC_CHECK_TYPES([pthread_barrier_t])
175  AC_CHECK_TYPES([pthread_spinlock_t])
176  AC_CHECK_TYPES([struct _pthread_cleanup_context],[],[AC_MSG_ERROR([struct _pthread_cleanup_context in <pthread.h> is mandatory])],[#include <pthread.h>])
177])
178
179AC_CHECK_HEADER([signal.h],[
180  AC_CHECK_TYPES([sighandler_t])
181])
182
183RTEMS_CHECK_MULTIPROCESSING
184RTEMS_CHECK_POSIX_API
185RTEMS_CHECK_NETWORKING
186RTEMS_CHECK_SMP
187if test "${RTEMS_HAS_SMP}" = "yes"; then
188  AC_CHECK_HEADERS([stdatomic.h],[],[AC_MSG_ERROR([<stdatomic.h> is required for SMP support])])
189fi
190
191rtems_major=`echo _RTEMS_VERSION | sed "s/\..*//"`
192rtems_minor=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/\..*//"`
193rtems_revision=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/[[0-9]][[0-9]]*\.//;s/\..*//"`
194
195_RTEMS_CPUOPT_INIT
196
197RTEMS_CPUOPT([RTEMS_DEBUG],
198  [test x"${enable_rtems_debug}" = x"yes"],
199  [1],
200  [if RTEMS_DEBUG is enabled])
201
202RTEMS_CPUOPT([RTEMS_MULTIPROCESSING],
203  [test x"$enable_multiprocessing" = xyes],
204  [1],
205  [if multiprocessing is enabled])
206
207RTEMS_CPUOPT([RTEMS_NEWLIB],
208  [test x"$RTEMS_USE_NEWLIB" = xyes],
209  [1],
210  [if using newlib])
211
212RTEMS_CPUOPT([RTEMS_POSIX_API],
213  [test x"$rtems_cv_HAS_POSIX_API" = xyes],
214  [1],
215  [if posix api is supported])
216
217RTEMS_CPUOPT([RTEMS_SMP],
218  [test x"$RTEMS_HAS_SMP" = xyes],
219  [1],
220  [if SMP is enabled])
221
222RTEMS_CPUOPT([RTEMS_PARAVIRT],
223  [test x"$RTEMS_HAS_PARAVIRT" = xyes],
224  [1],
225  [PARAVIRT is enabled])
226
227RTEMS_CPUOPT([RTEMS_PROFILING],
228  [test x"$RTEMS_HAS_PROFILING" = xyes],
229  [1],
230  [if profiling is enabled])
231
232RTEMS_CPUOPT([RTEMS_NETWORKING],
233  [test x"$rtems_cv_HAS_NETWORKING" = xyes],
234  [1],
235  [if networking is enabled])
236
237RTEMS_CPUOPT([RTEMS_DRVMGR_STARTUP],
238  [test x"$enable_drvmgr" = xyes],
239  [1],
240  [if driver manager api is supported])
241
242RTEMS_CPUOPT([RTEMS_VERSION],
243  [true],
244  ["]_RTEMS_VERSION["],
245  [RTEMS version string])
246
247## Header file differences that need to be known in .h after install
248RTEMS_CPUOPT([__RTEMS_HAVE_SYS_CPUSET_H__],
249  [test x"${ac_cv_header_sys_cpuset_h}" = x"yes"],
250  [1],
251  [indicate if <sys/cpuset.h> is present in toolset])
252
253## Header file differences that need to be known in .h after install
254RTEMS_CPUOPT([__RTEMS_HAVE_DECL_SIGALTSTACK__],
255  [test x"${ac_cv_have_decl_sigaltstack}" = x"yes"],
256  [1],
257  [indicate if <signal.h> in toolset has sigaltstack()])
258
259## This improves both the size and coverage analysis.
260RTEMS_CPUOPT([__RTEMS_DO_NOT_INLINE_THREAD_ENABLE_DISPATCH__],
261  [test x"${RTEMS_DO_NOT_INLINE_THREAD_ENABLE_DISPATCH}" = x"1"],
262  [1],
263  [disable inlining _Thread_Enable_dispatch])
264
265## This improves both the size and coverage analysis.
266RTEMS_CPUOPT([__RTEMS_DO_NOT_INLINE_CORE_MUTEX_SEIZE__],
267  [test x"${RTEMS_DO_NOT_INLINE_CORE_MUTEX_SEIZE}" = x"1"],
268  [1],
269  [disable inlining _Thread_Enable_dispatch])
270
271## This gives the same behavior as 4.8 and older
272RTEMS_CPUOPT([__RTEMS_STRICT_ORDER_MUTEX__],
273  [test x"${ENABLE_STRICT_ORDER_MUTEX}" = x"1"],
274  [1],
275  [disable strict order mutex])
276
277## Deactivate ada bindings
278RTEMS_CPUOPT([__RTEMS_ADA__],
279  [test x"${enable_ada}" = x"yes"],
280  [1],
281  [Define to 1 if ada/gnat bindings are built-in])
282
283## Then we propagate a private copy of the value into cpuopts.h
284## so it is always available to the RTEMS header files.
285
286RTEMS_CPUOPT([__RTEMS_MAJOR__],
287  [true],
288  [$rtems_major],
289  [major version portion of an RTEMS release])
290
291RTEMS_CPUOPT([__RTEMS_MINOR__],
292  [true],
293  [$rtems_minor],
294  [minor version portion of an RTEMS release])
295
296RTEMS_CPUOPT([__RTEMS_REVISION__],
297  [true],
298  [$rtems_revision],
299  [revision version portion of an RTEMS release])
300
301_RTEMS_CPUOPT_FINI
302
303AC_ENABLE_MULTILIB([Makefile],[..])
304
305# libmisc/shell/* wants to assign file descriptors to stdio file descriptors.
306AC_MSG_CHECKING([for assignable stdio])
307AC_COMPILE_IFELSE(
308  [AC_LANG_PROGRAM(
309    [#include <stdio.h>],
310    [stdin = fopen("/tmp", "r")])],
311  [HAVE_ASSIGNABLE_STDIO=yes],
312  [HAVE_ASSIGNABLE_STDIO=no])
313AC_MSG_RESULT([$HAVE_ASSIGNABLE_STDIO])
314
315# libmisc/serdbg exploits weak symbols
316RTEMS_CHECK_GCC_WEAK
317
318# FIXME: These checks are only in here to provide
319# configuration-time diagnostics and are not really used.
320AC_CHECK_DECLS([_POSIX_LOGIN_NAME_MAX],,,[#include <limits.h>])
321AC_CHECK_DECLS([CHAR_BIT],,,[#include <limits.h>])
322
323# FIXME: We should get rid of this.
324# So far, only used in libfs/src/nfsclient/src/dirutils.c
325AC_CHECK_SIZEOF([mode_t])
326AC_CHECK_SIZEOF([off_t])
327
328# FIXME: We should get rid of this. It's a cludge.
329AC_CHECK_SIZEOF([time_t])
330
331AC_CHECK_SIZEOF([size_t])
332
333# FIXME: Mandatory in SUSv4, optional in SUSv3.
334#   Not implemented in GCC/newlib, so far.
335AC_CHECK_DECLS([WORD_BIT],,,[#include <limits.h>])
336AC_CHECK_DECLS([LONG_BIT],,,[#include <limits.h>])
337
338## BSD-ism, excluded from POSIX, but available on most platforms
339AC_CHECK_DECLS([sbrk],,,[#include <unistd.h>])
340AC_CHECK_DECLS([rcmd],,,[#include <unistd.h>])
341
342## Check if libc provides BSD's strlcpy/strlcat
343AC_CHECK_FUNCS(strlcpy strlcat)
344
345## Check if libc provides decl of utime
346## FIXME: utime has been deprecated in SUSv4.
347##        and is likely to be removed in future versions.
348## FIXME (BUG in newlib): SUSv4 saids including <utime.h> should be sufficient.
349AC_CHECK_DECLS([utime],,,[#include <sys/types.h>
350#include <utime.h>])
351## Check if libc provides decl of utimes
352AC_CHECK_DECLS([utimes],,,[#include <sys/time.h>])
353
354# ... far too many conditionals ...
355AM_CONDITIONAL(LIBRPC,[test x"$rtems_cv_HAS_NETWORKING" = x"yes"])
356AM_CONDITIONAL(NEWLIB,test x"$RTEMS_USE_NEWLIB" = x"yes")
357
358AM_CONDITIONAL(HAS_MP,test x"$enable_multiprocessing" = x"yes" )
359AM_CONDITIONAL(HAS_SMP,[test "$RTEMS_HAS_SMP" = "yes"])
360
361AM_CONDITIONAL(HAS_PTHREADS,test x"$rtems_cv_HAS_POSIX_API" = x"yes")
362AM_CONDITIONAL(LIBNETWORKING,test x"$rtems_cv_HAS_NETWORKING" = x"yes")
363
364AM_CONDITIONAL([LIBSHELL],[test x"$HAVE_ASSIGNABLE_STDIO" = x"yes"])
365AM_CONDITIONAL([LIBSERDBG],[test x"$rtems_cv_cc_attribute_weak" = x"yes"])
366AM_CONDITIONAL([LIBGNAT],[test x"$rtems_cv_HAS_POSIX_API" = x"yes" \
367&& test x"$enable_ada" = x"yes"])
368
369AM_CONDITIONAL([LIBUTF8PROC],[test $ac_cv_sizeof_size_t -gt 2])
370
371AM_CONDITIONAL([LIBDOSFS],[dnl
372test x"$ac_cv_type_uint8_t" = xyes \
373&& test x"$ac_cv_type_uint16_t" = xyes])
374
375AC_CONFIG_HEADER(config.h)
376
377## These are needed by the NFS Client
378AC_CHECK_PROG(RPCGEN,rpcgen,rpcgen)
379AM_CONDITIONAL([RPCTOOLS],[test "$RPCGEN" = rpcgen \
380&& test -n "$AWK" \
381&& test "$enable_rpcgen" = yes])
382
383# Filter dynamic loading to only build for architectures that have
384# reloc backends
385AC_MSG_CHECKING([whether CPU supports libdl])
386case $RTEMS_CPU in
387  arm | i386 | m32r | m68k | mips | \
388  moxie | powerpc | sparc)
389   HAVE_LIBDL=yes ;;
390  # bfin has an issue to resolve with libdl. See ticket #2252
391  bfin)
392   HAVE_LIBDL=no ;;
393  # h8300 has an issue to resolve with libdl. See ticket #2284
394  h8300)
395   HAVE_LIBDL=no ;;
396  # lm32 has an issue to resolve with libdl. See ticket #2283
397  lm32)
398   HAVE_LIBDL=no ;;
399  # v850 has an issue to resolve with libdl. See ticket #2260
400  v850)
401   HAVE_LIBDL=no ;;
402  *)
403   HAVE_LIBDL=no ;;
404esac
405AM_CONDITIONAL(LIBDL,[test x"$HAVE_LIBDL" = x"yes"])
406AC_MSG_RESULT([$HAVE_LIBDL])
407
408AC_MSG_CHECKING([whether CPU supports SHA])
409case $RTEMS_CPU in
410  m32c)
411   HAVE_SHA=no ;;
412  *)
413   HAVE_SHA=yes ;;
414esac
415AM_CONDITIONAL(SHA,[test x"$HAVE_SHA" = x"yes"])
416AC_MSG_RESULT([$HAVE_SHA])
417
418# Filter libpci to only build for architectures that have support for it
419AC_MSG_CHECKING([whether CPU supports libpci])
420case $RTEMS_CPU in
421  sparc)
422   HAVE_LIBPCI=yes ;;
423  *)
424   HAVE_LIBPCI=no ;;
425esac
426AM_CONDITIONAL(LIBPCI,[test x"$HAVE_LIBPCI" = x"yes"])
427AC_MSG_RESULT([$HAVE_LIBPCI])
428
429# Filter libdrvmgr to only build for architectures that have support for it
430AC_MSG_CHECKING([whether CPU supports libdrvmgr])
431case $RTEMS_CPU in
432  sparc)
433   HAVE_LIBDRVMGR=yes ;;
434  *)
435   HAVE_LIBDRVMGR=no ;;
436esac
437AM_CONDITIONAL(LIBDRVMGR,[test x"$HAVE_LIBDRVMGR" = x"yes"])
438AC_MSG_RESULT([$HAVE_LIBDRVMGR])
439
440
441RTEMS_AMPOLISH3
442
443# Explicitly list all Makefiles here
444AC_CONFIG_FILES([
445Doxyfile
446Makefile
447dev/Makefile
448dtc/libfdt/Makefile
449rtems/Makefile
450sapi/Makefile
451score/Makefile
452score/cpu/Makefile
453score/cpu/arm/Makefile
454score/cpu/bfin/Makefile
455score/cpu/avr/Makefile
456score/cpu/epiphany/Makefile
457score/cpu/h8300/Makefile
458score/cpu/i386/Makefile
459score/cpu/lm32/Makefile
460score/cpu/m68k/Makefile
461score/cpu/m32c/Makefile
462score/cpu/m32r/Makefile
463score/cpu/mips/Makefile
464score/cpu/moxie/Makefile
465score/cpu/nios2/Makefile
466score/cpu/or1k/Makefile
467score/cpu/powerpc/Makefile
468score/cpu/sh/Makefile
469score/cpu/sparc/Makefile
470score/cpu/sparc64/Makefile
471score/cpu/v850/Makefile
472score/cpu/no_cpu/Makefile
473posix/Makefile
474libblock/Makefile
475libdrvmgr/Makefile
476libfs/Makefile
477libfs/src/nfsclient/Makefile
478libgnat/Makefile
479libcrypt/Makefile
480libcsupport/Makefile
481libnetworking/Makefile
482libpci/Makefile
483librpc/Makefile
484libmisc/Makefile
485libi2c/Makefile
486libmd/Makefile
487libdl/Makefile
488libstdthreads/Makefile
489zlib/Makefile
490ftpd/Makefile
491telnetd/Makefile
492pppd/Makefile
493mghttpd/Makefile
494wrapup/Makefile])
495
496AC_CONFIG_COMMANDS([preinstall-stamp],
497[test -z "$with_multisubdir" && ${MAKE} preinstall-stamp],
498[MAKE=${MAKE}
499with_multisubdir="$with_multisubdir"])
500
501AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.