source: rtems/c/src/lib/libbsp/sh/simsh4/startup/linkcmds @ 628d804

4.104.115
Last change on this file since 628d804 was 628d804, checked in by Joel Sherrill <joel.sherrill@…>, on Sep 15, 2008 at 7:18:36 PM

2008-09-15 Joel Sherrill <joel.sherrill@…>

  • Makefile.am, configure.ac, include/bsp.h, startup/hw_init.c, startup/linkcmds, startup/linkcmds-le, startup/linkcmds-le.coff: Use shared bsp_get_work_area() in its own file and rely on BSP Framework to perform more initialization. After factoring this out, it turned out that all SuperH BSPs has the same bsp_start() implementation so this was made shared.
  • startup/bspstart.c: Removed.
  • Property mode set to 100644
File size: 5.7 KB
Line 
1/*
2 * Memory layout for SH4 GNU simulator.
3 *
4 * Copyright (C) 2001 OKTET Ltd., St.-Petersburg, Russia
5 * Author: Victor V. Vengerov <vvv@oktet.ru>
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
10 *
11 *
12 *  COPYRIGHT (c) 1998-2001.
13 *  On-Line Applications Research Corporation (OAR).
14 *
15 *  The license and distribution terms for this file may be
16 *  found in the file LICENSE in this distribution or at
17 *  http://www.rtems.com/license/LICENSE.
18 *
19 *  $Id$
20 */
21
22/*
23OUTPUT_FORMAT("coff-sh")
24 */
25OUTPUT_ARCH(sh)
26ENTRY(_start)
27
28/* These assignments load code into SH7045F EVB SRAM for monitor debugging */
29
30_RamBase = DEFINED(_RamBase) ? _RamBase : 0x00000000;
31_RamSize = DEFINED(_RamSize) ? _RamSize : 0x01000000;
32
33MEMORY
34{
35  ram           : o = 0x00000000, l = 0x01000000
36}
37
38/* Sections are defined for RAM loading and monitor debugging */
39SECTIONS
40{
41
42  /* Read-only sections, merged into text segment: */
43
44  . = 0x00004000 ;
45  .interp        : { *(.interp)         }
46  .hash          : { *(.hash)           }
47  .dynsym        : { *(.dynsym)         }
48  .dynstr        : { *(.dynstr)         }
49  .gnu.version   : { *(.gnu.version)    }
50  .gnu.version_d : { *(.gnu.version_d)  }
51  .gnu.version_r : { *(.gnu.version_r)  }
52  .rela.dyn       :
53    {
54      *(.rela.init)
55      *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*)
56      *(.rela.fini)
57      *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*)
58      *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*)
59      *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*)
60      *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*)
61      *(.rela.ctors)
62      *(.rela.dtors)
63      *(.rela.got)
64      *(.rela.sdata .rela.sdata.* .rela.gnu.linkonce.s.*)
65      *(.rela.sbss .rela.sbss.* .rela.gnu.linkonce.sb.*)
66      *(.rela.sdata2 .rela.sdata2.* .rela.gnu.linkonce.s2.*)
67      *(.rela.sbss2 .rela.sbss2.* .rela.gnu.linkonce.sb2.*)
68      *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)
69    } >ram
70  .rel.text      :
71    { *(.rel.text) *(.rel.gnu.linkonce.t*) }
72  .rel.data      :
73    { *(.rel.data) *(.rel.gnu.linkonce.d*) }
74  .rel.rodata    :
75    { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
76  .rel.got       : { *(.rel.got)                }
77  .rel.ctors     : { *(.rel.ctors)      }
78  .rel.dtors     : { *(.rel.dtors)      }
79  .rel.init      : { *(.rel.init)       }
80  .rel.fini      : { *(.rel.fini)       }
81  .rel.bss       : { *(.rel.bss)                }
82  .rel.plt       : { *(.rel.plt)                }
83  .init          : { *(.init)   } =0
84  .plt           : { *(.plt)    }
85  .text   .      :
86  {
87    _start = .;
88    *(.text*)
89    *(.stub)
90
91    /*
92     * Special FreeBSD sysctl sections.
93     */
94    . = ALIGN (16);
95    ___start_set_sysctl_set = .;
96    *(set_sysc*);   /* set_sysctl_* but name is truncated by SH-coff */
97    ___stop_set_sysctl_set = ABSOLUTE(.);
98    *(set_doma*);   /* set_domain_* but name is truncated by SH-coff */
99    *(set_pseu*);   /* set_pseudo_* but name is truncated by SH-coff */
100
101    /* .gnu.warning sections are handled specially by elf32.em.  */
102    *(.gnu.warning)
103    *(.gnu.linkonce.t*)
104  } > ram
105  _etext = .;
106  PROVIDE (etext = .);
107  .fini    .  : { *(.fini)    } =0
108  .rodata  .  : { *(.rodata*) *(.gnu.linkonce.r*) }
109  .rodata1 .  : { *(.rodata1) }
110  /* Adjust the address for the data segment.  We want to adjust up to
111     the same address within the page on the next page up.  */
112  . = ALIGN(128) + (. & (128 - 1));
113  .data  .  :
114  {
115    *(.data*)
116    *(.gcc_exc*)
117    ___EH_FRAME_BEGIN__ = .;
118    *(.eh_fram*)
119    ___EH_FRAME_END__ = .;
120    LONG(0);
121    *(.gcc_except_table*)
122    *(.gnu.linkonce.d*)
123    CONSTRUCTORS
124  } > ram
125  .data1  . : { *(.data1) }
126  .ctors  .       :
127  {
128    ___ctors = .;
129    *(.ctors)
130    ___ctors_end = .;
131  }
132  .dtors  .       :
133  {
134    ___dtors = .;
135    *(.dtors)
136    ___dtors_end = .;
137  }
138  .got     .      : { *(.got.plt) *(.got) }
139  .dynamic .      : { *(.dynamic) }
140  /* We want the small data sections together, so single-instruction offsets
141     can access them all, and initialized data all before uninitialized, so
142     we can shorten the on-disk segment size.  */
143  .sdata   .  : { *(.sdata) }
144  _edata  =  .;
145  PROVIDE (edata = .);
146  __bss_start = .;
147  .sbss    .  : { *(.sbss*) *(.scommon) }
148  .bss     .  :
149  {
150   *(.dynbss)
151   *(.bss .bss* .gnu.linkonce.b*)
152   *(COMMON)
153  } > ram
154  _end = . ;
155  PROVIDE (end = .);
156
157  . = ALIGN(16);
158  .stack . : {
159     . = . + 4096;
160  }
161
162  . = ALIGN(16);
163  _WorkSpaceStart = . ;
164
165  . = ALIGN(16);
166  _CPU_Interrupt_stack_low  = . ;
167  _CPU_Interrupt_stack_high = _CPU_Interrupt_stack_low + 4096 ;
168
169  /* Stabs debugging sections.  */
170  .stab 0 : { *(.stab) }
171  .stabstr 0 : { *(.stabstr) }
172  .stab.excl 0 : { *(.stab.excl) }
173  .stab.exclstr 0 : { *(.stab.exclstr) }
174  .stab.index 0 : { *(.stab.index) }
175  .stab.indexstr 0 : { *(.stab.indexstr) }
176  .comment 0 : { *(.comment) }
177  /* DWARF debug sections.
178     Symbols in the DWARF debugging sections are relative to the beginning
179     of the section so we begin them at 0.  */
180  /* DWARF 1 */
181  .debug          0 : { *(.debug) }
182  .line           0 : { *(.line) }
183  /* GNU DWARF 1 extensions */
184  .debug_srcinfo  0 : { *(.debug_srcinfo) }
185  .debug_sfnames  0 : { *(.debug_sfnames) }
186  /* DWARF 1.1 and DWARF 2 */
187  .debug_aranges  0 : { *(.debug_aranges) }
188  .debug_pubnames 0 : { *(.debug_pubnames) }
189  /* DWARF 2 */
190  .debug_info     0 : { *(.debug_info) }
191  .debug_abbrev   0 : { *(.debug_abbrev) }
192  .debug_line     0 : { *(.debug_line) }
193  .debug_frame    0 : { *(.debug_frame) }
194  .debug_str      0 : { *(.debug_str) }
195  .debug_loc      0 : { *(.debug_loc) }
196  .debug_macinfo  0 : { *(.debug_macinfo) }
197  /* SGI/MIPS DWARF 2 extensions */
198  .debug_weaknames 0 : { *(.debug_weaknames) }
199  .debug_funcnames 0 : { *(.debug_funcnames) }
200  .debug_typenames 0 : { *(.debug_typenames) }
201  .debug_varnames  0 : { *(.debug_varnames) }
202
203}
Note: See TracBrowser for help on using the repository browser.