source: rtems/cpukit/configure.ac @ 2e7f5798

4.11
Last change on this file since 2e7f5798 was 2e7f5798, checked in by WeiY <wei.a.yang@…>, on Jul 15, 2013 at 3:31:13 PM

stdatomic.h support check when configure

  • Property mode set to 100644
File size: 11.5 KB
Line 
1## Process this file with autoconf to produce a configure script.
2
3AC_PREREQ([2.69])
4AC_INIT([rtems-cpukit],[_RTEMS_VERSION],[http://www.rtems.org/bugzilla])
5AC_CONFIG_SRCDIR([score])
6RTEMS_TOP([..],[])
7
8RTEMS_CANONICAL_TARGET_CPU
9
10AM_INIT_AUTOMAKE([no-define nostdinc subdir-objects foreign 1.12.2])
11AM_MAINTAINER_MODE
12
13RTEMS_ENABLE_MULTILIB
14RTEMS_ENABLE_MULTIPROCESSING
15RTEMS_ENABLE_POSIX
16RTEMS_ENABLE_RTEMS_DEBUG
17RTEMS_ENABLE_NETWORKING
18
19RTEMS_ENV_RTEMSCPU
20RTEMS_CHECK_RTEMS_DEBUG
21
22# Is this a supported CPU?
23AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
24if test -d "$srcdir/score/cpu/$RTEMS_CPU"; then
25  AC_MSG_RESULT(yes)
26else
27  AC_MSG_ERROR(no)
28fi
29
30RTEMS_PROG_CC_FOR_TARGET
31RTEMS_PROG_CCAS
32RTEMS_CANONICALIZE_TOOLS
33AM_PROG_CC_C_O
34AC_PROG_RANLIB
35
36RTEMS_CHECK_NEWLIB
37
38# BSD-isms, used throughout the sources
39# Not really used by this configure script
40# FIXME: They should be eliminated if possible.
41AC_CHECK_FUNCS([strsep strcasecmp snprintf])
42AC_CHECK_FUNCS([strdup strndup strncasecmp])
43AC_CHECK_FUNCS([bcopy bcmp])
44AC_CHECK_FUNCS([isascii fileno])
45
46# <FIXME>
47#   Check for functions supplied by newlib >= 1.17.0
48# Newlib's posix/ directory
49AC_CHECK_FUNCS([readdir_r isatty])
50AC_CHECK_FUNCS([creat \
51  opendir closedir readdir rewinddir scandir seekdir \
52  sleep \
53  telldir \
54  usleep],,
55  [rtems_missing_func="$ac_func";break])
56AS_IF([test -n "$rtems_missing_func"],
57  AC_MSG_ERROR([Missing function $rtems_missing_func in libc])])
58AC_CHECK_FUNCS([__assert])
59AC_CHECK_FUNCS([execl execlp execle execv execvp execve])
60AC_CHECK_FUNCS([regcomp regexec regerror regfree])
61
62# Mandated by POSIX, decls not present in some versions of newlib
63AC_CHECK_DECLS([flockfile],[AC_CHECK_FUNCS([flockfile])],,[#include <stdio.h>])
64AC_CHECK_DECLS([funlockfile],[AC_CHECK_FUNCS([funlockfile])],,[#include <stdio.h>])
65AC_CHECK_DECLS([ftrylockfile],[AC_CHECK_FUNCS([ftrylockfile])],,[#include <stdio.h>])
66
67# Newlib proprietary
68AC_CHECK_HEADERS([envlock.h])
69AC_CHECK_DECLS([__env_lock],,,[#include <envlock.h>])
70AC_CHECK_DECLS([__env_unlock],,,[#include <envlock.h>])
71
72# Mandated by POSIX, older newlibs bogusly provided CLOCK_PROCESS_CPUTIME+CLOCK_THREAD_CPUTIME
73AC_CHECK_DECL([CLOCK_PROCESS_CPUTIME_ID],[],[AC_MSG_ERROR([missing define CLOCK_PROCESS_CPUTIME_ID])],[#include <time.h>])
74AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID],[],[AC_MSG_ERROR([missing define CLOCK_THREAD_CPUTIME_ID])],[#include <time.h>])
75
76# Mandated by POSIX, decls not present in some versions of newlib,
77# some versions stubbed in newlib's rtems crt0
78RTEMS_CHECK_FUNC([seteuid],[#include <unistd.h>])
79RTEMS_CHECK_FUNC([geteuid],[#include <unistd.h>])
80RTEMS_CHECK_FUNC([setegid],[#include <unistd.h>])
81RTEMS_CHECK_FUNC([getegid],[#include <unistd.h>])
82RTEMS_CHECK_FUNC([setuid],[#include <unistd.h>])
83RTEMS_CHECK_FUNC([getuid],[#include <unistd.h>])
84RTEMS_CHECK_FUNC([setgid],[#include <unistd.h>])
85RTEMS_CHECK_FUNC([getgid],[#include <unistd.h>])
86RTEMS_CHECK_FUNC([setsid],[#include <unistd.h>])
87RTEMS_CHECK_FUNC([getsid],[#include <unistd.h>])
88RTEMS_CHECK_FUNC([setpgid],[#include <unistd.h>])
89RTEMS_CHECK_FUNC([getpgid],[#include <unistd.h>])
90RTEMS_CHECK_FUNC([setpgrp],[#include <unistd.h>])
91RTEMS_CHECK_FUNC([getpgrp],[#include <unistd.h>])
92
93# pthread-functions not declared in some versions of newlib.
94RTEMS_CHECK_FUNC([pthread_attr_getguardsize],[#include <pthread.h>])
95RTEMS_CHECK_FUNC([pthread_attr_setguardsize],[#include <pthread.h>])
96RTEMS_CHECK_FUNC([pthread_attr_setstack],[#include <pthread.h>])
97RTEMS_CHECK_FUNC([pthread_attr_getstack],[#include <pthread.h>])
98
99# Mandated by POSIX, not declared in some versions of newlib.
100AC_CHECK_DECLS([getrusage],,,[#include sys/resource.h])
101
102# Newlib's unix/ directory
103AC_CHECK_FUNCS([ttyname getcwd])
104# </FIXME>
105
106# Check if the installed toolchain provides these headers
107# and error out if not.
108AC_CHECK_HEADERS([tar.h errno.h sched.h sys/cdefs.h sys/queue.h],,
109  [rtems_missing_header="$ac_header";break])
110AS_IF([test -n "$rtems_missing_header"],
111  AC_MSG_ERROR([Missing required header $rtems_missing_header])])
112
113## error out if libc doesn't provide stdint.h
114AS_IF([test x"${ac_cv_header_stdint_h}" != xyes],
115[AC_MSG_ERROR([Required header stdint.h not found])])
116
117## error out if libc doesn't provide inttypes.h
118AS_IF([test x"${ac_cv_header_inttypes_h}" != xyes],
119[AC_MSG_ERROR([Required header inttypes.h not found])])
120
121AC_HEADER_STDBOOL
122AS_IF([test x"${ac_cv_header_stdbool_h}" != xyes],
123[AC_MSG_ERROR([No sufficient stdbool.h found])])
124
125AC_CHECK_TYPES([ uint8_t,  int8_t])
126AC_CHECK_TYPES([uint16_t, int16_t])
127AC_CHECK_TYPES([uint32_t, int32_t])
128AC_CHECK_TYPES([uint64_t, int64_t])
129AC_CHECK_TYPES([uintmax_t, intmax_t])
130AC_CHECK_TYPES([uintptr_t, intptr_t])
131
132# Some toolchain sanity checks and diagnostics
133RTEMS_CHECK_GCC_SANITY
134
135# These are conditionally defined by the toolchain
136# FIXME: we should either conditionally compile those parts in
137# RTEMS depending on them, or abort - For now, simply check.
138AC_CHECK_HEADER([pthread.h],[
139  AC_CHECK_TYPES([pthread_rwlock_t])
140  AC_CHECK_TYPES([pthread_barrier_t])
141  AC_CHECK_TYPES([pthread_spinlock_t])
142])
143
144AC_CHECK_HEADER([signal.h],[
145  AC_CHECK_TYPES([sighandler_t])
146])
147
148RTEMS_CHECK_MULTIPROCESSING
149RTEMS_CHECK_POSIX_API
150RTEMS_CHECK_NETWORKING
151RTEMS_CHECK_SMP
152RTEMS_CHECK_ATOMIC
153
154rtems_major=`echo _RTEMS_VERSION | sed "s/\..*//"`
155rtems_minor=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/\..*//"`
156rtems_revision=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/[[0-9]][[0-9]]*\.//;s/\..*//"`
157
158_RTEMS_CPUOPT_INIT
159
160RTEMS_CPUOPT([RTEMS_DEBUG],
161  [test x"${enable_rtems_debug}" = x"yes"],
162  [1],
163  [if RTEMS_DEBUG is enabled])
164
165RTEMS_CPUOPT([RTEMS_MULTIPROCESSING],
166  [test x"$enable_multiprocessing" = xyes],
167  [1],
168  [if multiprocessing is enabled])
169
170RTEMS_CPUOPT([RTEMS_NEWLIB],
171  [test x"$RTEMS_USE_NEWLIB" = xyes],
172  [1],
173  [if using newlib])
174
175RTEMS_CPUOPT([RTEMS_POSIX_API],
176  [test x"$rtems_cv_HAS_POSIX_API" = xyes],
177  [1],
178  [if posix api is supported])
179
180RTEMS_CPUOPT([RTEMS_SMP],
181  [test x"$RTEMS_HAS_SMP" = xyes],
182  [1],
183  [if SMP is enabled])
184
185RTEMS_CPUOPT([RTEMS_NETWORKING],
186  [test x"$rtems_cv_HAS_NETWORKING" = xyes],
187  [1],
188  [if networking is enabled])
189
190RTEMS_CPUOPT([RTEMS_ATOMIC],
191  [test x"$rtems_cv_ATOMIC" = xyes],
192  [1],
193  [if cpu supports atomic operations])
194
195RTEMS_CPUOPT([RTEMS_VERSION],
196  [true],
197  ["]_RTEMS_VERSION["],
198  [RTEMS version string])
199
200RTEMS_CPUOPT([__RTEMS_USE_TICKS_FOR_STATISTICS__],
201  [test x"${USE_TICKS_FOR_STATISTICS}" = x"1"],
202  [1],
203  [disable nanosecond granularity for statistics])
204
205## This improves both the size and coverage analysis.
206RTEMS_CPUOPT([__RTEMS_DO_NOT_INLINE_THREAD_ENABLE_DISPATCH__],
207  [test x"${RTEMS_DO_NOT_INLINE_THREAD_ENABLE_DISPATCH}" = x"1"],
208  [1],
209  [disable inlining _Thread_Enable_dispatch])
210
211## This improves both the size and coverage analysis.
212RTEMS_CPUOPT([__RTEMS_DO_NOT_INLINE_CORE_MUTEX_SEIZE__],
213  [test x"${RTEMS_DO_NOT_INLINE_CORE_MUTEX_SEIZE}" = x"1"],
214  [1],
215  [disable inlining _Thread_Enable_dispatch])
216
217## This improves both the size and coverage analysis.
218RTEMS_CPUOPT([__RTEMS_DO_NOT_UNROLL_THREADQ_ENQUEUE_PRIORITY__],
219  [test x"${RTEMS_DO_NOT_UNROLL_THREADQ_ENQUEUE_PRIORITY}" = x"1"],
220  [1],
221  [disable inlining _Thread_queue_Enqueue_priority])
222
223## This gives the same behavior as 4.8 and older
224RTEMS_CPUOPT([__RTEMS_STRICT_ORDER_MUTEX__],
225  [test x"${ENABLE_STRICT_ORDER_MUTEX}" = x"1"],
226  [1],
227  [disable strict order mutex])
228
229## Deactivate ada bindings
230RTEMS_CPUOPT([__RTEMS_ADA__],
231  [test x"${enable_ada}" = x"yes"],
232  [1],
233  [Define to 1 if ada/gnat bindings are built-in])
234
235## Then we propagate a private copy of the value into cpuopts.h
236## so it is always available to the RTEMS header files.
237
238RTEMS_CPUOPT([__RTEMS_MAJOR__],
239  [true],
240  [$rtems_major],
241  [major version portion of an RTEMS release])
242
243RTEMS_CPUOPT([__RTEMS_MINOR__],
244  [true],
245  [$rtems_minor],
246  [minor version portion of an RTEMS release])
247
248RTEMS_CPUOPT([__RTEMS_REVISION__],
249  [true],
250  [$rtems_revision],
251  [revision version portion of an RTEMS release])
252
253_RTEMS_CPUOPT_FINI
254
255AC_ENABLE_MULTILIB([Makefile],[..])
256
257# libmisc/shell/* wants to assign file descriptors to stdio file descriptors.
258AC_MSG_CHECKING([for assignable stdio])
259AC_COMPILE_IFELSE(
260  [AC_LANG_PROGRAM(
261    [#include <stdio.h>],
262    [stdin = fopen("/tmp", "r")])],
263  [HAVE_ASSIGNABLE_STDIO=yes],
264  [HAVE_ASSIGNABLE_STDIO=no])
265AC_MSG_RESULT([$HAVE_ASSIGNABLE_STDIO])
266
267# libmisc/serdbg exploits weak symbols
268RTEMS_CHECK_GCC_WEAK
269
270# FIXME: These checks are only in here to provide
271# configuration-time diagnostics and are not really used.
272AC_CHECK_DECLS([_POSIX_LOGIN_NAME_MAX],,,[#include <limits.h>])
273AC_CHECK_DECLS([CHAR_BIT],,,[#include <limits.h>])
274
275# FIXME: We should get rid of this.
276# So far, only used in libfs/src/nfsclient/src/dirutils.c
277AC_CHECK_SIZEOF([mode_t])
278AC_CHECK_SIZEOF([off_t])
279
280# FIXME: We should get rid of this. It's a cludge.
281AC_CHECK_SIZEOF([time_t])
282
283# FIXME: Mandatory in SUSv4, optional in SUSv3.
284#   Not implemented in GCC/newlib, so far.
285AC_CHECK_DECLS([WORD_BIT],,,[#include <limits.h>])
286AC_CHECK_DECLS([LONG_BIT],,,[#include <limits.h>])
287
288## BSD-ism, excluded from POSIX, but available on most platforms
289AC_CHECK_DECLS([sbrk],,,[#include <unistd.h>])
290AC_CHECK_DECLS([rcmd],,,[#include <unistd.h>])
291
292## Check if libc provides BSD's strlcpy/strlcat
293AC_CHECK_FUNCS(strlcpy strlcat)
294
295## Check if libc provides decl of utime
296## FIXME: utime has been deprecated in SUSv4.
297##        and is likely to be removed in future versions.
298## FIXME (BUG in newlib): SUSv4 saids including <utime.h> should be sufficient.
299AC_CHECK_DECLS([utime],,,[#include <sys/types.h>
300#include <utime.h>])
301## Check if libc provides decl of utimes
302AC_CHECK_DECLS([utimes],,,[#include <sys/time.h>])
303
304# ... far too many conditionals ...
305AM_CONDITIONAL(LIBRPC,[test x"$rtems_cv_HAS_NETWORKING" = x"yes"])
306AM_CONDITIONAL(NEWLIB,test x"$RTEMS_USE_NEWLIB" = x"yes")
307
308AM_CONDITIONAL(HAS_MP,test x"$enable_multiprocessing" = x"yes" )
309AM_CONDITIONAL(HAS_SMP,[test "$RTEMS_HAS_SMP" = "yes"])
310
311AM_CONDITIONAL(HAS_PTHREADS,test x"$rtems_cv_HAS_POSIX_API" = x"yes")
312AM_CONDITIONAL(LIBNETWORKING,test x"$rtems_cv_HAS_NETWORKING" = x"yes")
313AM_CONDITIONAL([ATOMIC],[test x"$rtems_cv_ATOMIC" = x"yes"])
314
315AM_CONDITIONAL([LIBSHELL],[test x"$HAVE_ASSIGNABLE_STDIO" = x"yes"])
316AM_CONDITIONAL([LIBSERDBG],[test x"$rtems_cv_cc_attribute_weak" = x"yes"])
317AM_CONDITIONAL([LIBGNAT],[test x"$rtems_cv_HAS_POSIX_API" = x"yes" \
318&& test x"$enable_ada" = x"yes"])
319
320AM_CONDITIONAL([LIBDOSFS],[dnl
321test x"$ac_cv_type_uint8_t" = xyes \
322&& test x"$ac_cv_type_uint16_t" = xyes])
323
324AC_CONFIG_HEADER(config.h)
325
326## These are needed by the NFS Client
327AC_CHECK_PROG(RPCGEN,rpcgen,rpcgen)
328AM_CONDITIONAL([RPCTOOLS],[test "$RPCGEN" = rpcgen \
329&& test -n "$AWK" \
330&& test "$enable_rpcgen" = yes])
331
332RTEMS_AMPOLISH3
333
334# Explicitly list all Makefiles here
335AC_CONFIG_FILES([
336Doxyfile
337Makefile
338rtems/Makefile
339sapi/Makefile
340score/Makefile
341score/cpu/Makefile
342score/cpu/arm/Makefile
343score/cpu/bfin/Makefile
344score/cpu/avr/Makefile
345score/cpu/h8300/Makefile
346score/cpu/i386/Makefile
347score/cpu/lm32/Makefile
348score/cpu/m68k/Makefile
349score/cpu/m32c/Makefile
350score/cpu/m32r/Makefile
351score/cpu/mips/Makefile
352score/cpu/moxie/Makefile
353score/cpu/nios2/Makefile
354score/cpu/powerpc/Makefile
355score/cpu/sh/Makefile
356score/cpu/sparc/Makefile
357score/cpu/sparc64/Makefile
358score/cpu/v850/Makefile
359score/cpu/no_cpu/Makefile
360posix/Makefile
361libblock/Makefile
362libfs/Makefile
363libfs/src/nfsclient/Makefile
364libgnat/Makefile
365libcsupport/Makefile
366libnetworking/Makefile
367librpc/Makefile
368libmisc/Makefile
369libi2c/Makefile
370libmd/Makefile
371zlib/Makefile
372ftpd/Makefile
373telnetd/Makefile
374pppd/Makefile
375mghttpd/Makefile
376wrapup/Makefile])
377
378AC_CONFIG_COMMANDS([preinstall-stamp],
379[test -z "$with_multisubdir" && ${MAKE} preinstall-stamp],
380[MAKE=${MAKE}
381with_multisubdir="$with_multisubdir"])
382
383AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.