source: rtems/c/src/lib/libbsp/sh/shsim/startup/linkcmds @ 512d0fc

4.104.11
Last change on this file since 512d0fc was 512d0fc, checked in by Joel Sherrill <joel.sherrill@…>, on Sep 15, 2008 at 7:18:31 PM

2008-09-15 Joel Sherrill <joel.sherrill@…>

  • Makefile.am, configure.ac, include/bsp.h, startup/linkcmds: Use shared bsp_get_work_area() in its own file and rely on BSP Framework to perform more initialization. After factoring this out, it turned out that all SuperH BSPs has the same bsp_start() implementation so this was made shared.
  • Property mode set to 100644
File size: 6.2 KB
Line 
1/*
2 * Memory layout for an SH 7032 with main memory in area 0
3 *
4 * NOTES:
5 * + All RAM/ROM areas are mapped onto area 0, because gdb's simulator
6 * is not able to simulate memory areas but area 0. Area 5 (on-chip
7 * peripherials) can not be mapped onto area 0 and will cause SIGILL
8 * exceptions.
9 * + Assumed to be compatible with other SH-cpu family members (eg. SH7045)
10 *
11 *  Authors: Ralf Corsepius (corsepiu@faw.uni-ulm.de)
12 *
13 *  COPYRIGHT (c) 2001, Ralf Corsepius, Ulm, Germany
14 *
15 *  This program is distributed in the hope that it will be useful,
16 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
17 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
18 *
19 *  $Id$
20 */
21
22OUTPUT_ARCH(sh)
23ENTRY(_start)
24
25_RamBase = DEFINED(_RamBase) ? _RamBase : 0x00040000;
26_RamSize = DEFINED(_RamSize) ? _RamSize : 512K;
27
28MEMORY
29{
30/* Real memory layout submitted
31  rom           : o = 0x00000000, l = 128k
32  ram           : o = 0x00040000, l = 256k
33*/
34
35/* Memory layout which links all tests */
36  rom           : o = 0x01000000, l = 512k
37  ram           : o = 0x00040000, l = 512k
38
39  onchip_peri   : o = 0x05000000, l = 512
40}
41
42SECTIONS
43{
44  /* boot vector table */
45  .monvects (NOLOAD) :
46  {
47    _monvects = . ;
48  } > rom
49
50  /* monitor play area */
51  .monram 0x00040000 (NOLOAD) :
52  {
53  _ramstart = .;
54  } > ram
55
56  /* monitor vector table */
57  .vects   0x00042000 (NOLOAD) : {
58    _vectab = . ;
59    *(.vects);
60  }
61
62  /* Read-only sections, merged into text segment: */
63
64  . = 0x00044000 ;
65  .interp        : { *(.interp)         }
66  .hash          : { *(.hash)           }
67  .dynsym        : { *(.dynsym)         }
68  .dynstr        : { *(.dynstr)         }
69  .gnu.version   : { *(.gnu.version)    }
70  .gnu.version_d : { *(.gnu.version_d)  }
71  .gnu.version_r : { *(.gnu.version_r)  }
72  .rela.dyn       :
73    {
74      *(.rela.init)
75      *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*)
76      *(.rela.fini)
77      *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*)
78      *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*)
79      *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*)
80      *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*)
81      *(.rela.ctors)
82      *(.rela.dtors)
83      *(.rela.got)
84      *(.rela.sdata .rela.sdata.* .rela.gnu.linkonce.s.*)
85      *(.rela.sbss .rela.sbss.* .rela.gnu.linkonce.sb.*)
86      *(.rela.sdata2 .rela.sdata2.* .rela.gnu.linkonce.s2.*)
87      *(.rela.sbss2 .rela.sbss2.* .rela.gnu.linkonce.sb2.*)
88      *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)
89    } >ram
90  .rel.text      :
91    { *(.rel.text) *(.rel.gnu.linkonce.t*) }
92  .rel.data      :
93    { *(.rel.data) *(.rel.gnu.linkonce.d*) }
94  .rel.rodata    :
95    { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
96  .rel.got       : { *(.rel.got)                }
97  .rel.ctors     : { *(.rel.ctors)      }
98  .rel.dtors     : { *(.rel.dtors)      }
99  .rel.init      : { *(.rel.init)       }
100  .rel.fini      : { *(.rel.fini)       }
101  .rel.bss       : { *(.rel.bss)                }
102  .rel.plt       : { *(.rel.plt)                }
103  .init          : { *(.init)   } =0
104  .plt           : { *(.plt)    }
105  .text   .      :
106  {
107    _start = .;
108    *(.text*)
109    *(.stub)
110
111    /*
112     * Special FreeBSD sysctl sections.
113     */
114    . = ALIGN (16);
115    ___start_set_sysctl_set = .;
116    *(set_sysc*);   /* set_sysctl_* but name is truncated by SH-coff */
117    ___stop_set_sysctl_set = ABSOLUTE(.);
118    *(set_doma*);   /* set_domain_* but name is truncated by SH-coff */
119    *(set_pseu*);   /* set_pseudo_* but name is truncated by SH-coff */
120
121    /* .gnu.warning sections are handled specially by elf32.em.  */
122    *(.gnu.warning)
123    *(.gnu.linkonce.t*)
124  } > ram
125  .fini           :
126  {
127    KEEP (*(.fini))
128  } =0
129  _etext = .;
130  PROVIDE (etext = .);
131  .rodata  .  : { *(.rodata*) .rodata.* *(.gnu.linkonce.r*) }
132  .rodata1 .  : { *(.rodata1) }
133  /* Adjust the address for the data segment.  We want to adjust up to
134     the same address within the page on the next page up.  */
135  . = ALIGN(128) + (. & (128 - 1));
136  .data  .  :
137  {
138    *(.data*)
139    *(.gcc_exc*)
140    ___EH_FRAME_BEGIN__ = .;
141    *(.eh_fram*)
142    ___EH_FRAME_END__ = .;
143    LONG(0);
144    *(.gcc_except_table*)
145    *(.gnu.linkonce.d*)
146    CONSTRUCTORS
147  } > ram
148  .data1  . : { *(.data1) }
149  .ctors  .       :
150  {
151    ___ctors = .;
152    *(.ctors)
153    ___ctors_end = .;
154  }
155  .dtors  .       :
156  {
157    ___dtors = .;
158    *(.dtors)
159    ___dtors_end = .;
160  }
161  .got     .      : { *(.got.plt) *(.got) }
162  .dynamic .      : { *(.dynamic) }
163  /* We want the small data sections together, so single-instruction offsets
164     can access them all, and initialized data all before uninitialized, so
165     we can shorten the on-disk segment size.  */
166  .sdata   .  : { *(.sdata) }
167  _edata  =  .;
168  PROVIDE (edata = .);
169  __bss_start = .;
170  .sbss    .  : { *(.sbss*) *(.scommon) }
171  .bss     .  :
172  {
173   *(.dynbss)
174   *(.bss .bss* .gnu.linkonce.b*)
175   *(COMMON)
176  } > ram
177  _end = . ;
178  PROVIDE (end = .);
179
180  _WorkSpaceStart = . ;
181
182  _CPU_Interrupt_stack_low  = 0x00080000 ;
183  _CPU_Interrupt_stack_high = _CPU_Interrupt_stack_low + 4096 ;
184
185  /* Stabs debugging sections.  */
186  .stab 0 : { *(.stab) }
187  .stabstr 0 : { *(.stabstr) }
188  .stab.excl 0 : { *(.stab.excl) }
189  .stab.exclstr 0 : { *(.stab.exclstr) }
190  .stab.index 0 : { *(.stab.index) }
191  .stab.indexstr 0 : { *(.stab.indexstr) }
192  .comment 0 : { *(.comment) }
193  /* DWARF debug sections.
194     Symbols in the DWARF debugging sections are relative to the beginning
195     of the section so we begin them at 0.  */
196  /* DWARF 1 */
197  .debug          0 : { *(.debug) }
198  .line           0 : { *(.line) }
199  /* GNU DWARF 1 extensions */
200  .debug_srcinfo  0 : { *(.debug_srcinfo) }
201  .debug_sfnames  0 : { *(.debug_sfnames) }
202  /* DWARF 1.1 and DWARF 2 */
203  .debug_aranges  0 : { *(.debug_aranges) }
204  .debug_pubnames 0 : { *(.debug_pubnames) }
205  /* DWARF 2 */
206  .debug_info     0 : { *(.debug_info) }
207  .debug_abbrev   0 : { *(.debug_abbrev) }
208  .debug_line     0 : { *(.debug_line) }
209  .debug_frame    0 : { *(.debug_frame) }
210  .debug_str      0 : { *(.debug_str) }
211  .debug_loc      0 : { *(.debug_loc) }
212  .debug_macinfo  0 : { *(.debug_macinfo) }
213  /* SGI/MIPS DWARF 2 extensions */
214  .debug_weaknames 0 : { *(.debug_weaknames) }
215  .debug_funcnames 0 : { *(.debug_funcnames) }
216  .debug_typenames 0 : { *(.debug_typenames) }
217  .debug_varnames  0 : { *(.debug_varnames) }
218
219  .stack /* 0x00081ff0 */: { _stack = .; *(.stack) } > ram /* > onchip_ram */
220  /* These must appear regardless of  .  */
221}
Note: See TracBrowser for help on using the repository browser.