source: rtems/configure.ac @ 261f99bd

4.104.114.84.95
Last change on this file since 261f99bd was fcb0cd46, checked in by Ralf Corsepius <ralf.corsepius@…>, on 12/02/06 at 06:06:55

2006-12-02 Ralf Corsépius <ralf.corsepius@…>

  • configure.ac: New BUG-REPORT address.
  • Property mode set to 100644
File size: 1.7 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id$
4
5AC_PREREQ(2.60)
6AC_INIT([rtems],[_RTEMS_VERSION],[http://www.rtems.org/bugzilla])
7AC_CONFIG_SRCDIR([c])
8RTEMS_TOP([.])
9
10# Abort if trying to build inside of the source tree.
11AS_IF([test -f aclocal/version.m4],[
12  rm -f config.cache config.log confdefs.h
13  AC_MSG_ERROR([***]
14    [Attempt to build inside of the source tree]
15    [Please use a separate build directory, instead] )
16])
17
18AC_CANONICAL_TARGET([])
19AM_INIT_AUTOMAKE([no-define foreign dist-bzip2 no-dist-gzip 1.10])
20AM_MAINTAINER_MODE
21
22## These option are only in here to let --help report all supported
23## options.
24RTEMS_ENABLE_MULTIPROCESSING
25RTEMS_ENABLE_POSIX
26RTEMS_ENABLE_ITRON
27RTEMS_ENABLE_NETWORKING
28RTEMS_ENABLE_RDBG
29RTEMS_ENABLE_CXX
30RTEMS_ENABLE_TESTS 
31RTEMS_ENABLE_RTEMS_DEBUG
32RTEMS_ENABLE_RTEMSBSP
33RTEMS_ENABLE_MULTILIB
34
35AC_ARG_ENABLE([docs],
36  [AC_HELP_STRING([--enable-docs],[enable building documentation
37    (default:disabled)])])
38
39## NOTES:
40## * tools/build are host-native tools to be installed on the host.
41## * tools/cpu are host-native or host-cross-target-tools
42
43RTEMS_BUILD_CONFIG_SUBDIRS([tools/build])
44RTEMS_BUILD_CONFIG_SUBDIRS([tools/cpu])
45
46case $enable_tests in
47yes | samples )
48  RTEMS_BUILD_CONFIG_SUBDIRS([testsuites/tools])
49  ;;
50esac
51
52# Some BSPs carelessly apply these tools as build-tools
53AS_IF([test $host != $build],[
54RTEMS_HOST_CONFIG_SUBDIRS([tools/build])
55])
56
57AS_IF([test x"${enable_docs}" = x"yes"],
58  [RTEMS_BUILD_CONFIG_SUBDIRS([doc])])
59
60AS_IF([test x"$enable_multilib" = x"yes"],[
61  RTEMS_TARGET_CONFIG_SUBDIRS([cpukit])
62])
63RTEMS_TARGET_CONFIG_SUBDIRS([c])
64
65AC_CONFIG_FILES([Makefile
66make/Makefile
67])
68
69AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.