source: rtems/configure.ac @ 66387986

4.104.114.84.9
Last change on this file since 66387986 was 66387986, checked in by Joel Sherrill <joel.sherrill@…>, on Oct 11, 2001 at 7:07:37 PM

2001-10-11 Ralf Corsepius <corsepiu@…>

  • .cvsignore: Add autom4te.cache for autoconf > 2.52.
  • configure.in: Remove.
  • configure.ac: New file, generated from configure.in by autoupdate.
  • Property mode set to 100644
File size: 3.0 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id$
4
5AC_PREREQ(2.52)
6AC_INIT
7AC_CONFIG_SRCDIR([c])
8RTEMS_TOP(.)
9
10# Abort if trying to build inside of the source tree.
11if test -f VERSION; then
12  rm -f config.cache config.log confdefs.h
13  AC_MSG_ERROR([***]
14    [Attempt to build inside of the source tree]
15    [Please use a separate build directory, instead] )
16fi
17
18AC_CANONICAL_TARGET([])
19AM_INIT_AUTOMAKE(rtems,$RTEMS_VERSION,no)
20AM_MAINTAINER_MODE
21
22## These option are only in here to let --help report all supported
23## options.
24RTEMS_ENABLE_MULTIPROCESSING
25RTEMS_ENABLE_POSIX
26RTEMS_ENABLE_ITRON
27RTEMS_ENABLE_NETWORKING
28RTEMS_ENABLE_RDBG
29RTEMS_ENABLE_INLINES
30RTEMS_ENABLE_CXX
31RTEMS_ENABLE_GCC28
32RTEMS_ENABLE_LIBCDIR
33RTEMS_ENABLE_TESTS 
34RTEMS_ENABLE_RTEMS_DEBUG
35RTEMS_ENABLE_RTEMSBSP(dummy)
36
37if test $host != $build; then
38AC_MSG_WARN([]
39[*** *** *** WARNING *** *** ***]
40[]
41[Entering BEYOND BLEEDING EDGE TERRITORY]
42[]
43[You are trying to build RTEMS Canadian cross]
44[If you really mean it, feel free to continue ...]
45[*** *** *** *** *** *** *** ***])
46fi
47
48## NOTES:
49## The tools/*-directories situation is unclear
50## * tools/build are host-native tools to be installed on the host.
51## * tools/cpu are host-native or host-cross-target-tools
52## * tools/update are build-host-native tools
53
54# these tools are built for the build environment
55#
56build_tools="tools/update"
57
58# these libraries are built for the host environment
59#
60host_libs=""
61
62# these tools are built for the host environment
63#
64host_tools="tools/build tools/cpu"
65
66# these libraries are built for the target environment, and are built after
67# the host libraries and the host tools (which may be a cross compiler)
68#
69target_libs="c"
70
71# these tools are built using the target libs, and are intended to run only
72# in the target environment
73#
74target_tools=""
75
76## All tools belong in one of the five categories, and are assigned above.
77## ${host_configdirs} is directories we build using the host tools.
78## ${target_configdirs} is directories we build using the target tools.
79#
80host_configdirs="${host_libs} ${host_tools}"
81AC_SUBST(host_configdirs)
82
83target_configdirs="${target_libs} ${target_tools}"
84AC_SUBST(target_configdirs)
85
86RTEMS_TARGET_CONFIG_PREPARE
87target_subdir=${target_alias}
88
89RTEMS_HOST_CONFIG_PREPARE
90host_subdir=${host_alias}
91
92if test $build = $host;
93then
94  BUILD_SUBDIRS="$build_tools $host_configdirs"
95
96  if test $build = $target;
97  then
98    BUILD_SUBDIRS="$BUILD_SUBDIRS $target_configdirs";
99  else
100    TARGET_SUBDIRS=`echo "$target_configdirs" | \
101      sed -e "s%\([[^ ]][[^ ]]*\)%$target_alias/\1%g"`
102  fi
103else
104## If building Canadian cross, disable the target directories
105  target_configdirs=""
106  BUILD_SUBDIRS="$build_tools"
107  TARGET_SUBDIRS=`echo "$host_configdirs" | \
108    sed -e "s%\([[^ ]][[^ ]]*\)%$host_alias/\1%g"`
109fi
110
111AC_CONFIG_SUBDIRS($BUILD_SUBDIRS)
112AC_SUBST(TARGET_SUBDIRS)
113AC_SUBST(BUILD_SUBDIRS)
114
115AC_CONFIG_FILES([Makefile
116tools/Makefile
117make/Makefile
118make/custom/Makefile
119make/Templates/Makefile
120make/compilers/Makefile
121doc/Makefile])
122AC_OUTPUT
123
124RTEMS_TARGET_CONFIG_SUBDIRS
125RTEMS_HOST_CONFIG_SUBDIRS
Note: See TracBrowser for help on using the repository browser.