source: rtems/c/src/lib/libbsp/sh/simsh4/startup/linkcmds @ 70d7eaa9

4.104.114.84.95
Last change on this file since 70d7eaa9 was 70d7eaa9, checked in by Joel Sherrill <joel.sherrill@…>, on Oct 15, 2001 at 6:07:19 PM

2001-10-12 Ralf Corsepius <corsepiu@…>

  • configure.ac: Added support for START_HW_INIT.
  • console/Makefile.am: Removed VPATH.
  • include/Makefile.am: Added missing ramdisk.h to include_HEADERS.
  • startup/linkcmds: Do not force output format to coff-sh.
  • startup/linkcmds-le: Comment out force of output format and add comment questioning need to have special linkcmds for little endian.
  • wrapup/Makefile.am: Add ramdisk to list of BSP_PIECES.
  • Property mode set to 100644
File size: 5.1 KB
Line 
1/*
2 * Memory layout for SH4 GNU simulator.
3 *
4 * Copyright (C) 2001 OKTET Ltd., St.-Petersburg, Russia
5 * Author: Victor V. Vengerov <vvv@oktet.ru>
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
10 *
11 *
12 *  COPYRIGHT (c) 1998-2001.
13 *  On-Line Applications Research Corporation (OAR).
14 *
15 *  The license and distribution terms for this file may be
16 *  found in the file LICENSE in this distribution or at
17 *  http://www.OARcorp.com/rtems/license.html.
18 *
19 *  $Id$
20 */
21
22/*
23OUTPUT_FORMAT("coff-sh")
24 */
25OUTPUT_ARCH(sh)
26ENTRY(_start)
27
28_HeapSize = DEFINED(_HeapSize) ? _HeapSize : (512 * 1024);
29_WorkspaceSize = DEFINED(_WorkspaceSize) ? _WorkspaceSize : (1024 * 1024);
30
31/* These assignments load code into SH7045F EVB SRAM for monitor debugging */
32
33MEMORY
34{
35  ram           : o = 0x00000000, l = 0x01000000
36}
37
38/* Sections are defined for RAM loading and monitor debugging */
39SECTIONS
40{
41
42  /* Read-only sections, merged into text segment: */
43
44  . = 0x00004000 ;
45  .interp        : { *(.interp)         }
46  .hash          : { *(.hash)           }
47  .dynsym        : { *(.dynsym)         }
48  .dynstr        : { *(.dynstr)         }
49  .gnu.version   : { *(.gnu.version)    }
50  .gnu.version_d : { *(.gnu.version_d)  }
51  .gnu.version_r : { *(.gnu.version_r)  }
52  .rel.text      :
53    { *(.rel.text) *(.rel.gnu.linkonce.t*) }
54  .rela.text     :
55    { *(.rela.text) *(.rela.gnu.linkonce.t*) }
56  .rel.data      :
57    { *(.rel.data) *(.rel.gnu.linkonce.d*) }
58  .rela.data     :
59    { *(.rela.data) *(.rela.gnu.linkonce.d*) }
60  .rel.rodata    :
61    { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
62  .rela.rodata   :
63    { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
64  .rel.got       : { *(.rel.got)                }
65  .rela.got      : { *(.rela.got)               }
66  .rel.ctors     : { *(.rel.ctors)      }
67  .rela.ctors    : { *(.rela.ctors)     }
68  .rel.dtors     : { *(.rel.dtors)      }
69  .rela.dtors    : { *(.rela.dtors)     }
70  .rel.init      : { *(.rel.init)       }
71  .rela.init     : { *(.rela.init)      }
72  .rel.fini      : { *(.rel.fini)       }
73  .rela.fini     : { *(.rela.fini)      }
74  .rel.bss       : { *(.rel.bss)                }
75  .rela.bss      : { *(.rela.bss)               }
76  .rel.plt       : { *(.rel.plt)                }
77  .rela.plt      : { *(.rela.plt)               }
78  .init          : { *(.init)   } =0
79  .plt           : { *(.plt)    }
80  .text   .      :
81  {
82    *(.text)
83    *(.stub)
84    /* .gnu.warning sections are handled specially by elf32.em.  */
85    *(.gnu.warning)
86    *(.gnu.linkonce.t*)
87  } > ram
88  _etext = .;
89  PROVIDE (etext = .);
90  .fini    .  : { *(.fini)    } =0
91  .rodata  .  : { *(.rodata) *(.gnu.linkonce.r*) }
92  .rodata1 .  : { *(.rodata1) }
93  /* Adjust the address for the data segment.  We want to adjust up to
94     the same address within the page on the next page up.  */
95  . = ALIGN(128) + (. & (128 - 1));
96  .data  .  :
97  {
98    *(.data)
99    *(.gnu.linkonce.d*)
100    CONSTRUCTORS
101  } > ram
102  .data1  . : { *(.data1) }
103  .ctors  .       :
104  {
105    ___ctors = .;
106    *(.ctors)
107    ___ctors_end = .;
108  }
109  .dtors  .       :
110  {
111    ___dtors = .;
112    *(.dtors)
113    ___dtors_end = .;
114  }
115  .got     .      : { *(.got.plt) *(.got) }
116  .dynamic .      : { *(.dynamic) }
117  /* We want the small data sections together, so single-instruction offsets
118     can access them all, and initialized data all before uninitialized, so
119     we can shorten the on-disk segment size.  */
120  .sdata   .  : { *(.sdata) }
121  _edata  =  .;
122  PROVIDE (edata = .);
123  __bss_start = .;
124  .sbss    .  : { *(.sbss) *(.scommon) }
125  .bss     .  :
126  {
127   *(.dynbss)
128   *(.bss)
129   *(COMMON)
130  } > ram
131  _end = . ;
132  PROVIDE (end = .);
133
134  . = ALIGN(16);
135  _HeapStart = . ;
136  . = . + _HeapSize ;
137  PROVIDE( _HeapEnd = . );
138
139  . = ALIGN(16);
140  _WorkSpaceStart = . ;
141  . = . + _WorkspaceSize ;
142  PROVIDE(_WorkSpaceEnd = .);
143
144  . = ALIGN(16);
145  .stack . : {
146     . = . + 4096;
147  }
148
149  . = ALIGN(16);
150  _CPU_Interrupt_stack_low  = . ;
151  _CPU_Interrupt_stack_high = _CPU_Interrupt_stack_low + 4096 ;
152
153  /* Stabs debugging sections.  */
154  .stab 0 : { *(.stab) }
155  .stabstr 0 : { *(.stabstr) }
156  .stab.excl 0 : { *(.stab.excl) }
157  .stab.exclstr 0 : { *(.stab.exclstr) }
158  .stab.index 0 : { *(.stab.index) }
159  .stab.indexstr 0 : { *(.stab.indexstr) }
160  .comment 0 : { *(.comment) }
161  /* DWARF debug sections.
162     Symbols in the DWARF debugging sections are relative to the beginning
163     of the section so we begin them at 0.  */
164  /* DWARF 1 */
165  .debug          0 : { *(.debug) }
166  .line           0 : { *(.line) }
167  /* GNU DWARF 1 extensions */
168  .debug_srcinfo  0 : { *(.debug_srcinfo) }
169  .debug_sfnames  0 : { *(.debug_sfnames) }
170  /* DWARF 1.1 and DWARF 2 */
171  .debug_aranges  0 : { *(.debug_aranges) }
172  .debug_pubnames 0 : { *(.debug_pubnames) }
173  /* DWARF 2 */
174  .debug_info     0 : { *(.debug_info) }
175  .debug_abbrev   0 : { *(.debug_abbrev) }
176  .debug_line     0 : { *(.debug_line) }
177  .debug_frame    0 : { *(.debug_frame) }
178  .debug_str      0 : { *(.debug_str) }
179  .debug_loc      0 : { *(.debug_loc) }
180  .debug_macinfo  0 : { *(.debug_macinfo) }
181  /* SGI/MIPS DWARF 2 extensions */
182  .debug_weaknames 0 : { *(.debug_weaknames) }
183  .debug_funcnames 0 : { *(.debug_funcnames) }
184  .debug_typenames 0 : { *(.debug_typenames) }
185  .debug_varnames  0 : { *(.debug_varnames) }
186
187}
Note: See TracBrowser for help on using the repository browser.