source: rtems/cpukit/configure.ac @ cfc9573

5
Last change on this file since cfc9573 was 76c03152, checked in by Amaan Cheval <amaan.cheval@…>, on 07/09/18 at 11:12:56

bsp/x86_64: Minimal bootable BSP

Current state:

  • Basic context initialization and switching code.
  • Stubbed console (empty functions).
  • Mostly functional linker script (may need tweaks if we ever want to move away from the large code model (see: CPU_CFLAGS).
  • Fully functional boot, by using FreeBSD's bootloader to load RTEMS's ELF for UEFI-awareness.

In short, the current state with this commit lets us boot, go through the system
initialization functions, and then call user application's Init task too.

Updates #2898.
  • Property mode set to 100644
File size: 14.9 KB
Line 
1## Process this file with autoconf to produce a configure script.
2
3AC_PREREQ([2.69])
4AC_INIT([rtems-cpukit],[_RTEMS_VERSION],[https://devel.rtems.org/newticket])
5AC_CONFIG_SRCDIR([score])
6RTEMS_TOP([..],[])
7RTEMS_SOURCE_TOP
8RTEMS_BUILD_TOP
9
10RTEMS_CANONICAL_TARGET_CPU
11
12AM_INIT_AUTOMAKE([no-define nostdinc subdir-objects foreign 1.12.2])
13AM_MAINTAINER_MODE
14
15RTEMS_ENABLE_MULTIPROCESSING
16RTEMS_ENABLE_POSIX
17RTEMS_ENABLE_RTEMS_DEBUG
18RTEMS_ENABLE_NETWORKING
19RTEMS_ENABLE_PARAVIRT
20RTEMS_ENABLE_PROFILING
21RTEMS_ENABLE_DRVMGR
22
23RTEMS_ENV_RTEMSCPU
24RTEMS_CHECK_RTEMS_DEBUG
25
26AC_DEFUN([RTEMS_TOOL_CHAIN_ERROR],AC_MSG_ERROR([please update your tool chain via the RSB <https://docs.rtems.org/branches/master/rsb/quick-start.html>]))
27
28# Is this a supported CPU?
29AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
30if test -d "$srcdir/score/cpu/$RTEMS_CPU"; then
31  AC_MSG_RESULT(yes)
32else
33  AC_MSG_ERROR(no)
34fi
35
36RTEMS_PROG_CC_FOR_TARGET
37AM_PROG_CC_C_O
38RTEMS_CANONICALIZE_TOOLS
39RTEMS_PROG_CCAS
40AC_PROG_RANLIB
41
42RTEMS_CHECK_NEWLIB
43
44# BSD-isms, used throughout the sources
45# Not really used by this configure script
46# FIXME: They should be eliminated if possible.
47AC_CHECK_FUNCS([strsep strcasecmp snprintf])
48AC_CHECK_FUNCS([strdup strndup strncasecmp])
49AC_CHECK_FUNCS([bcopy bcmp])
50AC_CHECK_FUNCS([isascii fileno])
51
52# <FIXME>
53#   Check for functions supplied by newlib >= 1.17.0
54# Newlib's posix/ directory
55AC_CHECK_FUNCS([readdir_r isatty])
56AC_CHECK_FUNCS([creat \
57  opendir closedir readdir rewinddir scandir seekdir \
58  sleep \
59  telldir \
60  usleep],,
61  [RTEMS_TOOL_CHAIN_ERROR])
62AC_CHECK_FUNCS([__assert])
63AC_CHECK_FUNCS([execl execlp execle execv execvp execve])
64AC_CHECK_FUNCS([regcomp regexec regerror regfree])
65
66# Mandated by POSIX, decls not present in some versions of newlib
67AC_CHECK_DECLS([flockfile],[AC_CHECK_FUNCS([flockfile])],,[#include <stdio.h>])
68AC_CHECK_DECLS([funlockfile],[AC_CHECK_FUNCS([funlockfile])],,[#include <stdio.h>])
69AC_CHECK_DECLS([ftrylockfile],[AC_CHECK_FUNCS([ftrylockfile])],,[#include <stdio.h>])
70
71# Newlib proprietary
72AC_CHECK_MEMBER([struct _Thread_queue_Queue._name],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <sys/lock.h>])
73
74# Mandated by POSIX, older newlibs bogusly provided CLOCK_PROCESS_CPUTIME+CLOCK_THREAD_CPUTIME
75AC_CHECK_DECL([CLOCK_PROCESS_CPUTIME_ID],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <time.h>])
76AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <time.h>])
77
78# Mandated by POSIX, decls not present in some versions of newlib,
79# some versions stubbed in newlib's rtems crt0
80RTEMS_CHECK_FUNC([seteuid],[#include <unistd.h>])
81RTEMS_CHECK_FUNC([geteuid],[#include <unistd.h>])
82RTEMS_CHECK_FUNC([setegid],[#include <unistd.h>])
83RTEMS_CHECK_FUNC([getegid],[#include <unistd.h>])
84RTEMS_CHECK_FUNC([setuid],[#include <unistd.h>])
85RTEMS_CHECK_FUNC([getuid],[#include <unistd.h>])
86RTEMS_CHECK_FUNC([setgid],[#include <unistd.h>])
87RTEMS_CHECK_FUNC([getgid],[#include <unistd.h>])
88RTEMS_CHECK_FUNC([setsid],[#include <unistd.h>])
89RTEMS_CHECK_FUNC([getsid],[#include <unistd.h>])
90RTEMS_CHECK_FUNC([setpgid],[#include <unistd.h>])
91RTEMS_CHECK_FUNC([getpgid],[#include <unistd.h>])
92RTEMS_CHECK_FUNC([setpgrp],[#include <unistd.h>])
93RTEMS_CHECK_FUNC([getpgrp],[#include <unistd.h>])
94
95# pthread-functions not declared in some versions of newlib.
96RTEMS_CHECK_FUNC([pthread_attr_getguardsize],[#include <pthread.h>])
97RTEMS_CHECK_FUNC([pthread_attr_setguardsize],[#include <pthread.h>])
98RTEMS_CHECK_FUNC([pthread_attr_setstack],[#include <pthread.h>])
99RTEMS_CHECK_FUNC([pthread_attr_getstack],[#include <pthread.h>])
100
101# These are SMP related and were added to newlib by RTEMS.
102RTEMS_CHECK_FUNC([pthread_attr_setaffinity_np],[
103  #define _GNU_SOURCE
104  #include <pthread.h>])
105RTEMS_CHECK_FUNC([pthread_attr_getaffinity_np],[
106  #define _GNU_SOURCE
107  #include <pthread.h>])
108RTEMS_CHECK_FUNC([pthread_setaffinity_np],[
109  #define _GNU_SOURCE
110  #include <pthread.h>])
111RTEMS_CHECK_FUNC([pthread_getaffinity_np],[
112  #define _GNU_SOURCE
113  #include <pthread.h>])
114RTEMS_CHECK_FUNC([pthread_getattr_np],[
115  #define _GNU_SOURCE
116  #include <pthread.h>])
117
118AC_LANG_PUSH(C)
119AC_MSG_CHECKING([for pthread_mutex_getprioceiling(const pthread_mutex_t *, ...)])
120AC_COMPILE_IFELSE([AC_LANG_SOURCE([
121#include <pthread.h>
122int pthread_mutex_getprioceiling(const pthread_mutex_t *__restrict, int *);
123])],[
124AC_MSG_RESULT([yes])
125AC_DEFINE(HAVE_PTHREAD_MUTEX_GETCEILING_CONST, [], [pthread_mutex_getprioceiling(const pthread_mutex_t *, ...)])
126],[
127AC_MSG_RESULT([no])
128])
129AC_MSG_CHECKING([for pthread_setschedparam(..., const struct sched_param *)])
130AC_COMPILE_IFELSE([AC_LANG_SOURCE([
131#include <pthread.h>
132int pthread_setschedparam(pthread_t, int, const struct sched_param *);
133])],[
134AC_MSG_RESULT([yes])
135AC_DEFINE(HAVE_PTHREAD_SETSCHEDPARAM_CONST, [], [pthread_setschedparam(..., const struct sched_param *)])
136],[
137AC_MSG_RESULT([no])
138])
139AC_LANG_POP(C)
140
141# Mandated by POSIX, not declared in some versions of newlib.
142AC_CHECK_DECLS([getrusage],,,[#include sys/resource.h])
143
144# Newlib's unix/ directory
145AC_CHECK_FUNCS([ttyname getcwd])
146# </FIXME>
147
148# Check if the installed toolchain provides these headers
149# and error out if not.
150AC_CHECK_HEADERS([errno.h sched.h semaphore.h sys/cdefs.h sys/queue.h tar.h threads.h],,
151  [RTEMS_TOOL_CHAIN_ERROR])
152
153## error out if libc doesn't provide stdint.h
154AS_IF([test x"${ac_cv_header_stdint_h}" != xyes],
155[RTEMS_TOOL_CHAIN_ERROR])
156
157## error out if libc doesn't provide inttypes.h
158AS_IF([test x"${ac_cv_header_inttypes_h}" != xyes],
159[RTEMS_TOOL_CHAIN_ERROR])
160
161AC_HEADER_STDBOOL
162AS_IF([test x"${ac_cv_header_stdbool_h}" != xyes],
163[RTEMS_TOOL_CHAIN_ERROR])
164
165AC_CHECK_TYPES([ uint8_t,  int8_t])
166AC_CHECK_TYPES([uint16_t, int16_t])
167AC_CHECK_TYPES([uint32_t, int32_t])
168AC_CHECK_TYPES([uint64_t, int64_t])
169AC_CHECK_TYPES([uintmax_t, intmax_t])
170AC_CHECK_TYPES([uintptr_t, intptr_t])
171
172# Some toolchain sanity checks and diagnostics
173RTEMS_CHECK_GCC_SANITY
174
175# These are conditionally defined by the toolchain
176# FIXME: we should either conditionally compile those parts in
177# RTEMS depending on them, or abort - For now, simply check.
178AC_CHECK_HEADER([pthread.h],[
179  AC_CHECK_TYPES([pthread_rwlock_t])
180  AC_CHECK_TYPES([pthread_barrier_t])
181  AC_CHECK_TYPES([pthread_spinlock_t])
182  AC_CHECK_TYPES([struct _pthread_cleanup_context],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <pthread.h>])
183  AC_CHECK_TYPES([struct _Priority_Node],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <pthread.h>])
184])
185
186AC_CHECK_HEADER([signal.h],[
187  AC_CHECK_TYPES([sighandler_t])
188])
189
190if test x"$RTEMS_USE_NEWLIB" = xyes ; then
191  AC_CHECK_DECLS([__getreent],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <sys/reent.h>])
192fi
193
194RTEMS_CHECK_MULTIPROCESSING
195RTEMS_CHECK_POSIX_API
196RTEMS_CHECK_NETWORKING
197RTEMS_CHECK_SMP
198if test "${RTEMS_HAS_SMP}" = "yes"; then
199  AC_CHECK_HEADERS([stdatomic.h],[],[RTEMS_TOOL_CHAIN_ERROR])
200fi
201
202rtems_major=`echo _RTEMS_VERSION | sed "s/\..*//"`
203rtems_minor=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/\..*//"`
204rtems_revision=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/[[0-9]][[0-9]]*\.//;s/\..*//"`
205
206_RTEMS_CPUOPT_INIT
207
208RTEMS_CPUOPT([RTEMS_DEBUG],
209  [test x"${enable_rtems_debug}" = x"yes"],
210  [1],
211  [if RTEMS_DEBUG is enabled])
212
213RTEMS_CPUOPT([RTEMS_MULTIPROCESSING],
214  [test x"$enable_multiprocessing" = xyes],
215  [1],
216  [if multiprocessing is enabled])
217
218RTEMS_CPUOPT([RTEMS_NEWLIB],
219  [test x"$RTEMS_USE_NEWLIB" = xyes],
220  [1],
221  [if using newlib])
222
223RTEMS_CPUOPT([RTEMS_POSIX_API],
224  [test x"$rtems_cv_HAS_POSIX_API" = xyes],
225  [1],
226  [if posix api is supported])
227
228RTEMS_CPUOPT([RTEMS_SMP],
229  [test x"$RTEMS_HAS_SMP" = xyes],
230  [1],
231  [if SMP is enabled])
232
233RTEMS_CPUOPT([RTEMS_PARAVIRT],
234  [test x"$RTEMS_HAS_PARAVIRT" = xyes],
235  [1],
236  [PARAVIRT is enabled])
237
238RTEMS_CPUOPT([RTEMS_PROFILING],
239  [test x"$RTEMS_HAS_PROFILING" = xyes],
240  [1],
241  [if profiling is enabled])
242
243RTEMS_CPUOPT([RTEMS_NETWORKING],
244  [test x"$rtems_cv_HAS_NETWORKING" = xyes],
245  [1],
246  [if networking is enabled])
247
248RTEMS_CPUOPT([RTEMS_DRVMGR_STARTUP],
249  [test x"$enable_drvmgr" = xyes],
250  [1],
251  [if driver manager api is supported])
252
253RTEMS_CPUOPT([RTEMS_VERSION],
254  [true],
255  ["]_RTEMS_VERSION["],
256  [RTEMS version string])
257
258## Header file differences that need to be known in .h after install
259
260## Deactivate ada bindings
261RTEMS_CPUOPT([__RTEMS_ADA__],
262  [test x"${enable_ada}" = x"yes"],
263  [1],
264  [Define to 1 if ada/gnat bindings are built-in])
265
266# These are used to provide <rtems/inttypes.h
267AC_CHECK_SIZEOF([mode_t])
268AC_CHECK_SIZEOF([off_t])
269AC_CHECK_SIZEOF([time_t])
270AC_CHECK_SIZEOF([size_t])
271AC_CHECK_SIZEOF([blksize_t])
272AC_CHECK_SIZEOF([blkcnt_t])
273
274## Provide sizeof(mode_t) information via cpuopts.h
275RTEMS_CPUOPT([__RTEMS_SIZEOF_MODE_T__],
276  [true],
277  [${ac_cv_sizeof_mode_t}],
278  [sizeof(mode_t)])
279
280## Provide sizeof(off_t) information via cpuopts.h
281RTEMS_CPUOPT([__RTEMS_SIZEOF_OFF_T__],
282  [true],
283  [${ac_cv_sizeof_off_t}],
284  [sizeof(off_t)])
285
286## Provide sizeof(time_t) information via cpuopts.h
287RTEMS_CPUOPT([__RTEMS_SIZEOF_TIME_T__],
288  [true],
289  [${ac_cv_sizeof_time_t}],
290  [sizeof(time_t)])
291
292## Provide sizeof(blksize_t) information via cpuopts.h
293RTEMS_CPUOPT([__RTEMS_SIZEOF_BLKSIZE_T__],
294  [true],
295  [${ac_cv_sizeof_blksize_t}],
296  [sizeof(blksize_t)])
297
298## Provide sizeof(blkcnt_t) information via cpuopts.h
299RTEMS_CPUOPT([__RTEMS_SIZEOF_BLKCNT_T__],
300  [true],
301  [${ac_cv_sizeof_blkcnt_t}],
302  [sizeof(blkcnt_t)])
303
304## Then we propagate a private copy of the value into cpuopts.h
305## so it is always available to the RTEMS header files.
306
307RTEMS_CPUOPT([__RTEMS_MAJOR__],
308  [true],
309  [$rtems_major],
310  [major version portion of an RTEMS release])
311
312RTEMS_CPUOPT([__RTEMS_MINOR__],
313  [true],
314  [$rtems_minor],
315  [minor version portion of an RTEMS release])
316
317RTEMS_CPUOPT([__RTEMS_REVISION__],
318  [true],
319  [$rtems_revision],
320  [revision version portion of an RTEMS release])
321
322_RTEMS_CPUOPT_FINI
323
324AC_ENABLE_MULTILIB([Makefile],[..])
325
326# libmisc/shell/* wants to assign file descriptors to stdio file descriptors.
327AC_MSG_CHECKING([for assignable stdio])
328AC_COMPILE_IFELSE(
329  [AC_LANG_PROGRAM(
330    [#include <stdio.h>],
331    [stdin = fopen("/tmp", "r")])],
332  [HAVE_ASSIGNABLE_STDIO=yes],
333  [HAVE_ASSIGNABLE_STDIO=no])
334AC_MSG_RESULT([$HAVE_ASSIGNABLE_STDIO])
335
336# libmisc/serdbg exploits weak symbols
337RTEMS_CHECK_GCC_WEAK
338
339# FIXME: These checks are only in here to provide
340# configuration-time diagnostics and are not really used.
341AC_CHECK_DECLS([_POSIX_LOGIN_NAME_MAX],,,[#include <limits.h>])
342AC_CHECK_DECLS([CHAR_BIT],,,[#include <limits.h>])
343
344# FIXME: Mandatory in SUSv4, optional in SUSv3.
345#   Not implemented in GCC/newlib, so far.
346AC_CHECK_DECLS([WORD_BIT],,,[#include <limits.h>])
347AC_CHECK_DECLS([LONG_BIT],,,[#include <limits.h>])
348
349## BSD-ism, excluded from POSIX, but available on most platforms
350AC_CHECK_DECLS([sbrk],,,[#include <unistd.h>])
351AC_CHECK_DECLS([rcmd],,,[#include <unistd.h>])
352
353## Check if libc provides BSD's strlcpy/strlcat
354AC_CHECK_FUNCS(strlcpy strlcat)
355
356## Check if libc provides decl of utime
357## FIXME: utime has been deprecated in SUSv4.
358##        and is likely to be removed in future versions.
359## FIXME (BUG in newlib): SUSv4 saids including <utime.h> should be sufficient.
360AC_CHECK_DECLS([utime],,,[#include <sys/types.h>
361#include <utime.h>])
362## Check if libc provides decl of utimes
363AC_CHECK_DECLS([utimes],,,[#include <sys/time.h>])
364
365# Ensure that Newlib does not provide things now in <machine/_timecounter.h>
366AC_CHECK_DECLS([_Timecounter_Time_second],[RTEMS_TOOL_CHAIN_ERROR],,[#include <sys/time.h>])
367
368# ... far too many conditionals ...
369AM_CONDITIONAL(NEWLIB,test x"$RTEMS_USE_NEWLIB" = x"yes")
370
371AM_CONDITIONAL(HAS_MP,test x"$enable_multiprocessing" = x"yes" )
372AM_CONDITIONAL(HAS_SMP,[test "$RTEMS_HAS_SMP" = "yes"])
373
374AM_CONDITIONAL(HAS_PTHREADS,test x"$rtems_cv_HAS_POSIX_API" = x"yes")
375AM_CONDITIONAL(LIBNETWORKING,test x"$rtems_cv_HAS_NETWORKING" = x"yes")
376
377AM_CONDITIONAL([LIBSHELL],[test x"$HAVE_ASSIGNABLE_STDIO" = x"yes"])
378AM_CONDITIONAL([LIBSERDBG],[test x"$rtems_cv_cc_attribute_weak" = x"yes"])
379AM_CONDITIONAL([LIBGNAT],[test x"$rtems_cv_HAS_POSIX_API" = x"yes" \
380&& test x"$enable_ada" = x"yes"])
381
382AM_CONDITIONAL([LIBUTF8PROC],[test $ac_cv_sizeof_size_t -gt 2])
383
384AM_CONDITIONAL([LIBDOSFS],[dnl
385test x"$ac_cv_type_uint8_t" = xyes \
386&& test x"$ac_cv_type_uint16_t" = xyes])
387
388AC_CONFIG_HEADER(config.h)
389
390## These are needed by the NFS Client
391AC_CHECK_PROG(RPCGEN,rpcgen,rpcgen)
392AM_CONDITIONAL([RPCTOOLS],[test "$RPCGEN" = rpcgen \
393&& test -n "$AWK" \
394&& test "$enable_rpcgen" = yes])
395
396# Filter dynamic loading to only build for architectures that have
397# reloc backends
398AC_MSG_CHECKING([whether CPU supports libdl])
399case $RTEMS_CPU in
400  arm | i386 | m68k | mips | moxie | powerpc | sparc)
401   HAVE_LIBDL=yes ;;
402  # bfin has an issue to resolve with libdl. See ticket #2252
403  bfin)
404   HAVE_LIBDL=no ;;
405  # lm32 has an issue to resolve with libdl. See ticket #2283
406  lm32)
407   HAVE_LIBDL=no ;;
408  # v850 has an issue to resolve with libdl. See ticket #2260
409  v850)
410   HAVE_LIBDL=no ;;
411  *)
412   HAVE_LIBDL=no ;;
413esac
414AM_CONDITIONAL(LIBDL,[test x"$HAVE_LIBDL" = x"yes"])
415AC_MSG_RESULT([$HAVE_LIBDL])
416
417# Filter debugger to only build for architectures that have a target backend
418AC_MSG_CHECKING([whether CPU supports libdebugger])
419case $RTEMS_CPU in
420  arm | i386)
421   HAVE_LIBDEBUGGER=yes ;;
422  *)
423   HAVE_LIBDEBUGGER=no ;;
424esac
425AM_CONDITIONAL(LIBDEBUGGER,[test x"$HAVE_LIBDEBUGGER" = x"yes"])
426AC_MSG_RESULT([$HAVE_LIBDEBUGGER])
427
428AC_MSG_CHECKING([whether CPU supports SHA])
429case $RTEMS_CPU in
430  m32c)
431   HAVE_SHA=no ;;
432  *)
433   HAVE_SHA=yes ;;
434esac
435AM_CONDITIONAL(SHA,[test x"$HAVE_SHA" = x"yes"])
436AC_MSG_RESULT([$HAVE_SHA])
437
438# Filter libpci to only build for architectures that have support for it
439AC_MSG_CHECKING([whether CPU supports libpci])
440case $RTEMS_CPU in
441  sparc)
442   HAVE_LIBPCI=yes ;;
443  *)
444   HAVE_LIBPCI=no ;;
445esac
446AM_CONDITIONAL(LIBPCI,[test x"$HAVE_LIBPCI" = x"yes"])
447AC_MSG_RESULT([$HAVE_LIBPCI])
448
449# Filter libdrvmgr to only build for architectures that have support for it
450AC_MSG_CHECKING([whether CPU supports libdrvmgr])
451case $RTEMS_CPU in
452  sparc)
453   HAVE_LIBDRVMGR=yes ;;
454  *)
455   HAVE_LIBDRVMGR=no ;;
456esac
457AM_CONDITIONAL(LIBDRVMGR,[test x"$HAVE_LIBDRVMGR" = x"yes"])
458AC_MSG_RESULT([$HAVE_LIBDRVMGR])
459
460
461RTEMS_AMPOLISH3
462
463# Explicitly list all Makefiles here
464AC_CONFIG_FILES([
465Doxyfile
466Makefile
467dev/Makefile
468dtc/libfdt/Makefile
469rtems/Makefile
470sapi/Makefile
471score/Makefile
472score/cpu/Makefile
473score/cpu/arm/Makefile
474score/cpu/bfin/Makefile
475score/cpu/epiphany/Makefile
476score/cpu/i386/Makefile
477score/cpu/lm32/Makefile
478score/cpu/m68k/Makefile
479score/cpu/m32c/Makefile
480score/cpu/mips/Makefile
481score/cpu/moxie/Makefile
482score/cpu/nios2/Makefile
483score/cpu/or1k/Makefile
484score/cpu/powerpc/Makefile
485score/cpu/riscv/Makefile
486score/cpu/sh/Makefile
487score/cpu/sparc/Makefile
488score/cpu/sparc64/Makefile
489score/cpu/v850/Makefile
490score/cpu/x86_64/Makefile
491score/cpu/no_cpu/Makefile
492posix/Makefile
493libblock/Makefile
494libdrvmgr/Makefile
495libfs/Makefile
496libfs/src/nfsclient/Makefile
497libgnat/Makefile
498libcrypt/Makefile
499libcsupport/Makefile
500libnetworking/Makefile
501libpci/Makefile
502librpc/Makefile
503libmisc/Makefile
504libi2c/Makefile
505libmd/Makefile
506libdl/Makefile
507libstdthreads/Makefile
508libdebugger/Makefile
509zlib/Makefile
510ftpd/Makefile
511telnetd/Makefile
512pppd/Makefile
513mghttpd/Makefile
514wrapup/Makefile])
515
516AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.