source: rtems/cpukit/configure.ac @ 8280caa4

4.104.114.84.95
Last change on this file since 8280caa4 was 8280caa4, checked in by Ralf Corsepius <ralf.corsepius@…>, on 10/25/05 at 16:14:23

Add telnetd.

  • Property mode set to 100644
File size: 7.9 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id$
4
5AC_PREREQ(2.59)
6AC_INIT([rtems-cpukit],[_RTEMS_VERSION],[rtems-bugs@rtems.com])
7AC_CONFIG_SRCDIR([score])
8RTEMS_TOP([..],[])
9
10RTEMS_CANONICAL_TARGET_CPU
11
12AM_INIT_AUTOMAKE([no-define nostdinc subdir-objects foreign 1.9])
13AM_MAINTAINER_MODE
14
15RTEMS_ENABLE_MULTILIB
16RTEMS_ENABLE_MULTIPROCESSING
17RTEMS_ENABLE_POSIX
18RTEMS_ENABLE_ITRON
19RTEMS_ENABLE_INLINES
20RTEMS_ENABLE_RTEMS_DEBUG
21RTEMS_ENABLE_NETWORKING
22
23RTEMS_ENV_RTEMSCPU
24RTEMS_CHECK_RTEMS_DEBUG
25
26# Is this a supported CPU?
27AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
28if test -d "$srcdir/score/cpu/$RTEMS_CPU"; then
29  AC_MSG_RESULT(yes)
30else
31  AC_MSG_ERROR(no)
32fi
33
34RTEMS_PROG_CC_FOR_TARGET([-fasm])
35RTEMS_PROG_CCAS
36RTEMS_CANONICALIZE_TOOLS
37AM_PROG_CC_C_O
38AC_PROG_RANLIB
39
40RTEMS_CHECK_NEWLIB
41
42RTEMS_CHECK_MULTIPROCESSING
43RTEMS_CHECK_POSIX_API
44RTEMS_CHECK_ITRON_API
45RTEMS_CHECK_NETWORKING
46
47AS_IF([test x"$HAS_NETWORKING" = x"yes"],[
48## FIXME: Should better use a feature-based test
49AC_MSG_CHECKING([whether CPU supports librpc])
50  case "$RTEMS_CPU" in
51  c4x )  LIBRPC=no;;
52  * )    LIBRPC=yes;;
53  esac
54AC_MSG_RESULT([$LIBRPC])
55])
56
57AC_ARG_ENABLE([deprecated],
58[AS_HELP_STRING(--enable-deprecated,allow using deprecated files)],
59[case "${enable_deprecated}" in
60  yes) ;;
61  no) ;;
62  *) enable_deprecated=no ;;
63esac],[enable_deprecated=no])
64AM_CONDITIONAL([DEPRECATED],[test "$enable_deprecated" = "yes"])
65
66# HACK: We should use a feature-based configuration.
67AS_IF([test x"${RTEMS_CPU}" = x"unix"],[
68# HACK: silently accept --enable-unixlib
69  test -n "${enable_unixlib}" || enable_unixlib="yes"
70])
71
72# BSD-isms, used throughout the sources
73# Not really used by this configure script
74# FIXME: They should be eliminated if possible.
75AC_CHECK_FUNCS([strsep strcasecmp snprintf])
76AC_CHECK_FUNCS([bcopy bcmp])
77AC_CHECK_FUNCS([isascii fileno])
78
79## Check if the installed toolchain has these headers
80AC_CHECK_HEADER([stdint.h])
81AC_CHECK_HEADER([inttypes.h])
82AC_CHECK_HEADER([tar.h])
83
84## BSD-ism, should not be used in RTEMS,
85## nevertheless it still is.
86AC_CHECK_HEADER([sys/errno.h],[],
87  [AC_MSG_ERROR([Missing required header sys/errno.h])])
88
89## if using newlib, we provide stdint.h and inttypes.h
90AM_CONDITIONAL([RTEMS_PROVIDES_STDINT_H],
91  [test x"${RTEMS_USE_NEWLIB}" = xyes \
92  && test x"${ac_cv_header_stdint_h}" = xno])
93AM_CONDITIONAL([RTEMS_PROVIDES_INTTYPES_H],
94  [test x"${RTEMS_USE_NEWLIB}" = xyes \
95  && test x"${ac_cv_header_inttypes_h}" = xno])
96
97## if using newlib, force using stdint.h
98AS_IF([test x"${RTEMS_USE_NEWLIB}" = xyes],
99[RTEMS_USES_STDINT_H=yes],
100[RTEMS_USES_STDINT_H=$ac_cv_header_stdint_h])
101
102AS_IF([test x"${RTEMS_USE_NEWLIB}" = xyes],
103[RTEMS_USES_TAR_H=yes],
104[RTEMS_USES_TAR_H=$ac_cv_header_tar_h])
105
106AS_IF([test x"${RTEMS_CPU}" = x"unix"],[
107## FIXME: This check is doubtful
108AS_IF([test "$HAS_MP" = "yes"],
109  [RTEMS_CHECK_SYSV_UNIX])
110
111## The code fragment below had been used in tools/cpu/unix/gensize.c.
112## FIXME:
113## * The pad very likely is not necessary.
114AC_CHECK_SIZEOF([CPU_CONTEXT],[],[
115#include <stdio.h>
116#include <setjmp.h>
117
118typedef struct {
119  jmp_buf     regs;
120  int         isr_level;
121  int         pad[4]; /* just in case */
122} CPU_CONTEXT;
123])
124])
125
126cat >>cpuopts.tmp <<\_ACEOF
127/**
128 * @file rtems/score/cpuopts.h
129 */
130/* target cpu dependent options file */
131/* automatically generated -- DO NOT EDIT!! */
132#ifndef _CPU_OPTIONS_H
133#define _CPU_OPTIONS_H
134_ACEOF
135
136RTEMS_CPUOPT([RTEMS_DEBUG],
137  [test x"${enable_rtems_debug}" = x"yes"],
138  [1],
139  [if RTEMS_DEBUG is enabled])
140
141RTEMS_CPUOPT([RTEMS_INLINES],
142  [test x"${enable_rtems_inlines}" = x"yes"],
143  [1],
144  [if using inlines])
145
146RTEMS_CPUOPT([RTEMS_ITRON_API],
147  [test x"$rtems_cv_HAS_ITRON_API" = x"yes"],
148  [1],
149  [if itron api is supported])
150
151RTEMS_CPUOPT([RTEMS_MULTIPROCESSING],
152  [test x"$enable_multiprocessing" = x"yes"],
153  [1],
154  [if multiprocessing is enabled])
155
156RTEMS_CPUOPT([RTEMS_NEWLIB],
157  [test x"$RTEMS_USE_NEWLIB" = x"yes"],
158  [1],
159  [if using newlib])
160
161RTEMS_CPUOPT([RTEMS_POSIX_API],
162  [test x"$rtems_cv_HAS_POSIX_API" = x"yes"],
163  [1],
164  [if posix api is supported])
165
166RTEMS_CPUOPT([RTEMS_UNIX],
167  [test x"$RTEMS_CPU" = x"unix"],
168  [1],
169  [to indicate RTEMS unix])
170
171RTEMS_CPUOPT([RTEMS_UNIXLIB],
172  [test x"${enable_unixlib}" = x"yes"],
173  [1],
174  [to indicate RTEMS using RTEMS's unixlib])
175
176RTEMS_CPUOPT([RTEMS_USES_STDINT_H],
177  [test x"${RTEMS_USES_STDINT_H}" = x"yes"],
178  [1],
179  [if RTEMS uses stdint.h])
180
181RTEMS_CPUOPT([RTEMS_USES_TAR_H],
182  [test x"${RTEMS_USES_TAR_H}" = x"yes"],
183  [1],
184  [if RTEMS uses tar.h])
185
186RTEMS_CPUOPT([RTEMS_VERSION],
187  [true],
188  ["]_RTEMS_VERSION["],
189  [RTEMS version string])
190
191RTEMS_CPUOPT([SIZEOF_CPU_CONTEXT],
192  [test x"$RTEMS_CPU" = x"unix"],
193  [$ac_cv_sizeof_CPU_CONTEXT],
194  [The size of a 'CPU_CONTEXT', as computed by sizeof])
195
196cat >>cpuopts.tmp <<\_ACEOF
197
198#endif
199_ACEOF
200
201AS_MKDIR_P(score/include/rtems/score)
202AS_IF([test -f score/include/rtems/score/cpuopts.h],
203[
204  AS_IF([cmp -s score/include/rtems/score/cpuopts.h cpuopts.tmp 2>/dev/null],
205  [
206    AC_MSG_NOTICE([score/include/rtems/score/cpuopts.h is unchanged])
207    rm -f cpuopts.tmp
208  ],[
209    AC_MSG_NOTICE([creating score/include/rtems/score/cpuopts.h])
210    rm -f score/include/rtems/score/cpuopts.h
211    mv cpuopts.tmp score/include/rtems/score/cpuopts.h
212  ])
213],[
214    AC_MSG_NOTICE([creating score/include/rtems/score/cpuopts.h])
215    rm -f score/include/rtems/score/cpuopts.h
216    mv cpuopts.tmp score/include/rtems/score/cpuopts.h
217])
218
219AC_ENABLE_MULTILIB([Makefile],[..])
220
221# libmisc/shell/* wants to assign file descriptors to stdio file descriptors.
222AC_MSG_CHECKING([for assignable stdio])
223AC_COMPILE_IFELSE(
224  [AC_LANG_PROGRAM(
225    [#include <stdio.h>],
226    [stdin = fopen("/tmp", "r")])],
227  [HAVE_ASSIGNABLE_STDIO=yes],
228  [HAVE_ASSIGNABLE_STDIO=no])
229AC_MSG_RESULT([$HAVE_ASSIGNABLE_STDIO])
230
231# libmisc/serdbg exploits weak symbols
232RTEMS_CHECK_GCC_WEAK
233
234AC_CHECK_HEADERS([sys/cdefs.h],[NEED_SYS_CDEFS_H=no],[NEED_SYS_CDEFS_H=yes])
235AC_CHECK_HEADERS([sys/queue.h],[NEED_SYS_QUEUE_H=no],[NEED_SYS_QUEUE_H=yes])
236
237# FIXME: These checks are only in here to provide
238# configuration-time diagnostics and are not really used.
239AC_CHECK_DECLS([_POSIX_LOGIN_NAME_MAX],,,[#include <limits.h>])
240AC_CHECK_DECLS([CHAR_BIT],,,[#include <limits.h>])
241
242## BSD-ism, excluded from POSIX, but available on most platforms
243AC_CHECK_DECLS([sbrk],,,[#include <unistd.h>])
244
245## Check if libc provides BSD's strlcpy/strlcat
246AC_CHECK_FUNCS(strlcpy strlcat)
247
248
249# ... far too many conditionals ...
250AM_CONDITIONAL(LIBRPC,[test "$LIBRPC" = "yes"])
251AM_CONDITIONAL(UNIX,[test x"${RTEMS_CPU}" = x"unix"])
252AM_CONDITIONAL(NEWLIB,test x"$RTEMS_USE_NEWLIB" = x"yes")
253
254AM_CONDITIONAL(INLINE,test x"$enable_rtems_inlines" = x"yes" )
255AM_CONDITIONAL(MACROS,test x"$enable_rtems_inlines" = x"no" )
256AM_CONDITIONAL(HAS_MP,test x"$enable_multiprocessing" = x"yes" )
257
258AM_CONDITIONAL(HAS_POSIX,test x"$rtems_cv_HAS_POSIX_API" = x"yes")
259AM_CONDITIONAL(HAS_ITRON,test x"$rtems_cv_HAS_ITRON_API" = x"yes")
260AM_CONDITIONAL(HAS_NETWORKING,test x"$HAS_NETWORKING" = x"yes")
261
262AM_CONDITIONAL([NEED_SYS_CDEFS_H],[test x"$NEED_SYS_CDEFS_H" = x"yes"])
263AM_CONDITIONAL([NEED_SYS_QUEUE_H],[test x"$NEED_SYS_QUEUE_H" = x"yes"])
264
265AM_CONDITIONAL([LIBSHELL],[test x"$HAVE_ASSIGNABLE_STDIO" = x"yes"])
266AM_CONDITIONAL([LIBSERDBG],[test x"$rtems_cv_cc_attribute_weak" = x"yes"])
267
268AC_PATH_PROG([AMPOLISH3],[ampolish3],[])
269AM_CONDITIONAL([AMPOLISH3],[test x"$USE_MAINTAINER_MODE" = x"yes" \
270  && test -n "$AMPOLISH3"])
271
272AC_CONFIG_HEADER(config.h)
273
274# Explicitly list all Makefiles here
275AC_CONFIG_FILES([
276Makefile
277rtems/Makefile
278sapi/Makefile
279score/Makefile
280score/cpu/Makefile
281score/cpu/arm/Makefile
282score/cpu/avr/Makefile
283score/cpu/c4x/Makefile
284score/cpu/h8300/Makefile
285score/cpu/i386/Makefile
286score/cpu/m68k/Makefile
287score/cpu/mips/Makefile
288score/cpu/powerpc/Makefile
289score/cpu/sh/Makefile
290score/cpu/sparc/Makefile
291score/cpu/unix/Makefile
292score/cpu/no_cpu/Makefile
293posix/Makefile
294itron/Makefile
295libblock/Makefile
296libfs/Makefile
297libcsupport/Makefile
298libnetworking/Makefile
299librpc/Makefile
300libmisc/Makefile
301httpd/Makefile
302ftpd/Makefile
303telnetd/Makefile
304wrapup/Makefile
305])
306
307AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.