source: rtems/cpukit/configure.ac @ 9483fbf

4.104.114.84.95
Last change on this file since 9483fbf was 9483fbf, checked in by Ralf Corsepius <ralf.corsepius@…>, on 07/08/03 at 08:12:15

2003-07-08 Ralf Corsepius <corsepiu@…>

  • configure.ac: Merge-in libblock/configure.ac.
  • Makefile.am: Add libblock to SUBDIRS.
  • Property mode set to 100644
File size: 4.6 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id$
4
5AC_PREREQ(2.57)
6AC_INIT([rtems-cpukit],[_RTEMS_VERSION],[rtems-bugs@OARcorp.com])
7AC_CONFIG_SRCDIR([score])
8RTEMS_TOP(..)
9
10RTEMS_CANONICAL_TARGET_CPU
11
12AM_INIT_AUTOMAKE([no-define nostdinc foreign 1.7.2])
13AM_MAINTAINER_MODE
14
15RTEMS_ENABLE_MULTILIB
16RTEMS_ENABLE_MULTIPROCESSING
17RTEMS_ENABLE_POSIX
18RTEMS_ENABLE_ITRON
19RTEMS_ENABLE_INLINES
20RTEMS_ENABLE_RTEMS_DEBUG
21RTEMS_ENABLE_NETWORKING
22
23RTEMS_ENV_RTEMSCPU
24RTEMS_CHECK_RTEMS_DEBUG
25
26RTEMS_CHECK_CPU
27RTEMS_CANONICAL_HOST
28
29RTEMS_PROG_CC_FOR_TARGET([-ansi -fasm])
30RTEMS_CANONICALIZE_TOOLS
31AC_PROG_RANLIB
32
33# FIXME: For the moment, no reason to check for ada
34# RTEMS_PROG_GNAT
35
36RTEMS_CHECK_NEWLIB
37
38RTEMS_CHECK_MULTIPROCESSING
39RTEMS_CHECK_POSIX_API
40RTEMS_CHECK_ITRON_API
41RTEMS_CHECK_NETWORKING
42
43# If RTEMS macros are enabled, then use them.  Otherwise, use inlines.
44AS_IF([test "$RTEMS_USE_MACROS" = "yes"],
45  [INLINEdir="macros"],
46  [INLINEdir="inline"])
47AC_SUBST(INLINEdir)
48AM_CONDITIONAL(INLINE,test x"$INLINEdir" = x"inline" )
49AM_CONDITIONAL(MACROS,test x"$INLINEdir" = x"macros" )
50AM_CONDITIONAL(HAS_MP,test x"$HAS_MP" = x"yes" )
51
52AC_DEFINE(RTEMS_VERSION,["rtems-][_RTEMS_VERSION]["],[RTEMS version string])
53
54AM_CONDITIONAL(HAS_POSIX,test x"$HAS_POSIX_API" = x"yes")
55AM_CONDITIONAL(HAS_ITRON,test x"$HAS_ITRON_API" = x"yes")
56AM_CONDITIONAL(HAS_NETWORKING,test x"$HAS_NETWORKING" = x"yes")
57
58AS_IF([test x"$HAS_POSIX_API" = x"yes"],
59  [AC_CONFIG_SUBDIRS([posix])]
60)
61AS_IF([test x"$HAS_ITRON_API" = x"yes"],
62  [AC_CONFIG_SUBDIRS(itron)]
63)
64RTEMS_CPU_SUBDIRS([score/cpu])
65# FIXME: All ports should have a libscorecpu.a - But the powerpc doesn't!
66AM_CONDITIONAL([LIBSCORECPU],
67[test -f "${srcdir}/score/cpu/${RTEMS_CPU}/cpu.c"])
68
69AC_CONFIG_SUBDIRS([libcsupport])
70AC_CONFIG_SUBDIRS([libfs])
71AS_IF([test x"$HAS_NETWORKING" = x"yes"],[
72  AC_CONFIG_SUBDIRS(libnetworking)
73## FIXME: Should better use a feature-based test
74AC_MSG_CHECKING([whether CPU supports librpc])
75  case "$RTEMS_CPU" in
76  c4x )  LIBRPC=no;;
77  or32 ) LIBRPC=no;;
78  * )    LIBRPC=yes;;
79  esac
80AC_MSG_RESULT([$LIBRPC])
81  AS_IF([test "$LIBRPC" = "yes"],
82    [AC_CONFIG_SUBDIRS([librpc])
83  ])
84])
85AM_CONDITIONAL(LIBRPC,[test "$LIBRPC" = "yes"])
86
87AC_ARG_ENABLE([ada],
88[AC_HELP_STRING([--enable-ada],[enable ada support])],
89[case "${enable_ada}" in
90  yes) ;;
91  no) ;;
92  *)  AC_MSG_ERROR([bad value ${enable_ada} for --enable-ada]) ;;
93esac],[enable_ada=no])
94
95RTEMS_DEFINE_POSIX_API
96RTEMS_DEFINE_ITRON_API
97RTEMS_DEFINE_MULTIPROCESSING
98
99# HACK: We should use a feature-based configuration.
100AS_IF([test x"${RTEMS_CPU}" = x"unix"],[
101  AC_DEFINE_UNQUOTED([RTEMS_UNIX],[1],[to indicate RTEMS unix])
102# HACK: silently accept --enable-unixlib
103  test -n "${enable_unixlib}" || enable_unixlib="yes"
104])
105
106AM_CONDITIONAL(UNIX,[test x"${RTEMS_CPU}" = x"unix"])
107
108AS_IF([test x"${enable_unixlib}" = x"yes"],
109  [AC_DEFINE_UNQUOTED([RTEMS_UNIXLIB],[1],
110    [to indicate RTEMS using RTEMS's unixlib])]
111)
112
113
114AM_CONFIG_HEADER([score/include/rtems/score/cpuopts-tmp.h],[
115echo "/* target cpu dependent options file */"         >$tmp/config.h
116echo "/* automatically generated -- DO NOT EDIT!! */" >>$tmp/config.h
117echo                                                  >>$tmp/config.h
118echo "#ifndef __CPU_OPTIONS_h"                        >>$tmp/config.h
119echo "#define __CPU_OPTIONS_h"                        >>$tmp/config.h
120echo                                                  >>$tmp/config.h
121sed -e '/.*PACKAGE.*/d' score/include/rtems/score/cpuopts-tmp.h >> $tmp/config.h
122echo                                                  >>$tmp/config.h
123echo "#endif"                                         >>$tmp/config.h
124AS_IF([cmp -s score/include/rtems/score/cpuopts.h $tmp/config.h 2>/dev/null],
125  [AC_MSG_NOTICE([score/include/rtems/score/cpuopts.h is unchanged])
126   rm -f $tmp/config.h],
127  [AC_MSG_NOTICE([creating score/include/rtems/score/cpuopts.h])
128   rm -f score/include/rtems/score/cpuopts.h
129   mv $tmp/config.h score/include/rtems/score/cpuopts.h])
130])
131
132AC_ENABLE_MULTILIB([Makefile],[..])
133
134## HACK: Add a define to cpuopts.h to indicate using multilibs
135## Can be applied to produce compiler errors if using
136## multilib-incompatible settings somewhere else (eg. bspopts.h).
137AS_IF([test x"${enable_multilib}" = x"yes"],[
138  AC_DEFINE_UNQUOTED([RTEMS_MULTILIBS],[1],[using multilib'ed RTEMS])
139])
140
141AC_CONFIG_SUBDIRS([libmisc])
142
143AM_CONDITIONAL(RTEMS_ADA,[test x"$enable_ada" = x"yes" \
144  && test x"$HAS_POSIX_API" = x"yes"])
145
146# Explicitly list all Makefiles here
147AC_CONFIG_FILES([Makefile
148include/Makefile
149rtems/Makefile
150sapi/Makefile
151score/Makefile
152score/cpu/Makefile
153])
154
155AC_CONFIG_FILES([libblock/Makefile])
156AC_CONFIG_FILES([ada/Makefile])
157AC_CONFIG_FILES([wrapup/Makefile])
158
159AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.