source: rtems/cpukit/configure.ac @ 79d145a7

5
Last change on this file since 79d145a7 was 79d145a7, checked in by Sebastian Huber <sebastian.huber@…>, on Oct 18, 2018 at 12:36:44 PM

Remove optional getrusage() declaration

Declaration provided by Newlib since 2014.

Update #3409.

  • Property mode set to 100644
File size: 15.3 KB
Line 
1## Process this file with autoconf to produce a configure script.
2
3AC_PREREQ([2.69])
4AC_INIT([rtems-cpukit],[_RTEMS_VERSION],[https://devel.rtems.org/newticket])
5AC_CONFIG_SRCDIR([score])
6RTEMS_TOP([..],[])
7RTEMS_SOURCE_TOP
8RTEMS_BUILD_TOP
9
10RTEMS_CANONICAL_TARGET_CPU
11
12AM_INIT_AUTOMAKE([no-define nostdinc subdir-objects foreign 1.12.2])
13AM_MAINTAINER_MODE
14
15RTEMS_ENABLE_MULTIPROCESSING
16RTEMS_ENABLE_POSIX
17RTEMS_ENABLE_RTEMS_DEBUG
18RTEMS_ENABLE_NETWORKING
19RTEMS_ENABLE_PARAVIRT
20RTEMS_ENABLE_PROFILING
21RTEMS_ENABLE_DRVMGR
22
23RTEMS_ENV_RTEMSCPU
24RTEMS_CHECK_RTEMS_DEBUG
25
26AC_DEFUN([RTEMS_TOOL_CHAIN_ERROR],AC_MSG_ERROR([please update your tool chain via the RSB <https://docs.rtems.org/branches/master/rsb/quick-start.html>]))
27
28# Is this a supported CPU?
29AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
30if test -d "$srcdir/score/cpu/$RTEMS_CPU"; then
31  AC_MSG_RESULT(yes)
32else
33  AC_MSG_ERROR(no)
34fi
35
36RTEMS_PROG_CC_FOR_TARGET
37AM_PROG_CC_C_O
38RTEMS_CANONICALIZE_TOOLS
39RTEMS_PROG_CCAS
40AC_PROG_RANLIB
41
42AC_MSG_CHECKING([for a need to avoid a long argument list])
43
44hack_to_avoid_long_arg_list=no
45case "${build_os}" in
46  *cygwin*|*mingw*|*msys*)
47     hack_to_avoid_long_arg_list=yes
48     ;;
49   *)
50     ;;
51esac
52
53AC_MSG_RESULT([${hack_to_avoid_long_arg_list}])
54AM_CONDITIONAL([HACK_TO_AVOID_LONG_ARG_LIST], [test "${hack_to_avoid_long_arg_list}" = yes])
55
56RTEMS_CHECK_NEWLIB
57
58# BSD-isms, used throughout the sources
59# Not really used by this configure script
60# FIXME: They should be eliminated if possible.
61AC_CHECK_FUNCS([strcasecmp snprintf])
62AC_CHECK_FUNCS([strdup strndup strncasecmp])
63AC_CHECK_FUNCS([bcopy bcmp])
64AC_CHECK_FUNCS([isascii fileno])
65
66# <FIXME>
67#   Check for functions supplied by newlib >= 1.17.0
68# Newlib's posix/ directory
69AC_CHECK_FUNCS([creat \
70  opendir closedir readdir rewinddir scandir seekdir \
71  sleep \
72  telldir \
73  usleep],,
74  [RTEMS_TOOL_CHAIN_ERROR])
75AC_CHECK_FUNCS([execl execlp execle execv execvp execve])
76AC_CHECK_FUNCS([regcomp regexec regerror regfree])
77
78# Mandated by POSIX, decls not present in some versions of newlib
79AC_CHECK_DECLS([flockfile],[AC_CHECK_FUNCS([flockfile])],,[#include <stdio.h>])
80AC_CHECK_DECLS([funlockfile],[AC_CHECK_FUNCS([funlockfile])],,[#include <stdio.h>])
81AC_CHECK_DECLS([ftrylockfile],[AC_CHECK_FUNCS([ftrylockfile])],,[#include <stdio.h>])
82
83# Newlib proprietary
84AC_CHECK_MEMBER([struct _Thread_queue_Queue._name],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <sys/lock.h>])
85
86# Mandated by POSIX, older newlibs bogusly provided CLOCK_PROCESS_CPUTIME+CLOCK_THREAD_CPUTIME
87AC_CHECK_DECL([CLOCK_PROCESS_CPUTIME_ID],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <time.h>])
88AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <time.h>])
89
90# Mandated by POSIX, decls not present in some versions of newlib,
91# some versions stubbed in newlib's rtems crt0
92RTEMS_CHECK_FUNC([seteuid],[#include <unistd.h>])
93RTEMS_CHECK_FUNC([geteuid],[#include <unistd.h>])
94RTEMS_CHECK_FUNC([setegid],[#include <unistd.h>])
95RTEMS_CHECK_FUNC([getegid],[#include <unistd.h>])
96RTEMS_CHECK_FUNC([setuid],[#include <unistd.h>])
97RTEMS_CHECK_FUNC([getuid],[#include <unistd.h>])
98RTEMS_CHECK_FUNC([setgid],[#include <unistd.h>])
99RTEMS_CHECK_FUNC([getgid],[#include <unistd.h>])
100RTEMS_CHECK_FUNC([setsid],[#include <unistd.h>])
101RTEMS_CHECK_FUNC([getsid],[#include <unistd.h>])
102RTEMS_CHECK_FUNC([setpgid],[#include <unistd.h>])
103RTEMS_CHECK_FUNC([getpgid],[#include <unistd.h>])
104RTEMS_CHECK_FUNC([setpgrp],[#include <unistd.h>])
105RTEMS_CHECK_FUNC([getpgrp],[#include <unistd.h>])
106
107# pthread-functions not declared in some versions of newlib.
108RTEMS_CHECK_FUNC([pthread_attr_getguardsize],[#include <pthread.h>])
109RTEMS_CHECK_FUNC([pthread_attr_setguardsize],[#include <pthread.h>])
110RTEMS_CHECK_FUNC([pthread_attr_setstack],[#include <pthread.h>])
111RTEMS_CHECK_FUNC([pthread_attr_getstack],[#include <pthread.h>])
112
113# These are SMP related and were added to newlib by RTEMS.
114RTEMS_CHECK_FUNC([pthread_attr_setaffinity_np],[
115  #define _GNU_SOURCE
116  #include <pthread.h>])
117RTEMS_CHECK_FUNC([pthread_attr_getaffinity_np],[
118  #define _GNU_SOURCE
119  #include <pthread.h>])
120RTEMS_CHECK_FUNC([pthread_setaffinity_np],[
121  #define _GNU_SOURCE
122  #include <pthread.h>])
123RTEMS_CHECK_FUNC([pthread_getaffinity_np],[
124  #define _GNU_SOURCE
125  #include <pthread.h>])
126RTEMS_CHECK_FUNC([pthread_getattr_np],[
127  #define _GNU_SOURCE
128  #include <pthread.h>])
129
130AC_LANG_PUSH(C)
131AC_MSG_CHECKING([for mprotect(const void *, ...)])
132AC_COMPILE_IFELSE([AC_LANG_SOURCE([
133#include <sys/mman.h>
134int mprotect(const void *, size_t, int);
135])],[
136AC_MSG_RESULT([yes])
137AC_DEFINE(HAVE_MPROTECT_CONST, [], [mprotect(const void *, ...)])
138],[
139AC_MSG_RESULT([no])
140])
141AC_MSG_CHECKING([for pthread_mutex_getprioceiling(const pthread_mutex_t *, ...)])
142AC_COMPILE_IFELSE([AC_LANG_SOURCE([
143#include <pthread.h>
144int pthread_mutex_getprioceiling(const pthread_mutex_t *__restrict, int *);
145])],[
146AC_MSG_RESULT([yes])
147AC_DEFINE(HAVE_PTHREAD_MUTEX_GETCEILING_CONST, [], [pthread_mutex_getprioceiling(const pthread_mutex_t *, ...)])
148],[
149AC_MSG_RESULT([no])
150])
151AC_MSG_CHECKING([for pthread_setschedparam(..., const struct sched_param *)])
152AC_COMPILE_IFELSE([AC_LANG_SOURCE([
153#include <pthread.h>
154int pthread_setschedparam(pthread_t, int, const struct sched_param *);
155])],[
156AC_MSG_RESULT([yes])
157AC_DEFINE(HAVE_PTHREAD_SETSCHEDPARAM_CONST, [], [pthread_setschedparam(..., const struct sched_param *)])
158],[
159AC_MSG_RESULT([no])
160])
161AC_LANG_POP(C)
162
163# Newlib's unix/ directory
164AC_CHECK_FUNCS([getcwd])
165# </FIXME>
166
167# Check if the installed toolchain provides these headers
168# and error out if not.
169AC_CHECK_HEADERS([errno.h sched.h semaphore.h sys/cdefs.h sys/queue.h tar.h threads.h],,
170  [RTEMS_TOOL_CHAIN_ERROR])
171
172## error out if libc doesn't provide stdint.h
173AS_IF([test x"${ac_cv_header_stdint_h}" != xyes],
174[RTEMS_TOOL_CHAIN_ERROR])
175
176## error out if libc doesn't provide inttypes.h
177AS_IF([test x"${ac_cv_header_inttypes_h}" != xyes],
178[RTEMS_TOOL_CHAIN_ERROR])
179
180AC_HEADER_STDBOOL
181AS_IF([test x"${ac_cv_header_stdbool_h}" != xyes],
182[RTEMS_TOOL_CHAIN_ERROR])
183
184AC_CHECK_TYPES([ uint8_t,  int8_t])
185AC_CHECK_TYPES([uint16_t, int16_t])
186AC_CHECK_TYPES([uint32_t, int32_t])
187AC_CHECK_TYPES([uint64_t, int64_t])
188AC_CHECK_TYPES([uintmax_t, intmax_t])
189AC_CHECK_TYPES([uintptr_t, intptr_t])
190
191# Some toolchain sanity checks and diagnostics
192RTEMS_CHECK_GCC_SANITY
193
194# These are conditionally defined by the toolchain
195# FIXME: we should either conditionally compile those parts in
196# RTEMS depending on them, or abort - For now, simply check.
197AC_CHECK_HEADER([pthread.h],[
198  AC_CHECK_TYPES([pthread_rwlock_t])
199  AC_CHECK_TYPES([pthread_barrier_t])
200  AC_CHECK_TYPES([pthread_spinlock_t])
201  AC_CHECK_TYPES([struct _pthread_cleanup_context],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <pthread.h>])
202  AC_CHECK_TYPES([struct _Priority_Node],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <pthread.h>])
203])
204
205AC_CHECK_HEADER([signal.h],[
206  AC_CHECK_TYPES([sighandler_t])
207])
208
209if test x"$RTEMS_USE_NEWLIB" = xyes ; then
210  AC_CHECK_DECLS([__getreent],[],[RTEMS_TOOL_CHAIN_ERROR],[#include <sys/reent.h>])
211fi
212
213RTEMS_CHECK_MULTIPROCESSING
214RTEMS_CHECK_POSIX_API
215RTEMS_CHECK_NETWORKING
216RTEMS_CHECK_SMP
217if test "${RTEMS_HAS_SMP}" = "yes"; then
218  AC_CHECK_HEADERS([stdatomic.h],[],[RTEMS_TOOL_CHAIN_ERROR])
219fi
220
221rtems_major=`echo _RTEMS_VERSION | sed "s/\..*//"`
222rtems_minor=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/\..*//"`
223rtems_revision=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/[[0-9]][[0-9]]*\.//;s/\..*//"`
224
225_RTEMS_CPUOPT_INIT
226
227RTEMS_CPUOPT([RTEMS_DEBUG],
228  [test x"${enable_rtems_debug}" = x"yes"],
229  [1],
230  [if RTEMS_DEBUG is enabled])
231
232RTEMS_CPUOPT([RTEMS_MULTIPROCESSING],
233  [test x"$enable_multiprocessing" = xyes],
234  [1],
235  [if multiprocessing is enabled])
236
237RTEMS_CPUOPT([RTEMS_NEWLIB],
238  [test x"$RTEMS_USE_NEWLIB" = xyes],
239  [1],
240  [if using newlib])
241
242RTEMS_CPUOPT([RTEMS_POSIX_API],
243  [test x"$rtems_cv_HAS_POSIX_API" = xyes],
244  [1],
245  [if posix api is supported])
246
247RTEMS_CPUOPT([RTEMS_SMP],
248  [test x"$RTEMS_HAS_SMP" = xyes],
249  [1],
250  [if SMP is enabled])
251
252RTEMS_CPUOPT([RTEMS_PARAVIRT],
253  [test x"$RTEMS_HAS_PARAVIRT" = xyes],
254  [1],
255  [PARAVIRT is enabled])
256
257RTEMS_CPUOPT([RTEMS_PROFILING],
258  [test x"$RTEMS_HAS_PROFILING" = xyes],
259  [1],
260  [if profiling is enabled])
261
262RTEMS_CPUOPT([RTEMS_NETWORKING],
263  [test x"$rtems_cv_HAS_NETWORKING" = xyes],
264  [1],
265  [if networking is enabled])
266
267RTEMS_CPUOPT([RTEMS_DRVMGR_STARTUP],
268  [test x"$enable_drvmgr" = xyes],
269  [1],
270  [if driver manager api is supported])
271
272RTEMS_CPUOPT([RTEMS_VERSION],
273  [true],
274  ["]_RTEMS_VERSION["],
275  [RTEMS version string])
276
277## Header file differences that need to be known in .h after install
278
279## Deactivate ada bindings
280RTEMS_CPUOPT([__RTEMS_ADA__],
281  [test x"${enable_ada}" = x"yes"],
282  [1],
283  [Define to 1 if ada/gnat bindings are built-in])
284
285# These are used to provide <rtems/inttypes.h
286AC_CHECK_SIZEOF([mode_t])
287AC_CHECK_SIZEOF([off_t])
288AC_CHECK_SIZEOF([time_t])
289AC_CHECK_SIZEOF([size_t])
290AC_CHECK_SIZEOF([blksize_t])
291AC_CHECK_SIZEOF([blkcnt_t])
292
293## Provide sizeof(mode_t) information via cpuopts.h
294RTEMS_CPUOPT([__RTEMS_SIZEOF_MODE_T__],
295  [true],
296  [${ac_cv_sizeof_mode_t}],
297  [sizeof(mode_t)])
298
299## Provide sizeof(off_t) information via cpuopts.h
300RTEMS_CPUOPT([__RTEMS_SIZEOF_OFF_T__],
301  [true],
302  [${ac_cv_sizeof_off_t}],
303  [sizeof(off_t)])
304
305## Provide sizeof(time_t) information via cpuopts.h
306RTEMS_CPUOPT([__RTEMS_SIZEOF_TIME_T__],
307  [true],
308  [${ac_cv_sizeof_time_t}],
309  [sizeof(time_t)])
310
311## Provide sizeof(blksize_t) information via cpuopts.h
312RTEMS_CPUOPT([__RTEMS_SIZEOF_BLKSIZE_T__],
313  [true],
314  [${ac_cv_sizeof_blksize_t}],
315  [sizeof(blksize_t)])
316
317## Provide sizeof(blkcnt_t) information via cpuopts.h
318RTEMS_CPUOPT([__RTEMS_SIZEOF_BLKCNT_T__],
319  [true],
320  [${ac_cv_sizeof_blkcnt_t}],
321  [sizeof(blkcnt_t)])
322
323## Then we propagate a private copy of the value into cpuopts.h
324## so it is always available to the RTEMS header files.
325
326RTEMS_CPUOPT([__RTEMS_MAJOR__],
327  [true],
328  [$rtems_major],
329  [major version portion of an RTEMS release])
330
331RTEMS_CPUOPT([__RTEMS_MINOR__],
332  [true],
333  [$rtems_minor],
334  [minor version portion of an RTEMS release])
335
336RTEMS_CPUOPT([__RTEMS_REVISION__],
337  [true],
338  [$rtems_revision],
339  [revision version portion of an RTEMS release])
340
341_RTEMS_CPUOPT_FINI
342
343AC_ENABLE_MULTILIB([Makefile],[..])
344
345# libmisc/shell/* wants to assign file descriptors to stdio file descriptors.
346AC_MSG_CHECKING([for assignable stdio])
347AC_COMPILE_IFELSE(
348  [AC_LANG_PROGRAM(
349    [#include <stdio.h>],
350    [stdin = fopen("/tmp", "r")])],
351  [HAVE_ASSIGNABLE_STDIO=yes],
352  [HAVE_ASSIGNABLE_STDIO=no])
353AC_MSG_RESULT([$HAVE_ASSIGNABLE_STDIO])
354
355# libmisc/serdbg exploits weak symbols
356RTEMS_CHECK_GCC_WEAK
357
358# FIXME: These checks are only in here to provide
359# configuration-time diagnostics and are not really used.
360AC_CHECK_DECLS([_POSIX_LOGIN_NAME_MAX],,,[#include <limits.h>])
361AC_CHECK_DECLS([CHAR_BIT],,,[#include <limits.h>])
362
363# FIXME: Mandatory in SUSv4, optional in SUSv3.
364#   Not implemented in GCC/newlib, so far.
365AC_CHECK_DECLS([WORD_BIT],,,[#include <limits.h>])
366AC_CHECK_DECLS([LONG_BIT],,,[#include <limits.h>])
367
368## BSD-ism, excluded from POSIX, but available on most platforms
369AC_CHECK_DECLS([sbrk],,,[#include <unistd.h>])
370AC_CHECK_DECLS([rcmd],,,[#include <unistd.h>])
371
372## Check if libc provides decl of utime
373## FIXME: utime has been deprecated in SUSv4.
374##        and is likely to be removed in future versions.
375## FIXME (BUG in newlib): SUSv4 saids including <utime.h> should be sufficient.
376AC_CHECK_DECLS([utime],,,[#include <sys/types.h>
377#include <utime.h>])
378## Check if libc provides decl of utimes
379AC_CHECK_DECLS([utimes],,,[#include <sys/time.h>])
380
381# Ensure that Newlib does not provide things now in <machine/_timecounter.h>
382AC_CHECK_DECLS([_Timecounter_Time_second],[RTEMS_TOOL_CHAIN_ERROR],,[#include <sys/time.h>])
383
384# ... far too many conditionals ...
385AM_CONDITIONAL(NEWLIB,test x"$RTEMS_USE_NEWLIB" = x"yes")
386
387AM_CONDITIONAL(HAS_MP,test x"$enable_multiprocessing" = x"yes" )
388AM_CONDITIONAL(HAS_SMP,[test "$RTEMS_HAS_SMP" = "yes"])
389
390AM_CONDITIONAL(HAS_PTHREADS,test x"$rtems_cv_HAS_POSIX_API" = x"yes")
391AM_CONDITIONAL(LIBNETWORKING,test x"$rtems_cv_HAS_NETWORKING" = x"yes")
392
393AM_CONDITIONAL([LIBSHELL],[test x"$HAVE_ASSIGNABLE_STDIO" = x"yes"])
394AM_CONDITIONAL([LIBSERDBG],[test x"$rtems_cv_cc_attribute_weak" = x"yes"])
395AM_CONDITIONAL([LIBGNAT],[test x"$rtems_cv_HAS_POSIX_API" = x"yes" \
396&& test x"$enable_ada" = x"yes"])
397
398AM_CONDITIONAL([LIBUTF8PROC],[test $ac_cv_sizeof_size_t -gt 2])
399
400AM_CONDITIONAL([LIBDOSFS],[dnl
401test x"$ac_cv_type_uint8_t" = xyes \
402&& test x"$ac_cv_type_uint16_t" = xyes])
403
404AC_CONFIG_HEADER(config.h)
405
406## These are needed by the NFS Client
407AC_CHECK_PROG(RPCGEN,rpcgen,rpcgen)
408AM_CONDITIONAL([RPCTOOLS],[test "$RPCGEN" = rpcgen \
409&& test -n "$AWK" \
410&& test "$enable_rpcgen" = yes])
411
412# Filter dynamic loading to only build for architectures that have
413# reloc backends
414AC_MSG_CHECKING([whether CPU supports libdl])
415case $RTEMS_CPU in
416  arm | i386 | m68k | mips | moxie | powerpc | sparc)
417   HAVE_LIBDL=yes ;;
418  # bfin has an issue to resolve with libdl. See ticket #2252
419  bfin)
420   HAVE_LIBDL=no ;;
421  # lm32 has an issue to resolve with libdl. See ticket #2283
422  lm32)
423   HAVE_LIBDL=no ;;
424  # v850 has an issue to resolve with libdl. See ticket #2260
425  v850)
426   HAVE_LIBDL=no ;;
427  *)
428   HAVE_LIBDL=no ;;
429esac
430AM_CONDITIONAL(LIBDL,[test x"$HAVE_LIBDL" = x"yes"])
431AC_MSG_RESULT([$HAVE_LIBDL])
432
433# Filter debugger to only build for architectures that have a target backend
434AC_MSG_CHECKING([whether CPU supports libdebugger])
435case $RTEMS_CPU in
436  arm | i386)
437   HAVE_LIBDEBUGGER=yes ;;
438  *)
439   HAVE_LIBDEBUGGER=no ;;
440esac
441AM_CONDITIONAL(LIBDEBUGGER,[test x"$HAVE_LIBDEBUGGER" = x"yes"])
442AC_MSG_RESULT([$HAVE_LIBDEBUGGER])
443
444AC_MSG_CHECKING([whether CPU supports SHA])
445case $RTEMS_CPU in
446  m32c)
447   HAVE_SHA=no ;;
448  *)
449   HAVE_SHA=yes ;;
450esac
451AM_CONDITIONAL(SHA,[test x"$HAVE_SHA" = x"yes"])
452AC_MSG_RESULT([$HAVE_SHA])
453
454# Filter libpci to only build for architectures that have support for it
455AC_MSG_CHECKING([whether CPU supports libpci])
456case $RTEMS_CPU in
457  sparc)
458   HAVE_LIBPCI=yes ;;
459  *)
460   HAVE_LIBPCI=no ;;
461esac
462AM_CONDITIONAL(LIBPCI,[test x"$HAVE_LIBPCI" = x"yes"])
463AC_MSG_RESULT([$HAVE_LIBPCI])
464
465# Filter libdrvmgr to only build for architectures that have support for it
466AC_MSG_CHECKING([whether CPU supports libdrvmgr])
467case $RTEMS_CPU in
468  sparc)
469   HAVE_LIBDRVMGR=yes ;;
470  *)
471   HAVE_LIBDRVMGR=no ;;
472esac
473AM_CONDITIONAL(LIBDRVMGR,[test x"$HAVE_LIBDRVMGR" = x"yes"])
474AC_MSG_RESULT([$HAVE_LIBDRVMGR])
475
476AM_CONDITIONAL([CPU_ARM],[test $RTEMS_CPU = "arm"])
477AM_CONDITIONAL([CPU_BFIN],[test $RTEMS_CPU = "bfin"])
478AM_CONDITIONAL([CPU_EPIPHANY],[test $RTEMS_CPU = "epiphany"])
479AM_CONDITIONAL([CPU_I386],[test $RTEMS_CPU = "i386"])
480AM_CONDITIONAL([CPU_LM32],[test $RTEMS_CPU = "lm32"])
481AM_CONDITIONAL([CPU_M32C],[test $RTEMS_CPU = "m32c"])
482AM_CONDITIONAL([CPU_M68K],[test $RTEMS_CPU = "m68k"])
483AM_CONDITIONAL([CPU_MIPS],[test $RTEMS_CPU = "mips"])
484AM_CONDITIONAL([CPU_MOXIE],[test $RTEMS_CPU = "moxie"])
485AM_CONDITIONAL([CPU_NIOS2],[test $RTEMS_CPU = "nios2"])
486AM_CONDITIONAL([CPU_NO_CPU],[test $RTEMS_CPU = "no_cpu"])
487AM_CONDITIONAL([CPU_OR1K],[test $RTEMS_CPU = "or1k"])
488AM_CONDITIONAL([CPU_POWERPC],[test $RTEMS_CPU = "powerpc"])
489AM_CONDITIONAL([CPU_RISCV],[test $RTEMS_CPU = "riscv"])
490AM_CONDITIONAL([CPU_SH],[test $RTEMS_CPU = "sh"])
491AM_CONDITIONAL([CPU_SPARC64],[test $RTEMS_CPU = "sparc64"])
492AM_CONDITIONAL([CPU_SPARC],[test $RTEMS_CPU = "sparc"])
493AM_CONDITIONAL([CPU_V850],[test $RTEMS_CPU = "v850"])
494AM_CONDITIONAL([CPU_X86_64],[test $RTEMS_CPU = "x86_64"])
495
496RTEMS_AMPOLISH3
497
498# Explicitly list all Makefiles here
499AC_CONFIG_FILES([
500Doxyfile
501Makefile])
502
503AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.