source: rtems/contrib/crossrpms/configure.ac @ 15fcf913

## $Id$

m4_define([RTEMS_API],[4.7])

AC_PREREQ(2.59)
AC_INIT([crossrpms],[0.20060625.0],[rtems-bugs@rtems.com])
AC_CONFIG_SRCDIR([binutils/binutils.add])
AC_CONFIG_AUX_DIR(.)

AC_CANONICAL_HOST
AC_CANONICAL_TARGET

AC_PREFIX_DEFAULT([/opt/rtems-][RTEMS_API])

AM_INIT_AUTOMAKE([1.9])

AC_ARG_ENABLE([targets],
  AS_HELP_STRING([--enable-targets=<targets>],[build for targets <targets>]),
  [targets="$enable_targets"],
  [targets=rtems]
)

case $targets in
rtems )
  savdir=`pwd`
  cd $srcdir
  targets=
  for d in rtems4.7/*/gcc-sources.add; do
      b=`echo $d | sed -e 's,rtems4.7/,,;s,/gcc-sources.add,,'`
      targets="$targets $b-rtems4.7"
  done
  cd $savdir
  ;;
all )
  savdir=`pwd`
  cd $srcdir
  targets=
  for d in rtems*/*/gcc-sources.add; do
      o=`echo $d | sed -e 's,/.*,,'`
      a=`echo $d | sed -e 's,/gcc-sources.add,,;s,.*/,,'`
      targets="$targets $a-$o"
  done
  for d in cygwin*/*/gcc-sources.add mingw*/*/gcc-sources.add \
      freebsd*/*/gcc-sources.add; do
      o=`echo $d | sed -e 's,/.*,,'`
      a=`echo $d | sed -e 's,/gcc-sources.add,,;s,.*/,,'`
      targets="$targets $a-pc-$o"
  done
  cd $savdir
  ;;
esac

case "$prefix" in
/usr)
  build_infos=0
  sysdirpattern="/%sysdir/d"
  rpmprefix=
  ;;
/usr/local)
  build_infos=0
  sysdirpattern="/%sysdir/d"
  rpmprefix="local-"
  ;;
/opt/rtems)
  build_infos=1
  sysdirpattern="s/^%sysdir/%dir/g"
  rpmprefix="rtems-"
  ;;
NONE|${ac_default_prefix}) # Default prefix
  build_infos=1
  sysdirpattern="s/^%sysdir/%dir/g"
  rpmprefix="[rtems-]RTEMS_API[-]"
  ;;
*)
  build_infos=0
  sysdirpattern="s/^%sysdir/%dir/g"
  rpmprefix="custom-"
  ;;
esac
AC_SUBST(sysdirpattern)

AC_ARG_ENABLE([rpmprefix],
[  --enable-rpmprefix=<rpmprefix>      prefix rpms],[
  case "$enable_rpmprefix" in
  yes) # ignore, use default
    ;;
  no) rpmprefix=
    ;;
  *) # presume user knows what he is doing
    rpmprefix=$enable_rpmprefix;;
  esac
])
AC_SUBST(rpmprefix)

AC_ARG_ENABLE([infos],
[  --enable-infos                      enable building infos],[
  case "$enable_infos" in
  yes)
    build_infos=1;;
  no)
    build_infos=0;;
  *)
    AC_MSG_ERROR([Invalid argument to --enable-infos])
  esac
])
AC_SUBST(build_infos)


AS_IF([test "${host}" != "${build}"],[
AC_MSG_CHECKING(for RPM OS)
case "$host" in
  i?86-*cygwin*)        RPM_OS=cygwin ;;
  i?86-*mingw*)         RPM_OS=mingw32 ;;
  sparc-*solaris*)      RPM_OS=solaris2.7 ;;
  i?86-*freebsd5*)      RPM_OS=freebsd5.2 ;;
  i?86-*freebsd6.0)     RPM_OS=freebsd6.0 ;;
  i?86-*freebsd6.1)     RPM_OS=freebsd6.1 ;;
  *)
    AC_MSG_ERROR([Unsupported host ${host}])
    ;;
esac
AC_MSG_RESULT($RPM_OS)
])
AC_SUBST(RPM_OS)

case "${target_os}" in
  rtems|[rtems]RTEMS_API[])
    TARGET_SUBDIRS=rtems
    ;;
  *) # ignore
#    AC_MSG_ERROR([Unsupported target ${target}])
esac
AC_SUBST([TARGET_SUBDIRS])

case "${target_os}" in
  [rtems]RTEMS_API[])
    osversion=[]RTEMS_API[]
    ;;
  *)
  osversion=
esac
AC_SUBST([osversion])

for f in $targets; do
ac_cv_mytarget=`$SHELL "$ac_aux_dir/config.sub" $f` ||
  AC_MSG_ERROR([$SHELL $ac_aux_dir/config.sub $f failed])
  RTEMS_CANONICAL_SPLIT(mytarget)

  AS_IF([test -d $srcdir/$mytarget_os/$mytarget_cpu],[
    target_subdirs="$target_subdirs $mytarget_os/$mytarget_cpu"],[
    AC_MSG_WARN([ignoring unsupported target $f])
    ])
done
AC_SUBST(TARGET_SUBDIRS,$target_subdirs)

AC_CONFIG_FILES([Makefile])

AC_CONFIG_FILES([cygwin/Makefile])
AC_CONFIG_FILES([cygwin/i686/Makefile])

AC_CONFIG_FILES([mingw32/Makefile])
AC_CONFIG_FILES([mingw32/i686/Makefile])

AC_CONFIG_FILES([solaris2.7/Makefile])
AC_CONFIG_FILES([solaris2.7/sparc/Makefile])

AC_CONFIG_FILES([freebsd5.2/Makefile])
AC_CONFIG_FILES([freebsd5.2/i586/Makefile])

AC_CONFIG_FILES([freebsd6.0/Makefile])
AC_CONFIG_FILES([freebsd6.0/i586/Makefile])

AC_CONFIG_FILES([freebsd6.1/Makefile])
AC_CONFIG_FILES([freebsd6.1/i586/Makefile])

AC_CONFIG_FILES([rtems4.7/Makefile])
AC_CONFIG_FILES([rtems4.7/arm/Makefile])
AC_CONFIG_FILES([rtems4.7/avr/Makefile])
AC_CONFIG_FILES([rtems4.7/h8300/Makefile])
AC_CONFIG_FILES([rtems4.7/i386/Makefile])
AC_CONFIG_FILES([rtems4.7/m68k/Makefile])
AC_CONFIG_FILES([rtems4.7/mips/Makefile])
AC_CONFIG_FILES([rtems4.7/powerpc/Makefile])
AC_CONFIG_FILES([rtems4.7/sh/Makefile])
AC_CONFIG_FILES([rtems4.7/sparc/Makefile])
AC_CONFIG_FILES([rtems4.7/tic4x/Makefile])

AC_OUTPUT