source: rtems/cpukit/configure.ac @ 15068f4c

Last change on this file since 15068f4c was 15068f4c, checked in by Joel Sherrill <joel@…>, on Jan 20, 2016 at 1:38:35 AM

Remove AVR port

closes #2443.

  • Property mode set to 100644
File size: 14.8 KB
Line 
1## Process this file with autoconf to produce a configure script.
2
3AC_PREREQ([2.69])
4AC_INIT([rtems-cpukit],[_RTEMS_VERSION],[https://devel.rtems.org/newticket])
5AC_CONFIG_SRCDIR([score])
6RTEMS_TOP([..],[])
7
8RTEMS_CANONICAL_TARGET_CPU
9
10AM_INIT_AUTOMAKE([no-define nostdinc subdir-objects foreign 1.12.2])
11AM_MAINTAINER_MODE
12
13RTEMS_ENABLE_MULTILIB
14RTEMS_ENABLE_MULTIPROCESSING
15RTEMS_ENABLE_POSIX
16RTEMS_ENABLE_RTEMS_DEBUG
17RTEMS_ENABLE_NETWORKING
18RTEMS_ENABLE_PARAVIRT
19RTEMS_ENABLE_PROFILING
20RTEMS_ENABLE_DRVMGR
21
22RTEMS_ENV_RTEMSCPU
23RTEMS_CHECK_RTEMS_DEBUG
24
25# Is this a supported CPU?
26AC_MSG_CHECKING([if cpu $RTEMS_CPU is supported])
27if test -d "$srcdir/score/cpu/$RTEMS_CPU"; then
28  AC_MSG_RESULT(yes)
29else
30  AC_MSG_ERROR(no)
31fi
32
33RTEMS_PROG_CC_FOR_TARGET
34RTEMS_PROG_CCAS
35RTEMS_CANONICALIZE_TOOLS
36AM_PROG_CC_C_O
37AC_PROG_RANLIB
38
39RTEMS_CHECK_NEWLIB
40
41# BSD-isms, used throughout the sources
42# Not really used by this configure script
43# FIXME: They should be eliminated if possible.
44AC_CHECK_FUNCS([strsep strcasecmp snprintf])
45AC_CHECK_FUNCS([strdup strndup strncasecmp])
46AC_CHECK_FUNCS([bcopy bcmp])
47AC_CHECK_FUNCS([isascii fileno])
48
49# <FIXME>
50#   Check for functions supplied by newlib >= 1.17.0
51# Newlib's posix/ directory
52AC_CHECK_FUNCS([readdir_r isatty])
53AC_CHECK_FUNCS([creat \
54  opendir closedir readdir rewinddir scandir seekdir \
55  sleep \
56  telldir \
57  usleep],,
58  [rtems_missing_func="$ac_func";break])
59AS_IF([test -n "$rtems_missing_func"],
60  AC_MSG_ERROR([Missing function $rtems_missing_func in libc])])
61AC_CHECK_FUNCS([__assert])
62AC_CHECK_FUNCS([execl execlp execle execv execvp execve])
63AC_CHECK_FUNCS([regcomp regexec regerror regfree])
64
65# Mandated by POSIX, decls not present in some versions of newlib
66AC_CHECK_DECLS([flockfile],[AC_CHECK_FUNCS([flockfile])],,[#include <stdio.h>])
67AC_CHECK_DECLS([funlockfile],[AC_CHECK_FUNCS([funlockfile])],,[#include <stdio.h>])
68AC_CHECK_DECLS([ftrylockfile],[AC_CHECK_FUNCS([ftrylockfile])],,[#include <stdio.h>])
69
70# Newlib proprietary
71AC_CHECK_HEADERS([envlock.h])
72AC_CHECK_DECLS([__env_lock],,,[#include <envlock.h>])
73AC_CHECK_DECLS([__env_unlock],,,[#include <envlock.h>])
74AC_CHECK_TYPES([struct _Thread_queue_Queue],[],[],[#include <sys/lock.h>])
75
76# Mandated by POSIX, older newlibs bogusly provided CLOCK_PROCESS_CPUTIME+CLOCK_THREAD_CPUTIME
77AC_CHECK_DECL([CLOCK_PROCESS_CPUTIME_ID],[],[AC_MSG_ERROR([missing define CLOCK_PROCESS_CPUTIME_ID])],[#include <time.h>])
78AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID],[],[AC_MSG_ERROR([missing define CLOCK_THREAD_CPUTIME_ID])],[#include <time.h>])
79
80# Mandated by POSIX, decls not present in some versions of newlib,
81# some versions stubbed in newlib's rtems crt0
82RTEMS_CHECK_FUNC([seteuid],[#include <unistd.h>])
83RTEMS_CHECK_FUNC([geteuid],[#include <unistd.h>])
84RTEMS_CHECK_FUNC([setegid],[#include <unistd.h>])
85RTEMS_CHECK_FUNC([getegid],[#include <unistd.h>])
86RTEMS_CHECK_FUNC([setuid],[#include <unistd.h>])
87RTEMS_CHECK_FUNC([getuid],[#include <unistd.h>])
88RTEMS_CHECK_FUNC([setgid],[#include <unistd.h>])
89RTEMS_CHECK_FUNC([getgid],[#include <unistd.h>])
90RTEMS_CHECK_FUNC([setsid],[#include <unistd.h>])
91RTEMS_CHECK_FUNC([getsid],[#include <unistd.h>])
92RTEMS_CHECK_FUNC([setpgid],[#include <unistd.h>])
93RTEMS_CHECK_FUNC([getpgid],[#include <unistd.h>])
94RTEMS_CHECK_FUNC([setpgrp],[#include <unistd.h>])
95RTEMS_CHECK_FUNC([getpgrp],[#include <unistd.h>])
96
97# pthread-functions not declared in some versions of newlib.
98RTEMS_CHECK_FUNC([pthread_attr_getguardsize],[#include <pthread.h>])
99RTEMS_CHECK_FUNC([pthread_attr_setguardsize],[#include <pthread.h>])
100RTEMS_CHECK_FUNC([pthread_attr_setstack],[#include <pthread.h>])
101RTEMS_CHECK_FUNC([pthread_attr_getstack],[#include <pthread.h>])
102
103# These are SMP related and were added to newlib by RTEMS.
104RTEMS_CHECK_FUNC([pthread_attr_setaffinity_np],[
105  #define _GNU_SOURCE
106  #include <pthread.h>])
107RTEMS_CHECK_FUNC([pthread_attr_getaffinity_np],[
108  #define _GNU_SOURCE
109  #include <pthread.h>])
110RTEMS_CHECK_FUNC([pthread_setaffinity_np],[
111  #define _GNU_SOURCE
112  #include <pthread.h>])
113RTEMS_CHECK_FUNC([pthread_getaffinity_np],[
114  #define _GNU_SOURCE
115  #include <pthread.h>])
116RTEMS_CHECK_FUNC([pthread_getattr_np],[
117  #define _GNU_SOURCE
118  #include <pthread.h>])
119AC_CHECK_HEADERS([sys/cpuset.h])
120
121# This was added to newlib in August 2014 to improve conformance.
122# Disable use of internal definition if it is present.
123RTEMS_CHECK_FUNC([sigaltstack],[
124  #define _GNU_SOURCE
125  #include <signal.h>])
126
127# Mandated by POSIX, not declared in some versions of newlib.
128AC_CHECK_DECLS([getrusage],,,[#include sys/resource.h])
129
130# Newlib's unix/ directory
131AC_CHECK_FUNCS([ttyname getcwd])
132# </FIXME>
133
134# Check if the installed toolchain provides these headers
135# and error out if not.
136AC_CHECK_HEADERS([tar.h errno.h sched.h sys/cdefs.h sys/queue.h],,
137  [rtems_missing_header="$ac_header";break])
138AS_IF([test -n "$rtems_missing_header"],
139  AC_MSG_ERROR([Missing required header $rtems_missing_header])])
140
141AC_CHECK_HEADERS([semaphore.h])
142AM_CONDITIONAL([HAVE_SEMAPHORE_H],[test x"$ac_cv_header_semaphore_h" = x"yes"])
143
144AC_CHECK_HEADERS([threads.h])
145AM_CONDITIONAL([HAVE_THREADS_H],[test x"$ac_cv_header_threads_h" = x"yes"])
146
147## error out if libc doesn't provide stdint.h
148AS_IF([test x"${ac_cv_header_stdint_h}" != xyes],
149[AC_MSG_ERROR([Required header stdint.h not found])])
150
151## error out if libc doesn't provide inttypes.h
152AS_IF([test x"${ac_cv_header_inttypes_h}" != xyes],
153[AC_MSG_ERROR([Required header inttypes.h not found])])
154
155AC_HEADER_STDBOOL
156AS_IF([test x"${ac_cv_header_stdbool_h}" != xyes],
157[AC_MSG_ERROR([No sufficient stdbool.h found])])
158
159AC_CHECK_TYPES([ uint8_t,  int8_t])
160AC_CHECK_TYPES([uint16_t, int16_t])
161AC_CHECK_TYPES([uint32_t, int32_t])
162AC_CHECK_TYPES([uint64_t, int64_t])
163AC_CHECK_TYPES([uintmax_t, intmax_t])
164AC_CHECK_TYPES([uintptr_t, intptr_t])
165
166# Some toolchain sanity checks and diagnostics
167RTEMS_CHECK_GCC_SANITY
168
169# These are conditionally defined by the toolchain
170# FIXME: we should either conditionally compile those parts in
171# RTEMS depending on them, or abort - For now, simply check.
172AC_CHECK_HEADER([pthread.h],[
173  AC_CHECK_TYPES([pthread_rwlock_t])
174  AC_CHECK_TYPES([pthread_barrier_t])
175  AC_CHECK_TYPES([pthread_spinlock_t])
176  AC_CHECK_TYPES([struct _pthread_cleanup_context],[],[AC_MSG_ERROR([struct _pthread_cleanup_context in <pthread.h> is mandatory])],[#include <pthread.h>])
177])
178
179AC_CHECK_HEADER([signal.h],[
180  AC_CHECK_TYPES([sighandler_t])
181])
182
183if test x"$RTEMS_USE_NEWLIB" = xyes ; then
184  AC_CHECK_DECLS([__getreent],[],[AC_MSG_ERROR([__getreent() in <sys/reent.h> is mandatory])],[#include <sys/reent.h>])
185fi
186
187RTEMS_CHECK_MULTIPROCESSING
188RTEMS_CHECK_POSIX_API
189RTEMS_CHECK_NETWORKING
190RTEMS_CHECK_SMP
191if test "${RTEMS_HAS_SMP}" = "yes"; then
192  AC_CHECK_HEADERS([stdatomic.h],[],[AC_MSG_ERROR([<stdatomic.h> is required for SMP support])])
193fi
194
195rtems_major=`echo _RTEMS_VERSION | sed "s/\..*//"`
196rtems_minor=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/\..*//"`
197rtems_revision=`echo _RTEMS_VERSION | sed "s/[[0-9]][[0-9]]*\.//;s/[[0-9]][[0-9]]*\.//;s/\..*//"`
198
199_RTEMS_CPUOPT_INIT
200
201RTEMS_CPUOPT([RTEMS_DEBUG],
202  [test x"${enable_rtems_debug}" = x"yes"],
203  [1],
204  [if RTEMS_DEBUG is enabled])
205
206RTEMS_CPUOPT([RTEMS_MULTIPROCESSING],
207  [test x"$enable_multiprocessing" = xyes],
208  [1],
209  [if multiprocessing is enabled])
210
211RTEMS_CPUOPT([RTEMS_NEWLIB],
212  [test x"$RTEMS_USE_NEWLIB" = xyes],
213  [1],
214  [if using newlib])
215
216RTEMS_CPUOPT([RTEMS_POSIX_API],
217  [test x"$rtems_cv_HAS_POSIX_API" = xyes],
218  [1],
219  [if posix api is supported])
220
221RTEMS_CPUOPT([RTEMS_SMP],
222  [test x"$RTEMS_HAS_SMP" = xyes],
223  [1],
224  [if SMP is enabled])
225
226RTEMS_CPUOPT([RTEMS_PARAVIRT],
227  [test x"$RTEMS_HAS_PARAVIRT" = xyes],
228  [1],
229  [PARAVIRT is enabled])
230
231RTEMS_CPUOPT([RTEMS_PROFILING],
232  [test x"$RTEMS_HAS_PROFILING" = xyes],
233  [1],
234  [if profiling is enabled])
235
236RTEMS_CPUOPT([RTEMS_NETWORKING],
237  [test x"$rtems_cv_HAS_NETWORKING" = xyes],
238  [1],
239  [if networking is enabled])
240
241RTEMS_CPUOPT([RTEMS_DRVMGR_STARTUP],
242  [test x"$enable_drvmgr" = xyes],
243  [1],
244  [if driver manager api is supported])
245
246RTEMS_CPUOPT([RTEMS_VERSION],
247  [true],
248  ["]_RTEMS_VERSION["],
249  [RTEMS version string])
250
251## Header file differences that need to be known in .h after install
252RTEMS_CPUOPT([__RTEMS_HAVE_SYS_CPUSET_H__],
253  [test x"${ac_cv_header_sys_cpuset_h}" = x"yes"],
254  [1],
255  [indicate if <sys/cpuset.h> is present in toolset])
256
257## Header file differences that need to be known in .h after install
258RTEMS_CPUOPT([__RTEMS_HAVE_DECL_SIGALTSTACK__],
259  [test x"${ac_cv_have_decl_sigaltstack}" = x"yes"],
260  [1],
261  [indicate if <signal.h> in toolset has sigaltstack()])
262
263## This improves both the size and coverage analysis.
264RTEMS_CPUOPT([__RTEMS_DO_NOT_INLINE_THREAD_ENABLE_DISPATCH__],
265  [test x"${RTEMS_DO_NOT_INLINE_THREAD_ENABLE_DISPATCH}" = x"1"],
266  [1],
267  [disable inlining _Thread_Enable_dispatch])
268
269## This improves both the size and coverage analysis.
270RTEMS_CPUOPT([__RTEMS_DO_NOT_INLINE_CORE_MUTEX_SEIZE__],
271  [test x"${RTEMS_DO_NOT_INLINE_CORE_MUTEX_SEIZE}" = x"1"],
272  [1],
273  [disable inlining _Thread_Enable_dispatch])
274
275## This gives the same behavior as 4.8 and older
276RTEMS_CPUOPT([__RTEMS_STRICT_ORDER_MUTEX__],
277  [test x"${ENABLE_STRICT_ORDER_MUTEX}" = x"1"],
278  [1],
279  [disable strict order mutex])
280
281## Deactivate ada bindings
282RTEMS_CPUOPT([__RTEMS_ADA__],
283  [test x"${enable_ada}" = x"yes"],
284  [1],
285  [Define to 1 if ada/gnat bindings are built-in])
286
287## Then we propagate a private copy of the value into cpuopts.h
288## so it is always available to the RTEMS header files.
289
290RTEMS_CPUOPT([__RTEMS_MAJOR__],
291  [true],
292  [$rtems_major],
293  [major version portion of an RTEMS release])
294
295RTEMS_CPUOPT([__RTEMS_MINOR__],
296  [true],
297  [$rtems_minor],
298  [minor version portion of an RTEMS release])
299
300RTEMS_CPUOPT([__RTEMS_REVISION__],
301  [true],
302  [$rtems_revision],
303  [revision version portion of an RTEMS release])
304
305_RTEMS_CPUOPT_FINI
306
307AC_ENABLE_MULTILIB([Makefile],[..])
308
309# libmisc/shell/* wants to assign file descriptors to stdio file descriptors.
310AC_MSG_CHECKING([for assignable stdio])
311AC_COMPILE_IFELSE(
312  [AC_LANG_PROGRAM(
313    [#include <stdio.h>],
314    [stdin = fopen("/tmp", "r")])],
315  [HAVE_ASSIGNABLE_STDIO=yes],
316  [HAVE_ASSIGNABLE_STDIO=no])
317AC_MSG_RESULT([$HAVE_ASSIGNABLE_STDIO])
318
319# libmisc/serdbg exploits weak symbols
320RTEMS_CHECK_GCC_WEAK
321
322# FIXME: These checks are only in here to provide
323# configuration-time diagnostics and are not really used.
324AC_CHECK_DECLS([_POSIX_LOGIN_NAME_MAX],,,[#include <limits.h>])
325AC_CHECK_DECLS([CHAR_BIT],,,[#include <limits.h>])
326
327# FIXME: We should get rid of this.
328# So far, only used in libfs/src/nfsclient/src/dirutils.c
329AC_CHECK_SIZEOF([mode_t])
330AC_CHECK_SIZEOF([off_t])
331
332# FIXME: We should get rid of this. It's a cludge.
333AC_CHECK_SIZEOF([time_t])
334
335AC_CHECK_SIZEOF([size_t])
336
337# FIXME: Mandatory in SUSv4, optional in SUSv3.
338#   Not implemented in GCC/newlib, so far.
339AC_CHECK_DECLS([WORD_BIT],,,[#include <limits.h>])
340AC_CHECK_DECLS([LONG_BIT],,,[#include <limits.h>])
341
342## BSD-ism, excluded from POSIX, but available on most platforms
343AC_CHECK_DECLS([sbrk],,,[#include <unistd.h>])
344AC_CHECK_DECLS([rcmd],,,[#include <unistd.h>])
345
346## Check if libc provides BSD's strlcpy/strlcat
347AC_CHECK_FUNCS(strlcpy strlcat)
348
349## Check if libc provides decl of utime
350## FIXME: utime has been deprecated in SUSv4.
351##        and is likely to be removed in future versions.
352## FIXME (BUG in newlib): SUSv4 saids including <utime.h> should be sufficient.
353AC_CHECK_DECLS([utime],,,[#include <sys/types.h>
354#include <utime.h>])
355## Check if libc provides decl of utimes
356AC_CHECK_DECLS([utimes],,,[#include <sys/time.h>])
357
358# ... far too many conditionals ...
359AM_CONDITIONAL(LIBRPC,[test x"$rtems_cv_HAS_NETWORKING" = x"yes"])
360AM_CONDITIONAL(NEWLIB,test x"$RTEMS_USE_NEWLIB" = x"yes")
361
362AM_CONDITIONAL(HAS_MP,test x"$enable_multiprocessing" = x"yes" )
363AM_CONDITIONAL(HAS_SMP,[test "$RTEMS_HAS_SMP" = "yes"])
364
365AM_CONDITIONAL(HAS_PTHREADS,test x"$rtems_cv_HAS_POSIX_API" = x"yes")
366AM_CONDITIONAL(LIBNETWORKING,test x"$rtems_cv_HAS_NETWORKING" = x"yes")
367
368AM_CONDITIONAL([LIBSHELL],[test x"$HAVE_ASSIGNABLE_STDIO" = x"yes"])
369AM_CONDITIONAL([LIBSERDBG],[test x"$rtems_cv_cc_attribute_weak" = x"yes"])
370AM_CONDITIONAL([LIBGNAT],[test x"$rtems_cv_HAS_POSIX_API" = x"yes" \
371&& test x"$enable_ada" = x"yes"])
372
373AM_CONDITIONAL([LIBUTF8PROC],[test $ac_cv_sizeof_size_t -gt 2])
374
375AM_CONDITIONAL([LIBDOSFS],[dnl
376test x"$ac_cv_type_uint8_t" = xyes \
377&& test x"$ac_cv_type_uint16_t" = xyes])
378
379AC_CONFIG_HEADER(config.h)
380
381## These are needed by the NFS Client
382AC_CHECK_PROG(RPCGEN,rpcgen,rpcgen)
383AM_CONDITIONAL([RPCTOOLS],[test "$RPCGEN" = rpcgen \
384&& test -n "$AWK" \
385&& test "$enable_rpcgen" = yes])
386
387# Filter dynamic loading to only build for architectures that have
388# reloc backends
389AC_MSG_CHECKING([whether CPU supports libdl])
390case $RTEMS_CPU in
391  arm | i386 | m68k | mips | moxie | powerpc | sparc)
392   HAVE_LIBDL=yes ;;
393  # bfin has an issue to resolve with libdl. See ticket #2252
394  bfin)
395   HAVE_LIBDL=no ;;
396  # lm32 has an issue to resolve with libdl. See ticket #2283
397  lm32)
398   HAVE_LIBDL=no ;;
399  # v850 has an issue to resolve with libdl. See ticket #2260
400  v850)
401   HAVE_LIBDL=no ;;
402  *)
403   HAVE_LIBDL=no ;;
404esac
405AM_CONDITIONAL(LIBDL,[test x"$HAVE_LIBDL" = x"yes"])
406AC_MSG_RESULT([$HAVE_LIBDL])
407
408AC_MSG_CHECKING([whether CPU supports SHA])
409case $RTEMS_CPU in
410  m32c)
411   HAVE_SHA=no ;;
412  *)
413   HAVE_SHA=yes ;;
414esac
415AM_CONDITIONAL(SHA,[test x"$HAVE_SHA" = x"yes"])
416AC_MSG_RESULT([$HAVE_SHA])
417
418# Filter libpci to only build for architectures that have support for it
419AC_MSG_CHECKING([whether CPU supports libpci])
420case $RTEMS_CPU in
421  sparc)
422   HAVE_LIBPCI=yes ;;
423  *)
424   HAVE_LIBPCI=no ;;
425esac
426AM_CONDITIONAL(LIBPCI,[test x"$HAVE_LIBPCI" = x"yes"])
427AC_MSG_RESULT([$HAVE_LIBPCI])
428
429# Filter libdrvmgr to only build for architectures that have support for it
430AC_MSG_CHECKING([whether CPU supports libdrvmgr])
431case $RTEMS_CPU in
432  sparc)
433   HAVE_LIBDRVMGR=yes ;;
434  *)
435   HAVE_LIBDRVMGR=no ;;
436esac
437AM_CONDITIONAL(LIBDRVMGR,[test x"$HAVE_LIBDRVMGR" = x"yes"])
438AC_MSG_RESULT([$HAVE_LIBDRVMGR])
439
440
441RTEMS_AMPOLISH3
442
443# Explicitly list all Makefiles here
444AC_CONFIG_FILES([
445Doxyfile
446Makefile
447dev/Makefile
448dtc/libfdt/Makefile
449rtems/Makefile
450sapi/Makefile
451score/Makefile
452score/cpu/Makefile
453score/cpu/arm/Makefile
454score/cpu/bfin/Makefile
455score/cpu/epiphany/Makefile
456score/cpu/i386/Makefile
457score/cpu/lm32/Makefile
458score/cpu/m68k/Makefile
459score/cpu/m32c/Makefile
460score/cpu/mips/Makefile
461score/cpu/moxie/Makefile
462score/cpu/nios2/Makefile
463score/cpu/or1k/Makefile
464score/cpu/powerpc/Makefile
465score/cpu/sh/Makefile
466score/cpu/sparc/Makefile
467score/cpu/sparc64/Makefile
468score/cpu/v850/Makefile
469score/cpu/no_cpu/Makefile
470posix/Makefile
471libblock/Makefile
472libdrvmgr/Makefile
473libfs/Makefile
474libfs/src/nfsclient/Makefile
475libgnat/Makefile
476libcrypt/Makefile
477libcsupport/Makefile
478libnetworking/Makefile
479libpci/Makefile
480librpc/Makefile
481libmisc/Makefile
482libi2c/Makefile
483libmd/Makefile
484libdl/Makefile
485libstdthreads/Makefile
486zlib/Makefile
487ftpd/Makefile
488telnetd/Makefile
489pppd/Makefile
490mghttpd/Makefile
491wrapup/Makefile])
492
493AC_CONFIG_COMMANDS([preinstall-stamp],
494[test -z "$with_multisubdir" && ${MAKE} preinstall-stamp],
495[MAKE=${MAKE}
496with_multisubdir="$with_multisubdir"])
497
498AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.