source: rtems/c/src/lib/libbsp/sh/simsh4/startup/linkcmds @ b5bc659

4.104.114.84.95
Last change on this file since b5bc659 was b5bc659, checked in by Joel Sherrill <joel.sherrill@…>, on Sep 4, 2003 at 6:52:50 PM

2003-09-04 Joel Sherrill <joel@…>

  • clock/ckinit.c, console/console.c, include/bsp.h, include/coverhd.h, include/ramdisk.h, start/start.S, startup/bspstart.c, startup/hw_init.c, startup/linkcmds, startup/linkcmds-le.coff, timer/timer.c, tools/runtest.in: URL for license changed.
  • Property mode set to 100644
File size: 5.6 KB
Line 
1/*
2 * Memory layout for SH4 GNU simulator.
3 *
4 * Copyright (C) 2001 OKTET Ltd., St.-Petersburg, Russia
5 * Author: Victor V. Vengerov <vvv@oktet.ru>
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
10 *
11 *
12 *  COPYRIGHT (c) 1998-2001.
13 *  On-Line Applications Research Corporation (OAR).
14 *
15 *  The license and distribution terms for this file may be
16 *  found in the file LICENSE in this distribution or at
17 *  http://www.rtems.com/license/LICENSE.
18 *
19 *  $Id$
20 */
21
22/*
23OUTPUT_FORMAT("coff-sh")
24 */
25OUTPUT_ARCH(sh)
26ENTRY(_start)
27
28_HeapSize = DEFINED(_HeapSize) ? _HeapSize : (512 * 1024);
29_WorkspaceSize = DEFINED(_WorkspaceSize) ? _WorkspaceSize : (1024 * 1024);
30
31/* These assignments load code into SH7045F EVB SRAM for monitor debugging */
32
33MEMORY
34{
35  ram           : o = 0x00000000, l = 0x01000000
36}
37
38/* Sections are defined for RAM loading and monitor debugging */
39SECTIONS
40{
41
42  /* Read-only sections, merged into text segment: */
43
44  . = 0x00004000 ;
45  .interp        : { *(.interp)         }
46  .hash          : { *(.hash)           }
47  .dynsym        : { *(.dynsym)         }
48  .dynstr        : { *(.dynstr)         }
49  .gnu.version   : { *(.gnu.version)    }
50  .gnu.version_d : { *(.gnu.version_d)  }
51  .gnu.version_r : { *(.gnu.version_r)  }
52  .rel.text      :
53    { *(.rel.text) *(.rel.gnu.linkonce.t*) }
54  .rela.text     :
55    { *(.rela.text) *(.rela.gnu.linkonce.t*) }
56  .rel.data      :
57    { *(.rel.data) *(.rel.gnu.linkonce.d*) }
58  .rela.data     :
59    { *(.rela.data) *(.rela.gnu.linkonce.d*) }
60  .rel.rodata    :
61    { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
62  .rela.rodata   :
63    { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
64  .rel.got       : { *(.rel.got)                }
65  .rela.got      : { *(.rela.got)               }
66  .rel.ctors     : { *(.rel.ctors)      }
67  .rela.ctors    : { *(.rela.ctors)     }
68  .rel.dtors     : { *(.rel.dtors)      }
69  .rela.dtors    : { *(.rela.dtors)     }
70  .rel.init      : { *(.rel.init)       }
71  .rela.init     : { *(.rela.init)      }
72  .rel.fini      : { *(.rel.fini)       }
73  .rela.fini     : { *(.rela.fini)      }
74  .rel.bss       : { *(.rel.bss)                }
75  .rela.bss      : { *(.rela.bss)               }
76  .rel.plt       : { *(.rel.plt)                }
77  .rela.plt      : { *(.rela.plt)               }
78  .init          : { *(.init)   } =0
79  .plt           : { *(.plt)    }
80  .text   .      :
81  {
82    *(.text)
83    *(.stub)
84
85    /*
86     * Special FreeBSD sysctl sections.
87     */
88    . = ALIGN (16);
89    ___start_set_sysctl_set = .;
90    *(set_sysc*);   /* set_sysctl_* but name is truncated by SH-coff */
91    ___stop_set_sysctl_set = ABSOLUTE(.);
92    *(set_doma*);   /* set_domain_* but name is truncated by SH-coff */
93    *(set_pseu*);   /* set_pseudo_* but name is truncated by SH-coff */
94
95    /* .gnu.warning sections are handled specially by elf32.em.  */
96    *(.gnu.warning)
97    *(.gnu.linkonce.t*)
98  } > ram
99  _etext = .;
100  PROVIDE (etext = .);
101  .fini    .  : { *(.fini)    } =0
102  .rodata  .  : { *(.rodata*) *(.gnu.linkonce.r*) }
103  .rodata1 .  : { *(.rodata1) }
104  /* Adjust the address for the data segment.  We want to adjust up to
105     the same address within the page on the next page up.  */
106  . = ALIGN(128) + (. & (128 - 1));
107  .data  .  :
108  {
109    *(.data)
110    *(.gcc_exc*)
111    ___EH_FRAME_BEGIN__ = .;
112    *(.eh_fram*)
113    ___EH_FRAME_END__ = .;
114    LONG(0);
115    *(.gcc_except_table)
116    *(.gnu.linkonce.d*)
117    CONSTRUCTORS
118  } > ram
119  .data1  . : { *(.data1) }
120  .ctors  .       :
121  {
122    ___ctors = .;
123    *(.ctors)
124    ___ctors_end = .;
125  }
126  .dtors  .       :
127  {
128    ___dtors = .;
129    *(.dtors)
130    ___dtors_end = .;
131  }
132  .got     .      : { *(.got.plt) *(.got) }
133  .dynamic .      : { *(.dynamic) }
134  /* We want the small data sections together, so single-instruction offsets
135     can access them all, and initialized data all before uninitialized, so
136     we can shorten the on-disk segment size.  */
137  .sdata   .  : { *(.sdata) }
138  _edata  =  .;
139  PROVIDE (edata = .);
140  __bss_start = .;
141  .sbss    .  : { *(.sbss) *(.scommon) }
142  .bss     .  :
143  {
144   *(.dynbss)
145   *(.bss)
146   *(COMMON)
147  } > ram
148  _end = . ;
149  PROVIDE (end = .);
150
151  . = ALIGN(16);
152  _HeapStart = . ;
153  . = . + _HeapSize ;
154  PROVIDE( _HeapEnd = . );
155
156  . = ALIGN(16);
157  _WorkSpaceStart = . ;
158  . = . + _WorkspaceSize ;
159  PROVIDE(_WorkSpaceEnd = .);
160
161  . = ALIGN(16);
162  .stack . : {
163     . = . + 4096;
164  }
165
166  . = ALIGN(16);
167  _CPU_Interrupt_stack_low  = . ;
168  _CPU_Interrupt_stack_high = _CPU_Interrupt_stack_low + 4096 ;
169
170  /* Stabs debugging sections.  */
171  .stab 0 : { *(.stab) }
172  .stabstr 0 : { *(.stabstr) }
173  .stab.excl 0 : { *(.stab.excl) }
174  .stab.exclstr 0 : { *(.stab.exclstr) }
175  .stab.index 0 : { *(.stab.index) }
176  .stab.indexstr 0 : { *(.stab.indexstr) }
177  .comment 0 : { *(.comment) }
178  /* DWARF debug sections.
179     Symbols in the DWARF debugging sections are relative to the beginning
180     of the section so we begin them at 0.  */
181  /* DWARF 1 */
182  .debug          0 : { *(.debug) }
183  .line           0 : { *(.line) }
184  /* GNU DWARF 1 extensions */
185  .debug_srcinfo  0 : { *(.debug_srcinfo) }
186  .debug_sfnames  0 : { *(.debug_sfnames) }
187  /* DWARF 1.1 and DWARF 2 */
188  .debug_aranges  0 : { *(.debug_aranges) }
189  .debug_pubnames 0 : { *(.debug_pubnames) }
190  /* DWARF 2 */
191  .debug_info     0 : { *(.debug_info) }
192  .debug_abbrev   0 : { *(.debug_abbrev) }
193  .debug_line     0 : { *(.debug_line) }
194  .debug_frame    0 : { *(.debug_frame) }
195  .debug_str      0 : { *(.debug_str) }
196  .debug_loc      0 : { *(.debug_loc) }
197  .debug_macinfo  0 : { *(.debug_macinfo) }
198  /* SGI/MIPS DWARF 2 extensions */
199  .debug_weaknames 0 : { *(.debug_weaknames) }
200  .debug_funcnames 0 : { *(.debug_funcnames) }
201  .debug_typenames 0 : { *(.debug_typenames) }
202  .debug_varnames  0 : { *(.debug_varnames) }
203
204}
Note: See TracBrowser for help on using the repository browser.