source: rtems/cpukit/configure.ac @ 4f09060

4.11
Last change on this file since 4f09060 was 4f09060, checked in by Daniel Hellstrom <daniel@…>, on Apr 13, 2015 at 8:32:50 AM

DRVMGR: only build on SPARC platform

  • Property mode set to 100644
File size: 14.7 KB
Line 
1## Process this file with autoconf to produce a configure script.
2
3AC_PREREQ([2.69])
4AC_INIT([rtems-cpukit],[_RTEMS_VERSION],[https://devel.rtems.org/newticket])
5AC_CONFIG_SRCDIR([score])
6RTEMS_TOP([..],[])
7
8RTEMS_CANONICAL_TARGET_CPU
9
10AM_INIT_AUTOMAKE([no-define nostdinc subdir-objects foreign 1.12.2])
11AM_MAINTAINER_MODE
12
13RTEMS_ENABLE_MULTILIB
14RTEMS_ENABLE_MULTIPROCESSING
15RTEMS_ENABLE_POSIX
16RTEMS_ENABLE_RTEMS_DEBUG
17RTEMS_ENABLE_NETWORKING
18RTEMS_ENABLE_PARAVIRT
19RTEMS_ENABLE_PROFILING
20RTEMS_ENABLE_DRVMGR
21
22RTEMS_ENV_RTEMSCPU
23RTEMS_CHECK_RTEMS_DEBUG
24
25# Is this a supported CPU?
26AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
27if test -d "$srcdir/score/cpu/$RTEMS_CPU"; then
28  AC_MSG_RESULT(yes)
29else
30  AC_MSG_ERROR(no)
31fi
32
33RTEMS_PROG_CC_FOR_TARGET
34RTEMS_PROG_CCAS
35RTEMS_CANONICALIZE_TOOLS
36AM_PROG_CC_C_O
37AC_PROG_RANLIB
38
39RTEMS_CHECK_NEWLIB
40
41# BSD-isms, used throughout the sources
42# Not really used by this configure script
43# FIXME: They should be eliminated if possible.
44AC_CHECK_FUNCS([strsep strcasecmp snprintf])
45AC_CHECK_FUNCS([strdup strndup strncasecmp])
46AC_CHECK_FUNCS([bcopy bcmp])
47AC_CHECK_FUNCS([isascii fileno])
48
49# <FIXME>
50#   Check for functions supplied by newlib >= 1.17.0
51# Newlib's posix/ directory
52AC_CHECK_FUNCS([readdir_r isatty])
53AC_CHECK_FUNCS([creat \
54  opendir closedir readdir rewinddir scandir seekdir \
55  sleep \
56  telldir \
57  usleep],,
58  [rtems_missing_func="$ac_func";break])
59AS_IF([test -n "$rtems_missing_func"],
60  AC_MSG_ERROR([Missing function $rtems_missing_func in libc])])
61AC_CHECK_FUNCS([__assert])
62AC_CHECK_FUNCS([execl execlp execle execv execvp execve])
63AC_CHECK_FUNCS([regcomp regexec regerror regfree])
64
65# Mandated by POSIX, decls not present in some versions of newlib
66AC_CHECK_DECLS([flockfile],[AC_CHECK_FUNCS([flockfile])],,[#include <stdio.h>])
67AC_CHECK_DECLS([funlockfile],[AC_CHECK_FUNCS([funlockfile])],,[#include <stdio.h>])
68AC_CHECK_DECLS([ftrylockfile],[AC_CHECK_FUNCS([ftrylockfile])],,[#include <stdio.h>])
69
70# Newlib proprietary
71AC_CHECK_HEADERS([envlock.h])
72AC_CHECK_DECLS([__env_lock],,,[#include <envlock.h>])
73AC_CHECK_DECLS([__env_unlock],,,[#include <envlock.h>])
74
75# Mandated by POSIX, older newlibs bogusly provided CLOCK_PROCESS_CPUTIME+CLOCK_THREAD_CPUTIME
76AC_CHECK_DECL([CLOCK_PROCESS_CPUTIME_ID],[],[AC_MSG_ERROR([missing define CLOCK_PROCESS_CPUTIME_ID])],[#include <time.h>])
77AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID],[],[AC_MSG_ERROR([missing define CLOCK_THREAD_CPUTIME_ID])],[#include <time.h>])
78
79# Mandated by POSIX, decls not present in some versions of newlib,
80# some versions stubbed in newlib's rtems crt0
81RTEMS_CHECK_FUNC([seteuid],[#include <unistd.h>])
82RTEMS_CHECK_FUNC([geteuid],[#include <unistd.h>])
83RTEMS_CHECK_FUNC([setegid],[#include <unistd.h>])
84RTEMS_CHECK_FUNC([getegid],[#include <unistd.h>])
85RTEMS_CHECK_FUNC([setuid],[#include <unistd.h>])
86RTEMS_CHECK_FUNC([getuid],[#include <unistd.h>])
87RTEMS_CHECK_FUNC([setgid],[#include <unistd.h>])
88RTEMS_CHECK_FUNC([getgid],[#include <unistd.h>])
89RTEMS_CHECK_FUNC([setsid],[#include <unistd.h>])
90RTEMS_CHECK_FUNC([getsid],[#include <unistd.h>])
91RTEMS_CHECK_FUNC([setpgid],[#include <unistd.h>])
92RTEMS_CHECK_FUNC([getpgid],[#include <unistd.h>])
93RTEMS_CHECK_FUNC([setpgrp],[#include <unistd.h>])
94RTEMS_CHECK_FUNC([getpgrp],[#include <unistd.h>])
95
96# pthread-functions not declared in some versions of newlib.
97RTEMS_CHECK_FUNC([pthread_attr_getguardsize],[#include <pthread.h>])
98RTEMS_CHECK_FUNC([pthread_attr_setguardsize],[#include <pthread.h>])
99RTEMS_CHECK_FUNC([pthread_attr_setstack],[#include <pthread.h>])
100RTEMS_CHECK_FUNC([pthread_attr_getstack],[#include <pthread.h>])
101
102# These are SMP related and were added to newlib by RTEMS.
103RTEMS_CHECK_FUNC([pthread_attr_setaffinity_np],[
104  #define _GNU_SOURCE
105  #include <pthread.h>])
106RTEMS_CHECK_FUNC([pthread_attr_getaffinity_np],[
107  #define _GNU_SOURCE
108  #include <pthread.h>])
109RTEMS_CHECK_FUNC([pthread_setaffinity_np],[
110  #define _GNU_SOURCE
111  #include <pthread.h>])
112RTEMS_CHECK_FUNC([pthread_getaffinity_np],[
113  #define _GNU_SOURCE
114  #include <pthread.h>])
115RTEMS_CHECK_FUNC([pthread_getattr_np],[
116  #define _GNU_SOURCE
117  #include <pthread.h>])
118AC_CHECK_HEADERS([sys/cpuset.h])
119
120# This was added to newlib in August 2014 to improve conformance.
121# Disable use of internal definition if it is present.
122RTEMS_CHECK_FUNC([sigaltstack],[
123  #define _GNU_SOURCE
124  #include <signal.h>])
125
126# Mandated by POSIX, not declared in some versions of newlib.
127AC_CHECK_DECLS([getrusage],,,[#include sys/resource.h])
128
129# Newlib's unix/ directory
130AC_CHECK_FUNCS([ttyname getcwd])
131# </FIXME>
132
133# Check if the installed toolchain provides these headers
134# and error out if not.
135AC_CHECK_HEADERS([tar.h errno.h sched.h sys/cdefs.h sys/queue.h],,
136  [rtems_missing_header="$ac_header";break])
137AS_IF([test -n "$rtems_missing_header"],
138  AC_MSG_ERROR([Missing required header $rtems_missing_header])])
139
140AC_CHECK_HEADERS([semaphore.h])
141AM_CONDITIONAL([HAVE_SEMAPHORE_H],[test x"$ac_cv_header_semaphore_h" = x"yes"])
142
143## error out if libc doesn't provide stdint.h
144AS_IF([test x"${ac_cv_header_stdint_h}" != xyes],
145[AC_MSG_ERROR([Required header stdint.h not found])])
146
147## error out if libc doesn't provide inttypes.h
148AS_IF([test x"${ac_cv_header_inttypes_h}" != xyes],
149[AC_MSG_ERROR([Required header inttypes.h not found])])
150
151AC_HEADER_STDBOOL
152AS_IF([test x"${ac_cv_header_stdbool_h}" != xyes],
153[AC_MSG_ERROR([No sufficient stdbool.h found])])
154
155AC_CHECK_TYPES([ uint8_t,  int8_t])
156AC_CHECK_TYPES([uint16_t, int16_t])
157AC_CHECK_TYPES([uint32_t, int32_t])
158AC_CHECK_TYPES([uint64_t, int64_t])
159AC_CHECK_TYPES([uintmax_t, intmax_t])
160AC_CHECK_TYPES([uintptr_t, intptr_t])
161
162# Some toolchain sanity checks and diagnostics
163RTEMS_CHECK_GCC_SANITY
164
165# These are conditionally defined by the toolchain
166# FIXME: we should either conditionally compile those parts in
167# RTEMS depending on them, or abort - For now, simply check.
168AC_CHECK_HEADER([pthread.h],[
169  AC_CHECK_TYPES([pthread_rwlock_t])
170  AC_CHECK_TYPES([pthread_barrier_t])
171  AC_CHECK_TYPES([pthread_spinlock_t])
172  AC_CHECK_TYPES([struct _pthread_cleanup_context],[],[],[#include <pthread.h>])
173])
174
175AC_CHECK_HEADER([signal.h],[
176  AC_CHECK_TYPES([sighandler_t])
177])
178
179RTEMS_CHECK_MULTIPROCESSING
180RTEMS_CHECK_POSIX_API
181RTEMS_CHECK_NETWORKING
182RTEMS_CHECK_SMP
183if test "${RTEMS_HAS_SMP}" = "yes"; then
184  AC_CHECK_HEADERS([stdatomic.h],[],[AC_MSG_ERROR([<stdatomic.h> is required for SMP support])])
185fi
186
187rtems_major=`echo _RTEMS_VERSION | sed "s/\..*//"`
188rtems_minor=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/\..*//"`
189rtems_revision=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/[[0-9]][[0-9]]*\.//;s/\..*//"`
190
191_RTEMS_CPUOPT_INIT
192
193RTEMS_CPUOPT([RTEMS_DEBUG],
194  [test x"${enable_rtems_debug}" = x"yes"],
195  [1],
196  [if RTEMS_DEBUG is enabled])
197
198RTEMS_CPUOPT([RTEMS_MULTIPROCESSING],
199  [test x"$enable_multiprocessing" = xyes],
200  [1],
201  [if multiprocessing is enabled])
202
203RTEMS_CPUOPT([RTEMS_NEWLIB],
204  [test x"$RTEMS_USE_NEWLIB" = xyes],
205  [1],
206  [if using newlib])
207
208RTEMS_CPUOPT([RTEMS_POSIX_API],
209  [test x"$rtems_cv_HAS_POSIX_API" = xyes],
210  [1],
211  [if posix api is supported])
212
213RTEMS_CPUOPT([RTEMS_SMP],
214  [test x"$RTEMS_HAS_SMP" = xyes],
215  [1],
216  [if SMP is enabled])
217
218RTEMS_CPUOPT([RTEMS_PARAVIRT],
219  [test x"$RTEMS_HAS_PARAVIRT" = xyes],
220  [1],
221  [PARAVIRT is enabled])
222
223RTEMS_CPUOPT([RTEMS_PROFILING],
224  [test x"$RTEMS_HAS_PROFILING" = xyes],
225  [1],
226  [if profiling is enabled])
227
228RTEMS_CPUOPT([RTEMS_NETWORKING],
229  [test x"$rtems_cv_HAS_NETWORKING" = xyes],
230  [1],
231  [if networking is enabled])
232
233RTEMS_CPUOPT([RTEMS_DRVMGR_STARTUP],
234  [test x"$enable_drvmgr" = xyes],
235  [1],
236  [if driver manager api is supported])
237
238RTEMS_CPUOPT([RTEMS_VERSION],
239  [true],
240  ["]_RTEMS_VERSION["],
241  [RTEMS version string])
242
243RTEMS_CPUOPT([__RTEMS_USE_TICKS_FOR_STATISTICS__],
244  [test x"${USE_TICKS_FOR_STATISTICS}" = x"1"],
245  [1],
246  [disable nanosecond granularity for statistics])
247
248## Header file differences that need to be known in .h after install
249RTEMS_CPUOPT([__RTEMS_HAVE_SYS_CPUSET_H__],
250  [test x"${ac_cv_header_sys_cpuset_h}" = x"yes"],
251  [1],
252  [indicate if <sys/cpuset.h> is present in toolset])
253
254## Header file differences that need to be known in .h after install
255RTEMS_CPUOPT([__RTEMS_HAVE_DECL_SIGALTSTACK__],
256  [test x"${ac_cv_have_decl_sigaltstack}" = x"yes"],
257  [1],
258  [indicate if <signal.h> in toolset has sigaltstack()])
259
260## This improves both the size and coverage analysis.
261RTEMS_CPUOPT([__RTEMS_DO_NOT_INLINE_THREAD_ENABLE_DISPATCH__],
262  [test x"${RTEMS_DO_NOT_INLINE_THREAD_ENABLE_DISPATCH}" = x"1"],
263  [1],
264  [disable inlining _Thread_Enable_dispatch])
265
266## This improves both the size and coverage analysis.
267RTEMS_CPUOPT([__RTEMS_DO_NOT_INLINE_CORE_MUTEX_SEIZE__],
268  [test x"${RTEMS_DO_NOT_INLINE_CORE_MUTEX_SEIZE}" = x"1"],
269  [1],
270  [disable inlining _Thread_Enable_dispatch])
271
272## This gives the same behavior as 4.8 and older
273RTEMS_CPUOPT([__RTEMS_STRICT_ORDER_MUTEX__],
274  [test x"${ENABLE_STRICT_ORDER_MUTEX}" = x"1"],
275  [1],
276  [disable strict order mutex])
277
278## Deactivate ada bindings
279RTEMS_CPUOPT([__RTEMS_ADA__],
280  [test x"${enable_ada}" = x"yes"],
281  [1],
282  [Define to 1 if ada/gnat bindings are built-in])
283
284## Then we propagate a private copy of the value into cpuopts.h
285## so it is always available to the RTEMS header files.
286
287RTEMS_CPUOPT([__RTEMS_MAJOR__],
288  [true],
289  [$rtems_major],
290  [major version portion of an RTEMS release])
291
292RTEMS_CPUOPT([__RTEMS_MINOR__],
293  [true],
294  [$rtems_minor],
295  [minor version portion of an RTEMS release])
296
297RTEMS_CPUOPT([__RTEMS_REVISION__],
298  [true],
299  [$rtems_revision],
300  [revision version portion of an RTEMS release])
301
302_RTEMS_CPUOPT_FINI
303
304AC_ENABLE_MULTILIB([Makefile],[..])
305
306# libmisc/shell/* wants to assign file descriptors to stdio file descriptors.
307AC_MSG_CHECKING([for assignable stdio])
308AC_COMPILE_IFELSE(
309  [AC_LANG_PROGRAM(
310    [#include <stdio.h>],
311    [stdin = fopen("/tmp", "r")])],
312  [HAVE_ASSIGNABLE_STDIO=yes],
313  [HAVE_ASSIGNABLE_STDIO=no])
314AC_MSG_RESULT([$HAVE_ASSIGNABLE_STDIO])
315
316# libmisc/serdbg exploits weak symbols
317RTEMS_CHECK_GCC_WEAK
318
319# FIXME: These checks are only in here to provide
320# configuration-time diagnostics and are not really used.
321AC_CHECK_DECLS([_POSIX_LOGIN_NAME_MAX],,,[#include <limits.h>])
322AC_CHECK_DECLS([CHAR_BIT],,,[#include <limits.h>])
323
324# FIXME: We should get rid of this.
325# So far, only used in libfs/src/nfsclient/src/dirutils.c
326AC_CHECK_SIZEOF([mode_t])
327AC_CHECK_SIZEOF([off_t])
328
329# FIXME: We should get rid of this. It's a cludge.
330AC_CHECK_SIZEOF([time_t])
331
332AC_CHECK_SIZEOF([size_t])
333
334# FIXME: Mandatory in SUSv4, optional in SUSv3.
335#   Not implemented in GCC/newlib, so far.
336AC_CHECK_DECLS([WORD_BIT],,,[#include <limits.h>])
337AC_CHECK_DECLS([LONG_BIT],,,[#include <limits.h>])
338
339## BSD-ism, excluded from POSIX, but available on most platforms
340AC_CHECK_DECLS([sbrk],,,[#include <unistd.h>])
341AC_CHECK_DECLS([rcmd],,,[#include <unistd.h>])
342
343## Check if libc provides BSD's strlcpy/strlcat
344AC_CHECK_FUNCS(strlcpy strlcat)
345
346## Check if libc provides decl of utime
347## FIXME: utime has been deprecated in SUSv4.
348##        and is likely to be removed in future versions.
349## FIXME (BUG in newlib): SUSv4 saids including <utime.h> should be sufficient.
350AC_CHECK_DECLS([utime],,,[#include <sys/types.h>
351#include <utime.h>])
352## Check if libc provides decl of utimes
353AC_CHECK_DECLS([utimes],,,[#include <sys/time.h>])
354
355# ... far too many conditionals ...
356AM_CONDITIONAL(LIBRPC,[test x"$rtems_cv_HAS_NETWORKING" = x"yes"])
357AM_CONDITIONAL(NEWLIB,test x"$RTEMS_USE_NEWLIB" = x"yes")
358
359AM_CONDITIONAL(HAS_MP,test x"$enable_multiprocessing" = x"yes" )
360AM_CONDITIONAL(HAS_SMP,[test "$RTEMS_HAS_SMP" = "yes"])
361
362AM_CONDITIONAL(HAS_PTHREADS,test x"$rtems_cv_HAS_POSIX_API" = x"yes")
363AM_CONDITIONAL(LIBNETWORKING,test x"$rtems_cv_HAS_NETWORKING" = x"yes")
364
365AM_CONDITIONAL([LIBSHELL],[test x"$HAVE_ASSIGNABLE_STDIO" = x"yes"])
366AM_CONDITIONAL([LIBSERDBG],[test x"$rtems_cv_cc_attribute_weak" = x"yes"])
367AM_CONDITIONAL([LIBGNAT],[test x"$rtems_cv_HAS_POSIX_API" = x"yes" \
368&& test x"$enable_ada" = x"yes"])
369
370AM_CONDITIONAL([LIBUTF8PROC],[test $ac_cv_sizeof_size_t -gt 2])
371
372AM_CONDITIONAL([LIBDOSFS],[dnl
373test x"$ac_cv_type_uint8_t" = xyes \
374&& test x"$ac_cv_type_uint16_t" = xyes])
375
376AC_CONFIG_HEADER(config.h)
377
378## These are needed by the NFS Client
379AC_CHECK_PROG(RPCGEN,rpcgen,rpcgen)
380AM_CONDITIONAL([RPCTOOLS],[test "$RPCGEN" = rpcgen \
381&& test -n "$AWK" \
382&& test "$enable_rpcgen" = yes])
383
384# Filter dynamic loading to only build for architectures that have
385# reloc backends
386AC_MSG_CHECKING([whether CPU supports libdl])
387case $RTEMS_CPU in
388  arm | i386 | m32r | m68k | mips | \
389  moxie | powerpc | sparc)
390   HAVE_LIBDL=yes ;;
391  # bfin has an issue to resolve with libdl. See ticket #2252
392  bfin)
393   HAVE_LIBDL=no ;;
394  # h8300 has an issue to resolve with libdl. See ticket #2284
395  h8300)
396   HAVE_LIBDL=no ;;
397  # lm32 has an issue to resolve with libdl. See ticket #2283
398  lm32)
399   HAVE_LIBDL=no ;;
400  # v850 has an issue to resolve with libdl. See ticket #2260
401  v850)
402   HAVE_LIBDL=no ;;
403  *)
404   HAVE_LIBDL=no ;;
405esac
406AM_CONDITIONAL(LIBDL,[test x"$HAVE_LIBDL" = x"yes"])
407AC_MSG_RESULT([$HAVE_LIBDL])
408
409AC_MSG_CHECKING([whether CPU supports SHA])
410case $RTEMS_CPU in
411  m32c)
412   HAVE_SHA=no ;;
413  *)
414   HAVE_SHA=yes ;;
415esac
416AM_CONDITIONAL(SHA,[test x"$HAVE_SHA" = x"yes"])
417AC_MSG_RESULT([$HAVE_SHA])
418
419# Filter libpci to only build for architectures that have support for it
420AC_MSG_CHECKING([whether CPU supports libpci])
421case $RTEMS_CPU in
422  sparc)
423   HAVE_LIBPCI=yes ;;
424  *)
425   HAVE_LIBPCI=no ;;
426esac
427AM_CONDITIONAL(LIBPCI,[test x"$HAVE_LIBPCI" = x"yes"])
428AC_MSG_RESULT([$HAVE_LIBPCI])
429
430# Filter libdrvmgr to only build for architectures that have support for it
431AC_MSG_CHECKING([whether CPU supports libdrvmgr])
432case $RTEMS_CPU in
433  sparc)
434   HAVE_LIBDRVMGR=yes ;;
435  *)
436   HAVE_LIBDRVMGR=no ;;
437esac
438AM_CONDITIONAL(LIBDRVMGR,[test x"$HAVE_LIBDRVMGR" = x"yes"])
439AC_MSG_RESULT([$HAVE_LIBDRVMGR])
440
441
442RTEMS_AMPOLISH3
443
444# Explicitly list all Makefiles here
445AC_CONFIG_FILES([
446Doxyfile
447Makefile
448dev/Makefile
449rtems/Makefile
450sapi/Makefile
451score/Makefile
452score/cpu/Makefile
453score/cpu/arm/Makefile
454score/cpu/bfin/Makefile
455score/cpu/avr/Makefile
456score/cpu/h8300/Makefile
457score/cpu/i386/Makefile
458score/cpu/lm32/Makefile
459score/cpu/m68k/Makefile
460score/cpu/m32c/Makefile
461score/cpu/m32r/Makefile
462score/cpu/mips/Makefile
463score/cpu/moxie/Makefile
464score/cpu/nios2/Makefile
465score/cpu/or1k/Makefile
466score/cpu/powerpc/Makefile
467score/cpu/sh/Makefile
468score/cpu/sparc/Makefile
469score/cpu/sparc64/Makefile
470score/cpu/v850/Makefile
471score/cpu/no_cpu/Makefile
472posix/Makefile
473libblock/Makefile
474libdrvmgr/Makefile
475libfs/Makefile
476libfs/src/nfsclient/Makefile
477libgnat/Makefile
478libcrypt/Makefile
479libcsupport/Makefile
480libnetworking/Makefile
481libpci/Makefile
482librpc/Makefile
483libmisc/Makefile
484libi2c/Makefile
485libmd/Makefile
486libdl/Makefile
487zlib/Makefile
488ftpd/Makefile
489telnetd/Makefile
490pppd/Makefile
491mghttpd/Makefile
492wrapup/Makefile])
493
494AC_CONFIG_COMMANDS([preinstall-stamp],
495[test -z "$with_multisubdir" && ${MAKE} preinstall-stamp],
496[MAKE=${MAKE}
497with_multisubdir="$with_multisubdir"])
498
499AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.