source: rtems/c/src/lib/libcpu/powerpc/new-exceptions/cpu_asm.S @ a6f84b27

5
Last change on this file since a6f84b27 was a6f84b27, checked in by Sebastian Huber <sebastian.huber@…>, on Aug 1, 2017 at 8:57:46 AM

powerpc: Add 64-bit context/interrupt support

Update #3082.

  • Property mode set to 100644
File size: 15.1 KB
Line 
1/*  cpu_asm.s   1.1 - 95/12/04
2 *
3 *  This file contains the assembly code for the PowerPC implementation
4 *  of RTEMS.
5 *
6 *  Author:     Andrew Bray <andy@i-cubed.co.uk>
7 *
8 *  COPYRIGHT (c) 1995 by i-cubed ltd.
9 *
10 *  To anyone who acknowledges that this file is provided "AS IS"
11 *  without any express or implied warranty:
12 *      permission to use, copy, modify, and distribute this file
13 *      for any purpose is hereby granted without fee, provided that
14 *      the above copyright notice and this notice appears in all
15 *      copies, and that the name of i-cubed limited not be used in
16 *      advertising or publicity pertaining to distribution of the
17 *      software without specific, written prior permission.
18 *      i-cubed limited makes no representations about the suitability
19 *      of this software for any purpose.
20 *
21 *  Derived from c/src/exec/cpu/no_cpu/cpu_asm.c:
22 *
23 *  COPYRIGHT (c) 1989-1997.
24 *  On-Line Applications Research Corporation (OAR).
25 *
26 *  Copyright (c) 2011, 2017 embedded brains GmbH
27 *
28 *  The license and distribution terms for this file may in
29 *  the file LICENSE in this distribution or at
30 *  http://www.rtems.org/license/LICENSE.
31 */
32
33#include <rtems/asm.h>
34#include <rtems/powerpc/powerpc.h>
35#include <rtems/score/percpu.h>
36#include <libcpu/powerpc-utility.h>
37#include <bspopts.h>
38
39#ifdef BSP_USE_DATA_CACHE_BLOCK_TOUCH
40  #define DATA_CACHE_TOUCH(rega, regb) \
41        dcbt rega, regb
42#else
43  #define DATA_CACHE_TOUCH(rega, regb)
44#endif
45
46#if BSP_DATA_CACHE_ENABLED && PPC_DEFAULT_CACHE_LINE_SIZE == 32
47  #define DATA_CACHE_ZERO_AND_TOUCH(reg, offset) \
48        li reg, offset; dcbz reg, r3; DATA_CACHE_TOUCH(reg, r4)
49#else
50  #define DATA_CACHE_ZERO_AND_TOUCH(reg, offset)
51#endif
52
53#define PPC_CONTEXT_CACHE_LINE_0 (1 * PPC_DEFAULT_CACHE_LINE_SIZE)
54#define PPC_CONTEXT_CACHE_LINE_1 (2 * PPC_DEFAULT_CACHE_LINE_SIZE)
55#define PPC_CONTEXT_CACHE_LINE_2 (3 * PPC_DEFAULT_CACHE_LINE_SIZE)
56#define PPC_CONTEXT_CACHE_LINE_3 (4 * PPC_DEFAULT_CACHE_LINE_SIZE)
57#define PPC_CONTEXT_CACHE_LINE_4 (5 * PPC_DEFAULT_CACHE_LINE_SIZE)
58#define PPC_CONTEXT_CACHE_LINE_5 (6 * PPC_DEFAULT_CACHE_LINE_SIZE)
59
60        BEGIN_CODE
61
62#if PPC_HAS_FPU == 1
63
64/*
65 * Offsets for Context_Control_fp
66 */
67
68#if (PPC_HAS_DOUBLE==1)
69        .set    FP_SIZE,        8
70#define LDF     lfd
71#define STF     stfd
72#else
73        .set    FP_SIZE,        4
74#define LDF     lfs
75#define STF     stfs
76#endif
77
78        .set    FP_0, 0
79        .set    FP_1, (FP_0 + FP_SIZE)
80        .set    FP_2, (FP_1 + FP_SIZE)
81        .set    FP_3, (FP_2 + FP_SIZE)
82        .set    FP_4, (FP_3 + FP_SIZE)
83        .set    FP_5, (FP_4 + FP_SIZE)
84        .set    FP_6, (FP_5 + FP_SIZE)
85        .set    FP_7, (FP_6 + FP_SIZE)
86        .set    FP_8, (FP_7 + FP_SIZE)
87        .set    FP_9, (FP_8 + FP_SIZE)
88        .set    FP_10, (FP_9 + FP_SIZE)
89        .set    FP_11, (FP_10 + FP_SIZE)
90        .set    FP_12, (FP_11 + FP_SIZE)
91        .set    FP_13, (FP_12 + FP_SIZE)
92        .set    FP_14, (FP_13 + FP_SIZE)
93        .set    FP_15, (FP_14 + FP_SIZE)
94        .set    FP_16, (FP_15 + FP_SIZE)
95        .set    FP_17, (FP_16 + FP_SIZE)
96        .set    FP_18, (FP_17 + FP_SIZE)
97        .set    FP_19, (FP_18 + FP_SIZE)
98        .set    FP_20, (FP_19 + FP_SIZE)
99        .set    FP_21, (FP_20 + FP_SIZE)
100        .set    FP_22, (FP_21 + FP_SIZE)
101        .set    FP_23, (FP_22 + FP_SIZE)
102        .set    FP_24, (FP_23 + FP_SIZE)
103        .set    FP_25, (FP_24 + FP_SIZE)
104        .set    FP_26, (FP_25 + FP_SIZE)
105        .set    FP_27, (FP_26 + FP_SIZE)
106        .set    FP_28, (FP_27 + FP_SIZE)
107        .set    FP_29, (FP_28 + FP_SIZE)
108        .set    FP_30, (FP_29 + FP_SIZE)
109        .set    FP_31, (FP_30 + FP_SIZE)
110        .set    FP_FPSCR, (FP_31 + FP_SIZE)
111
112/*
113 *  _CPU_Context_save_fp_context
114 *
115 *  This routine is responsible for saving the FP context
116 *  at *fp_context_ptr.  If the point to load the FP context
117 *  from is changed then the pointer is modified by this routine.
118 *
119 *  Sometimes a macro implementation of this is in cpu.h which dereferences
120 *  the ** and a similarly named routine in this file is passed something
121 *  like a (Context_Control_fp *).  The general rule on making this decision
122 *  is to avoid writing assembly language.
123 */
124
125        ALIGN (PPC_CACHE_ALIGNMENT, PPC_CACHE_ALIGN_POWER)
126        PUBLIC_PROC (_CPU_Context_save_fp)
127PROC (_CPU_Context_save_fp):
128/* A FP context switch may occur in an ISR or exception handler when the FPU is not
129 * available. Therefore, we must explicitely enable it here!
130 */
131        mfmsr   r4
132        andi.   r5,r4,MSR_FP
133        bne     1f
134        ori     r5,r4,MSR_FP
135        mtmsr   r5
136        isync
1371:
138        lwz     r3, 0(r3)
139        STF     f0, FP_0(r3)
140        STF     f1, FP_1(r3)
141        STF     f2, FP_2(r3)
142        STF     f3, FP_3(r3)
143        STF     f4, FP_4(r3)
144        STF     f5, FP_5(r3)
145        STF     f6, FP_6(r3)
146        STF     f7, FP_7(r3)
147        STF     f8, FP_8(r3)
148        STF     f9, FP_9(r3)
149        STF     f10, FP_10(r3)
150        STF     f11, FP_11(r3)
151        STF     f12, FP_12(r3)
152        STF     f13, FP_13(r3)
153        STF     f14, FP_14(r3)
154        STF     f15, FP_15(r3)
155        STF     f16, FP_16(r3)
156        STF     f17, FP_17(r3)
157        STF     f18, FP_18(r3)
158        STF     f19, FP_19(r3)
159        STF     f20, FP_20(r3)
160        STF     f21, FP_21(r3)
161        STF     f22, FP_22(r3)
162        STF     f23, FP_23(r3)
163        STF     f24, FP_24(r3)
164        STF     f25, FP_25(r3)
165        STF     f26, FP_26(r3)
166        STF     f27, FP_27(r3)
167        STF     f28, FP_28(r3)
168        STF     f29, FP_29(r3)
169        STF     f30, FP_30(r3)
170        STF     f31, FP_31(r3)
171        mffs    f2
172        STF     f2, FP_FPSCR(r3)
173        bne     1f
174        mtmsr   r4
175        isync
1761:
177        blr
178
179/*
180 *  _CPU_Context_restore_fp_context
181 *
182 *  This routine is responsible for restoring the FP context
183 *  at *fp_context_ptr.  If the point to load the FP context
184 *  from is changed then the pointer is modified by this routine.
185 *
186 *  Sometimes a macro implementation of this is in cpu.h which dereferences
187 *  the ** and a similarly named routine in this file is passed something
188 *  like a (Context_Control_fp *).  The general rule on making this decision
189 *  is to avoid writing assembly language.
190 */
191
192        ALIGN (PPC_CACHE_ALIGNMENT, PPC_CACHE_ALIGN_POWER)
193        PUBLIC_PROC (_CPU_Context_restore_fp)
194PROC (_CPU_Context_restore_fp):
195        lwz     r3, 0(r3)
196/* A FP context switch may occur in an ISR or exception handler when the FPU is not
197 * available. Therefore, we must explicitely enable it here!
198 */
199        mfmsr   r4
200        andi.   r5,r4,MSR_FP
201        bne     1f
202        ori     r5,r4,MSR_FP
203        mtmsr   r5
204        isync
2051:
206        LDF     f2, FP_FPSCR(r3)
207        mtfsf   255, f2
208        LDF     f0, FP_0(r3)
209        LDF     f1, FP_1(r3)
210        LDF     f2, FP_2(r3)
211        LDF     f3, FP_3(r3)
212        LDF     f4, FP_4(r3)
213        LDF     f5, FP_5(r3)
214        LDF     f6, FP_6(r3)
215        LDF     f7, FP_7(r3)
216        LDF     f8, FP_8(r3)
217        LDF     f9, FP_9(r3)
218        LDF     f10, FP_10(r3)
219        LDF     f11, FP_11(r3)
220        LDF     f12, FP_12(r3)
221        LDF     f13, FP_13(r3)
222        LDF     f14, FP_14(r3)
223        LDF     f15, FP_15(r3)
224        LDF     f16, FP_16(r3)
225        LDF     f17, FP_17(r3)
226        LDF     f18, FP_18(r3)
227        LDF     f19, FP_19(r3)
228        LDF     f20, FP_20(r3)
229        LDF     f21, FP_21(r3)
230        LDF     f22, FP_22(r3)
231        LDF     f23, FP_23(r3)
232        LDF     f24, FP_24(r3)
233        LDF     f25, FP_25(r3)
234        LDF     f26, FP_26(r3)
235        LDF     f27, FP_27(r3)
236        LDF     f28, FP_28(r3)
237        LDF     f29, FP_29(r3)
238        LDF     f30, FP_30(r3)
239        LDF     f31, FP_31(r3)
240        bne     1f
241        mtmsr   r4
242        isync
2431:
244        blr
245#endif /* PPC_HAS_FPU == 1 */
246
247        ALIGN (PPC_CACHE_ALIGNMENT, PPC_CACHE_ALIGN_POWER)
248        PUBLIC_PROC (_CPU_Context_switch)
249PROC (_CPU_Context_switch):
250
251#ifdef BSP_USE_SYNC_IN_CONTEXT_SWITCH
252        sync
253        isync
254#endif
255
256        /* Align to a cache line */
257        clrrwi  r3, r3, PPC_DEFAULT_CACHE_LINE_POWER
258        clrrwi  r5, r4, PPC_DEFAULT_CACHE_LINE_POWER
259
260        DATA_CACHE_ZERO_AND_TOUCH(r10, PPC_CONTEXT_CACHE_LINE_0)
261
262#if PPC_CONTEXT_CACHE_LINE_2 <= PPC_CONTEXT_VOLATILE_SIZE
263        DATA_CACHE_ZERO_AND_TOUCH(r11, PPC_CONTEXT_CACHE_LINE_1)
264#endif
265
266        /* Save context to r3 */
267
268        GET_SELF_CPU_CONTROL    r12
269        mfmsr   r6
270        mfcr    r7
271        mflr    r8
272        lwz     r11, PER_CPU_ISR_DISPATCH_DISABLE(r12)
273
274        /*
275         * We have to clear the reservation of the executing thread.  See also
276         * Book E section 6.1.6.2 "Atomic Update Primitives".  Recent GCC
277         * versions use atomic operations in the C++ library for example.  On
278         * SMP configurations the reservation is cleared later during the
279         * context switch.
280         */
281#if PPC_CONTEXT_OFFSET_GPR1 != PPC_CONTEXT_CACHE_LINE_0 \
282  || !BSP_DATA_CACHE_ENABLED \
283  || PPC_DEFAULT_CACHE_LINE_SIZE != 32
284        li      r10, PPC_CONTEXT_OFFSET_GPR1
285#endif
286#ifndef RTEMS_SMP
287        stwcx.  r1, r3, r10
288#endif
289
290        stw     r6, PPC_CONTEXT_OFFSET_MSR(r3)
291        stw     r7, PPC_CONTEXT_OFFSET_CR(r3)
292        PPC_REG_STORE   r1, PPC_CONTEXT_OFFSET_GPR1(r3)
293        PPC_REG_STORE   r8, PPC_CONTEXT_OFFSET_LR(r3)
294
295        PPC_GPR_STORE   r14, PPC_CONTEXT_OFFSET_GPR14(r3)
296        PPC_GPR_STORE   r15, PPC_CONTEXT_OFFSET_GPR15(r3)
297
298#if PPC_CONTEXT_OFFSET_GPR20 == PPC_CONTEXT_CACHE_LINE_2
299        DATA_CACHE_ZERO_AND_TOUCH(r10, PPC_CONTEXT_CACHE_LINE_2)
300#endif
301
302        PPC_GPR_STORE   r16, PPC_CONTEXT_OFFSET_GPR16(r3)
303        PPC_GPR_STORE   r17, PPC_CONTEXT_OFFSET_GPR17(r3)
304
305#if PPC_CONTEXT_OFFSET_GPR26 == PPC_CONTEXT_CACHE_LINE_2
306        DATA_CACHE_ZERO_AND_TOUCH(r10, PPC_CONTEXT_CACHE_LINE_2)
307#endif
308
309        PPC_GPR_STORE   r18, PPC_CONTEXT_OFFSET_GPR18(r3)
310        PPC_GPR_STORE   r19, PPC_CONTEXT_OFFSET_GPR19(r3)
311
312#if PPC_CONTEXT_OFFSET_GPR24 == PPC_CONTEXT_CACHE_LINE_3
313        DATA_CACHE_ZERO_AND_TOUCH(r10, PPC_CONTEXT_CACHE_LINE_3)
314#endif
315
316        PPC_GPR_STORE   r20, PPC_CONTEXT_OFFSET_GPR20(r3)
317        PPC_GPR_STORE   r21, PPC_CONTEXT_OFFSET_GPR21(r3)
318        PPC_GPR_STORE   r22, PPC_CONTEXT_OFFSET_GPR22(r3)
319        PPC_GPR_STORE   r23, PPC_CONTEXT_OFFSET_GPR23(r3)
320
321#if PPC_CONTEXT_OFFSET_GPR28 == PPC_CONTEXT_CACHE_LINE_4
322        DATA_CACHE_ZERO_AND_TOUCH(r10, PPC_CONTEXT_CACHE_LINE_4)
323#endif
324
325        PPC_GPR_STORE   r24, PPC_CONTEXT_OFFSET_GPR24(r3)
326        PPC_GPR_STORE   r25, PPC_CONTEXT_OFFSET_GPR25(r3)
327
328#if PPC_CONTEXT_OFFSET_V22 == PPC_CONTEXT_CACHE_LINE_2
329        DATA_CACHE_ZERO_AND_TOUCH(r10, PPC_CONTEXT_CACHE_LINE_2)
330#endif
331
332        PPC_GPR_STORE   r26, PPC_CONTEXT_OFFSET_GPR26(r3)
333        PPC_GPR_STORE   r27, PPC_CONTEXT_OFFSET_GPR27(r3)
334
335        PPC_GPR_STORE   r28, PPC_CONTEXT_OFFSET_GPR28(r3)
336        PPC_GPR_STORE   r29, PPC_CONTEXT_OFFSET_GPR29(r3)
337        PPC_GPR_STORE   r30, PPC_CONTEXT_OFFSET_GPR30(r3)
338        PPC_GPR_STORE   r31, PPC_CONTEXT_OFFSET_GPR31(r3)
339
340        stw     r11, PPC_CONTEXT_OFFSET_ISR_DISPATCH_DISABLE(r3)
341
342#ifdef PPC_MULTILIB_ALTIVEC
343        li      r9, PPC_CONTEXT_OFFSET_V20
344        stvx    v20, r3, r9
345        li      r9, PPC_CONTEXT_OFFSET_V21
346        stvx    v21, r3, r9
347
348#if PPC_CONTEXT_OFFSET_V26 == PPC_CONTEXT_CACHE_LINE_3
349        DATA_CACHE_ZERO_AND_TOUCH(r10, PPC_CONTEXT_CACHE_LINE_3)
350#endif
351
352        li      r9, PPC_CONTEXT_OFFSET_V22
353        stvx    v22, r3, r9
354        li      r9, PPC_CONTEXT_OFFSET_V23
355        stvx    v23, r3, r9
356        li      r9, PPC_CONTEXT_OFFSET_V24
357        stvx    v24, r3, r9
358        li      r9, PPC_CONTEXT_OFFSET_V25
359        stvx    v25, r3, r9
360
361#if PPC_CONTEXT_OFFSET_V30 == PPC_CONTEXT_CACHE_LINE_4
362        DATA_CACHE_ZERO_AND_TOUCH(r10, PPC_CONTEXT_CACHE_LINE_4)
363#endif
364
365        li      r9, PPC_CONTEXT_OFFSET_V26
366        stvx    v26, r3, r9
367        li      r9, PPC_CONTEXT_OFFSET_V27
368        stvx    v27, r3, r9
369        li      r9, PPC_CONTEXT_OFFSET_V28
370        stvx    v28, r3, r9
371        li      r9, PPC_CONTEXT_OFFSET_V29
372        stvx    v29, r3, r9
373
374#if PPC_CONTEXT_OFFSET_F17 == PPC_CONTEXT_CACHE_LINE_5
375        DATA_CACHE_ZERO_AND_TOUCH(r10, PPC_CONTEXT_CACHE_LINE_5)
376#endif
377
378        li      r9, PPC_CONTEXT_OFFSET_V30
379        stvx    v30, r3, r9
380        li      r9, PPC_CONTEXT_OFFSET_V31
381        stvx    v31, r3, r9
382        mfvrsave        r9
383        stw     r9, PPC_CONTEXT_OFFSET_VRSAVE(r3)
384#endif
385
386#ifdef PPC_MULTILIB_FPU
387        stfd    f14, PPC_CONTEXT_OFFSET_F14(r3)
388        stfd    f15, PPC_CONTEXT_OFFSET_F15(r3)
389        stfd    f16, PPC_CONTEXT_OFFSET_F16(r3)
390        stfd    f17, PPC_CONTEXT_OFFSET_F17(r3)
391        stfd    f18, PPC_CONTEXT_OFFSET_F18(r3)
392        stfd    f19, PPC_CONTEXT_OFFSET_F19(r3)
393        stfd    f20, PPC_CONTEXT_OFFSET_F20(r3)
394        stfd    f21, PPC_CONTEXT_OFFSET_F21(r3)
395        stfd    f22, PPC_CONTEXT_OFFSET_F22(r3)
396        stfd    f23, PPC_CONTEXT_OFFSET_F23(r3)
397        stfd    f24, PPC_CONTEXT_OFFSET_F24(r3)
398        stfd    f25, PPC_CONTEXT_OFFSET_F25(r3)
399        stfd    f26, PPC_CONTEXT_OFFSET_F26(r3)
400        stfd    f27, PPC_CONTEXT_OFFSET_F27(r3)
401        stfd    f28, PPC_CONTEXT_OFFSET_F28(r3)
402        stfd    f29, PPC_CONTEXT_OFFSET_F29(r3)
403        stfd    f30, PPC_CONTEXT_OFFSET_F30(r3)
404        stfd    f31, PPC_CONTEXT_OFFSET_F31(r3)
405#endif
406
407#ifdef RTEMS_SMP
408        /*
409         * The executing thread no longer executes on this processor.  Switch
410         * the stack to the temporary interrupt stack of this processor.  Mark
411         * the context of the executing thread as not executing.
412         */
413        msync
414
415        addi    r1, r12, PER_CPU_INTERRUPT_FRAME_AREA + CPU_INTERRUPT_FRAME_SIZE
416        li      r6, 0
417        stw     r6, PPC_CONTEXT_OFFSET_IS_EXECUTING(r3)
418
419.Lcheck_is_executing:
420
421        /* Check the is executing indicator of the heir context */
422        addi    r6, r5, PPC_CONTEXT_OFFSET_IS_EXECUTING
423        lwarx   r7, r0, r6
424        cmpwi   r7, 0
425        bne     .Lget_potential_new_heir
426
427        /* Try to update the is executing indicator of the heir context */
428        li      r7, 1
429        stwcx.  r7, r0, r6
430        bne     .Lget_potential_new_heir
431        isync
432#endif
433
434        /* Restore context from r5 */
435restore_context:
436
437#if defined(__ALTIVEC__) && !defined(PPC_MULTILIB_ALTIVEC)
438        mr      r4, r5
439        .extern _CPU_Context_switch_altivec
440        bl      _CPU_Context_switch_altivec
441#endif
442
443        lwz     r6, PPC_CONTEXT_OFFSET_MSR(r5)
444        lwz     r7, PPC_CONTEXT_OFFSET_CR(r5)
445        PPC_REG_LOAD    r1, PPC_CONTEXT_OFFSET_GPR1(r5)
446        PPC_REG_LOAD    r8, PPC_CONTEXT_OFFSET_LR(r5)
447
448        PPC_GPR_LOAD    r14, PPC_CONTEXT_OFFSET_GPR14(r5)
449        PPC_GPR_LOAD    r15, PPC_CONTEXT_OFFSET_GPR15(r5)
450
451        DATA_CACHE_TOUCH(r0, r1)
452
453        PPC_GPR_LOAD    r16, PPC_CONTEXT_OFFSET_GPR16(r5)
454        PPC_GPR_LOAD    r17, PPC_CONTEXT_OFFSET_GPR17(r5)
455        PPC_GPR_LOAD    r18, PPC_CONTEXT_OFFSET_GPR18(r5)
456        PPC_GPR_LOAD    r19, PPC_CONTEXT_OFFSET_GPR19(r5)
457
458        PPC_GPR_LOAD    r20, PPC_CONTEXT_OFFSET_GPR20(r5)
459        PPC_GPR_LOAD    r21, PPC_CONTEXT_OFFSET_GPR21(r5)
460        PPC_GPR_LOAD    r22, PPC_CONTEXT_OFFSET_GPR22(r5)
461        PPC_GPR_LOAD    r23, PPC_CONTEXT_OFFSET_GPR23(r5)
462
463        PPC_GPR_LOAD    r24, PPC_CONTEXT_OFFSET_GPR24(r5)
464        PPC_GPR_LOAD    r25, PPC_CONTEXT_OFFSET_GPR25(r5)
465        PPC_GPR_LOAD    r26, PPC_CONTEXT_OFFSET_GPR26(r5)
466        PPC_GPR_LOAD    r27, PPC_CONTEXT_OFFSET_GPR27(r5)
467
468        PPC_GPR_LOAD    r28, PPC_CONTEXT_OFFSET_GPR28(r5)
469        PPC_GPR_LOAD    r29, PPC_CONTEXT_OFFSET_GPR29(r5)
470        PPC_GPR_LOAD    r30, PPC_CONTEXT_OFFSET_GPR30(r5)
471        PPC_GPR_LOAD    r31, PPC_CONTEXT_OFFSET_GPR31(r5)
472
473#ifdef __powerpc64__
474        ld      r13, PPC_CONTEXT_OFFSET_TP(r5)
475#else
476        lwz     r2, PPC_CONTEXT_OFFSET_TP(r5)
477#endif
478        lwz     r11, PPC_CONTEXT_OFFSET_ISR_DISPATCH_DISABLE(r5)
479
480#ifdef PPC_MULTILIB_ALTIVEC
481        li      r9, PPC_CONTEXT_OFFSET_V20
482        lvx     v20, r5, r9
483        li      r9, PPC_CONTEXT_OFFSET_V21
484        lvx     v21, r5, r9
485        li      r9, PPC_CONTEXT_OFFSET_V22
486        lvx     v22, r5, r9
487        li      r9, PPC_CONTEXT_OFFSET_V23
488        lvx     v23, r5, r9
489        li      r9, PPC_CONTEXT_OFFSET_V24
490        lvx     v24, r5, r9
491        li      r9, PPC_CONTEXT_OFFSET_V25
492        lvx     v25, r5, r9
493        li      r9, PPC_CONTEXT_OFFSET_V26
494        lvx     v26, r5, r9
495        li      r9, PPC_CONTEXT_OFFSET_V27
496        lvx     v27, r5, r9
497        li      r9, PPC_CONTEXT_OFFSET_V28
498        lvx     v28, r5, r9
499        li      r9, PPC_CONTEXT_OFFSET_V29
500        lvx     v29, r5, r9
501        li      r9, PPC_CONTEXT_OFFSET_V30
502        lvx     v30, r5, r9
503        li      r9, PPC_CONTEXT_OFFSET_V31
504        lvx     v31, r5, r9
505        lwz     r9, PPC_CONTEXT_OFFSET_VRSAVE(r5)
506        mtvrsave        r9
507#endif
508
509#ifdef PPC_MULTILIB_FPU
510        lfd     f14, PPC_CONTEXT_OFFSET_F14(r5)
511        lfd     f15, PPC_CONTEXT_OFFSET_F15(r5)
512        lfd     f16, PPC_CONTEXT_OFFSET_F16(r5)
513        lfd     f17, PPC_CONTEXT_OFFSET_F17(r5)
514        lfd     f18, PPC_CONTEXT_OFFSET_F18(r5)
515        lfd     f19, PPC_CONTEXT_OFFSET_F19(r5)
516        lfd     f20, PPC_CONTEXT_OFFSET_F20(r5)
517        lfd     f21, PPC_CONTEXT_OFFSET_F21(r5)
518        lfd     f22, PPC_CONTEXT_OFFSET_F22(r5)
519        lfd     f23, PPC_CONTEXT_OFFSET_F23(r5)
520        lfd     f24, PPC_CONTEXT_OFFSET_F24(r5)
521        lfd     f25, PPC_CONTEXT_OFFSET_F25(r5)
522        lfd     f26, PPC_CONTEXT_OFFSET_F26(r5)
523        lfd     f27, PPC_CONTEXT_OFFSET_F27(r5)
524        lfd     f28, PPC_CONTEXT_OFFSET_F28(r5)
525        lfd     f29, PPC_CONTEXT_OFFSET_F29(r5)
526        lfd     f30, PPC_CONTEXT_OFFSET_F30(r5)
527        lfd     f31, PPC_CONTEXT_OFFSET_F31(r5)
528#endif
529
530        mtlr    r8
531        mtcr    r7
532        mtmsr   r6
533        stw     r11, PER_CPU_ISR_DISPATCH_DISABLE(r12)
534
535#ifdef BSP_USE_SYNC_IN_CONTEXT_SWITCH
536        isync
537#endif
538
539        blr
540
541        PUBLIC_PROC (_CPU_Context_restore)
542PROC (_CPU_Context_restore):
543        /* Align to a cache line */
544        clrrwi  r5, r3, PPC_DEFAULT_CACHE_LINE_POWER
545
546        GET_SELF_CPU_CONTROL    r12
547
548#if defined(__ALTIVEC__) && !defined(PPC_MULTILIB_ALTIVEC)
549        li      r3, 0
550#endif
551
552        b       restore_context
553
554#ifdef RTEMS_SMP
555.Lget_potential_new_heir:
556
557        /* We may have a new heir */
558
559        /* Read the executing and heir */
560        PPC_REG_LOAD    r7, PER_CPU_OFFSET_EXECUTING(r12)
561        PPC_REG_LOAD    r8, PER_CPU_OFFSET_HEIR(r12)
562
563        /*
564         * Update the executing only if necessary to avoid cache line
565         * monopolization.
566         */
567        PPC_REG_CMP     r7, r8
568        beq     .Lcheck_is_executing
569
570        /* Calculate the heir context pointer */
571        sub     r7, r4, r7
572        add     r4, r8, r7
573        clrrwi  r5, r4, PPC_DEFAULT_CACHE_LINE_POWER
574
575        /* Update the executing */
576        PPC_REG_STORE   r8, PER_CPU_OFFSET_EXECUTING(r12)
577
578        b       .Lcheck_is_executing
579#endif
Note: See TracBrowser for help on using the repository browser.