source: rtems/c/src/lib/libbsp/sparc/erc32/startup/linkcmds @ 73c2d23

Last change on this file since 73c2d23 was 73c2d23, checked in by Joel Sherrill <joel.sherrill@…>, on Oct 5, 2005 at 7:25:07 PM

2005-10-05 Jiri Gaisler <jiri@…>

Edvin Catovic <edvin@…>
Konrad Eisele <konrad@…>

PR 827/bsps

  • ChangeLog?, configure.ac, console/Makefile.am, console/console.c, console/debugputs.c, startup/Makefile.am, startup/linkcmds, tools/Makefile.am: Portion of large update of SPARC BSPs. Includes addition of sis, leon2 and leon3 BSPs, deletion of leon BSP, addition of SMC91111 NIC driver and much more.
  • Property mode set to 100644
File size: 3.5 KB
Line 
1/*  linkcmds
2 *
3 *  $Id$
4 */
5
6OUTPUT_ARCH(sparc)
7__DYNAMIC  =  0;
8
9/*
10 * The memory map looks like this:
11 * +--------------------+ <- low memory
12 * | .text              |
13 * |        etext       |
14 * |        ctor list   | the ctor and dtor lists are for
15 * |        dtor list   | C++ support
16 * |        _endtext    |
17 * +--------------------+
18 * | .data              | initialized data goes here
19 * |        _sdata      |
20 * |        _edata      |
21 * +--------------------+
22 * | .bss               |
23 * |        __bss_start | start of bss, cleared by crt0
24 * |        _end        | start of heap, used by sbrk()
25 * +--------------------+
26 * |    heap space      |
27 * |        _ENDHEAP    |
28 * |    stack space     |
29 * |        __stack     | top of stack
30 * +--------------------+ <- high memory
31 */
32
33
34/*
35 * User modifiable values:
36 *
37 * _CLOCK_SPEED               in Mhz (used to program the counter/timers)
38 *
39 * _PROM_SIZE                 size of PROM (permissible values are 128K, 256K,
40 *                               512K, 1M, 2M, 4M, 8M and 16M)
41 * _RAM_SIZE                  size of RAM (permissible values are 256K, 512K,
42 *                               1M, 2M, 4M, 8M, 16M, and 32M)
43 *
44 */
45
46/* Default values, can be overridden */
47
48_PROM_SIZE = 2M;
49_RAM_SIZE = 4M;
50
51_RAM_START = 0x02000000;
52_RAM_END = _RAM_START + _RAM_SIZE;
53
54_PROM_START = 0x00000000;
55_PROM_END = _PROM_START + _PROM_SIZE;
56
57/*
58 *  Alternate names without leading _.
59 */
60
61PROM_START = _PROM_START;
62PROM_SIZE = _PROM_SIZE;
63PROM_END = _PROM_END;
64
65RAM_START = _RAM_START;
66RAM_SIZE = _RAM_SIZE;
67RAM_END = _RAM_END;
68
69/*
70 *  Base address of the on-CPU peripherals
71 */
72
73_ERC32_MEC = 0x01f80000;
74ERC32_MEC = 0x01f80000;
75
76/* these are the maximum values */
77
78MEMORY
79{
80  rom     : ORIGIN = 0x00000000, LENGTH = 16
81  ram     : ORIGIN = 0x02000000, LENGTH = 32M
82}
83
84/*
85 * stick everything in ram (of course)
86 */
87SECTIONS
88{
89  .text :
90  {
91    CREATE_OBJECT_SYMBOLS
92    text_start = .;
93    _text_start = .;
94    *(.text)
95    . = ALIGN (16);
96
97
98    /*
99     * Special FreeBSD sysctl sections.
100     */
101    . = ALIGN (16);
102    __start_set_sysctl_set = .;
103    *(set_sysctl_*);
104    __stop_set_sysctl_set = ABSOLUTE(.);
105    *(set_domain_*);
106    *(set_pseudo_*);
107
108    *(.eh_frame)
109    . = ALIGN (16);
110
111    *(.gnu.linkonce.t*)
112
113    /*
114     * C++ constructors
115     */
116    __CTOR_LIST__ = .;
117    LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
118    *(.ctors)
119    LONG(0)
120    __CTOR_END__ = .;
121    __DTOR_LIST__ = .;
122    LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
123    *(.dtors)
124    LONG(0)
125    __DTOR_END__ = .;
126
127    _rodata_start = . ;
128    *(.rodata*)
129    *(.gnu.linkonce.r*)
130    _erodata = ALIGN( 0x10 ) ;
131
132    etext = ALIGN(0x10);
133    _etext = .;
134    *(.init)
135    *(.fini)
136    *(.lit)
137    *(.shdata)
138    . = ALIGN (16);
139    _endtext = .;
140  } > ram
141  .data :
142  {
143    data_start = .;
144    _data_start = .;
145    _sdata = . ;
146    *(.data)
147    *(.gnu.linkonce.d*)
148    *(.gcc_except_table)
149    . = ALIGN(0x10);
150    edata = .;
151    _edata = .;
152  } > ram
153  .dynamic        : { *(.dynamic)       } >ram
154  .jcr            : { *(.jcr)           } >ram
155  .got            : { *(.got)           } >ram
156  .plt            : { *(.plt)           } >ram
157  .hash           : { *(.hash)          } >ram
158  .dynrel         : { *(.dynrel)        } >ram
159  .dynsym         : { *(.dynsym)        } >ram
160  .dynstr         : { *(.dynstr)        } >ram
161  .hash           : { *(.hash)          } >ram
162  .shbss :
163  {
164    *(.shbss)
165  } > ram
166  .bss :
167  {
168    __bss_start = ALIGN(0x8);
169    _bss_start = .;
170    bss_start = .;
171    *(.bss)
172    *(COMMON)
173    end = .;
174    _end = ALIGN(0x8);
175    __end = ALIGN(0x8);
176  } > ram
177  .stab . (NOLOAD) :
178  {
179    [ .stab ]
180  }
181  .stabstr . (NOLOAD) :
182  {
183    [ .stabstr ]
184  }
185}
Note: See TracBrowser for help on using the repository browser.