source: rtems/c/src/lib/libbsp/sh/gensh2/startup/linkcmds @ d1f57b5

4.104.114.95
Last change on this file since d1f57b5 was d1f57b5, checked in by Joel Sherrill <joel.sherrill@…>, on Mar 3, 2008 at 11:07:47 PM

2008-03-03 Joel Sherrill <joel.sherrill@…>

  • startup/linkcmds: Add wildcard to gcc_except_table section so programs compiled with gcc 4.3.x can link.
  • Property mode set to 100644
File size: 6.9 KB
Line 
1/*
2 * This is an adapted linker script from egcs-1.0.1
3 *
4 * Memory layout for an SH7045F with main memory in area 2
5 * This memory layout it very similar to that used for Hitachi's
6 * EVB with CMON in FLASH
7 *
8 * NOTE: The ram start address may vary, all other start addresses are fixed
9 *       Not suiteable for gdb's simulator
10 *
11 *  Authors: Ralf Corsepius (corsepiu@faw.uni-ulm.de) and
12 *           Bernd Becker (becker@faw.uni-ulm.de)
13 *
14 *  COPYRIGHT (c) 1997-1998, FAW Ulm, Germany
15 *
16 *  This program is distributed in the hope that it will be useful,
17 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
18 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
19 *
20 *
21 *  COPYRIGHT (c) 1998.
22 *  On-Line Applications Research Corporation (OAR).
23 *
24 *  The license and distribution terms for this file may be
25 *  found in the file LICENSE in this distribution or at
26 *  http://www.rtems.com/license/LICENSE.
27 *
28 *      Modified to reflect SH7045F processor and EVB:
29 *      John M. Mills (jmills@tga.com)
30 *      TGA Technologies, Inc.
31 *      100 Pinnacle Way, Suite 140
32 *      Norcross, GA 30071 U.S.A.
33 *
34 *      This modified file may be copied and distributed in accordance
35 *      the above-referenced license. It is provided for critique and
36 *      developmental purposes without any warranty nor representation
37 *      by the authors or by TGA Technologies.
38 *
39 *  $Id$
40 */
41
42OUTPUT_ARCH(sh)
43ENTRY(_start)
44
45/* These assignments load code into SH7045F EVB SRAM for monitor debugging */
46
47MEMORY
48{
49  rom           : o = 0x00400000, l = 0x00040000
50  ram           : o = 0x00440000, l = 0x00080000
51  onchip_peri   : o = 0xFFFF8000, l = 0x00000800
52  onchip_ram    : o = 0xFFFFF000, l = 0x00001000
53}
54
55/* Sections are defined for RAM loading and monitor debugging */
56SECTIONS
57{
58  /* boot vector table */
59  .monvects 0x00400000 (NOLOAD): {
60    _monvects = . ;
61  } > rom
62
63  /* monitor play area */
64  .monram 0x00440000 (NOLOAD) :
65  {
66  _ramstart = .;
67  } > ram
68
69  /* monitor vector table */
70  .vects   0x00442000 (NOLOAD) : {
71    _vectab = . ;
72    *(.vects);
73  }
74
75  /* Read-only sections, merged into text segment: */
76
77  . = 0x00444000 ;
78  .interp        : { *(.interp)         }
79  .hash          : { *(.hash)           }
80  .dynsym        : { *(.dynsym)         }
81  .dynstr        : { *(.dynstr)         }
82  .gnu.version   : { *(.gnu.version)    }
83  .gnu.version_d : { *(.gnu.version_d)  }
84  .gnu.version_r : { *(.gnu.version_r)  }
85  .rela.dyn       :
86    {
87      *(.rela.init)
88      *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*)
89      *(.rela.fini)
90      *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*)
91      *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*)
92      *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*)
93      *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*)
94      *(.rela.ctors)
95      *(.rela.dtors)
96      *(.rela.got)
97      *(.rela.sdata .rela.sdata.* .rela.gnu.linkonce.s.*)
98      *(.rela.sbss .rela.sbss.* .rela.gnu.linkonce.sb.*)
99      *(.rela.sdata2 .rela.sdata2.* .rela.gnu.linkonce.s2.*)
100      *(.rela.sbss2 .rela.sbss2.* .rela.gnu.linkonce.sb2.*)
101      *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)
102    } >ram
103  .rel.text      :
104    { *(.rel.text) *(.rel.gnu.linkonce.t*) }
105  .rel.data      :
106    { *(.rel.data) *(.rel.gnu.linkonce.d*) }
107  .rel.rodata    :
108    { *(.rel.rodata*) *(.rel.gnu.linkonce.r*) }
109  .rel.got       : { *(.rel.got)                }
110  .rel.ctors     : { *(.rel.ctors)      }
111  .rel.dtors     : { *(.rel.dtors)      }
112  .rel.init      : { *(.rel.init)       }
113  .rel.fini      : { *(.rel.fini)       }
114  .rel.bss       : { *(.rel.bss)                }
115  .rel.plt       : { *(.rel.plt)                }
116  .init          : { *(.init)   } =0
117  .plt           : { *(.plt)    }
118  .text   .      :
119  {
120    *(.text*)
121    *(.stub)
122
123    /*
124     * Special FreeBSD sysctl sections.
125     */
126    . = ALIGN (16);
127    ___start_set_sysctl_set = .;
128    *(set_sysc*);   /* set_sysctl_* but name is truncated by SH-coff */
129    ___stop_set_sysctl_set = ABSOLUTE(.);
130    *(set_doma*);   /* set_domain_* but name is truncated by SH-coff */
131    *(set_pseu*);   /* set_pseudo_* but name is truncated by SH-coff */
132
133    /* .gnu.warning sections are handled specially by elf32.em.  */
134    *(.gnu.warning)
135    *(.gnu.linkonce.t*)
136  } > ram
137  _etext = .;
138  PROVIDE (etext = .);
139  .fini    .  : { *(.fini)    } =0
140  .rodata  .  : { *(.rodata*) *(.gnu.linkonce.r*) }
141  .rodata1 .  : { *(.rodata1) }
142  /* Adjust the address for the data segment.  We want to adjust up to
143     the same address within the page on the next page up.  */
144  . = ALIGN(128) + (. & (128 - 1));
145  .data  .  :
146  {
147    *(.data*)
148    *(.gcc_exc*)
149    ___EH_FRAME_BEGIN__ = .;
150    *(.eh_fram*)
151    ___EH_FRAME_END__ = .;
152    LONG(0);
153    *(.gcc_except_table*)
154    *(.gnu.linkonce.d*)
155    CONSTRUCTORS
156  } > ram
157  .data1  . : { *(.data1) }
158  .ctors  .       :
159  {
160    ___ctors = .;
161    *(.ctors)
162    ___ctors_end = .;
163  }
164  .dtors  .       :
165  {
166    ___dtors = .;
167    *(.dtors)
168    ___dtors_end = .;
169  }
170  .got     .      : { *(.got.plt) *(.got) }
171  .dynamic .      : { *(.dynamic) }
172  /* We want the small data sections together, so single-instruction offsets
173     can access them all, and initialized data all before uninitialized, so
174     we can shorten the on-disk segment size.  */
175  .sdata   .  : { *(.sdata) }
176  _edata  =  .;
177  PROVIDE (edata = .);
178  __bss_start = .;
179  .sbss    .  : { *(.sbss*) *(.scommon) }
180  .bss     .  :
181  {
182   *(.dynbss)
183   *(.bss .bss* .gnu.linkonce.b*)
184   *(COMMON)
185  } > ram
186  _end = . ;
187  PROVIDE (end = .);
188
189  _HeapStart = . ;
190  . = . + 1024 * 20 ;
191  PROVIDE( _HeapEnd = . );
192
193  _WorkSpaceStart = . ;
194  . = 0x00480000 ;
195  PROVIDE(_WorkSpaceEnd = .);
196
197  _CPU_Interrupt_stack_low  = 0xFFFFF000;
198  _CPU_Interrupt_stack_high = 0xFFFFFFFF;
199
200  /* Stabs debugging sections.  */
201  .stab 0 : { *(.stab) }
202  .stabstr 0 : { *(.stabstr) }
203  .stab.excl 0 : { *(.stab.excl) }
204  .stab.exclstr 0 : { *(.stab.exclstr) }
205  .stab.index 0 : { *(.stab.index) }
206  .stab.indexstr 0 : { *(.stab.indexstr) }
207  .comment 0 : { *(.comment) }
208  /* DWARF debug sections.
209     Symbols in the DWARF debugging sections are relative to the beginning
210     of the section so we begin them at 0.  */
211  /* DWARF 1 */
212  .debug          0 : { *(.debug) }
213  .line           0 : { *(.line) }
214  /* GNU DWARF 1 extensions */
215  .debug_srcinfo  0 : { *(.debug_srcinfo) }
216  .debug_sfnames  0 : { *(.debug_sfnames) }
217  /* DWARF 1.1 and DWARF 2 */
218  .debug_aranges  0 : { *(.debug_aranges) }
219  .debug_pubnames 0 : { *(.debug_pubnames) }
220  /* DWARF 2 */
221  .debug_info     0 : { *(.debug_info) }
222  .debug_abbrev   0 : { *(.debug_abbrev) }
223  .debug_line     0 : { *(.debug_line) }
224  .debug_frame    0 : { *(.debug_frame) }
225  .debug_str      0 : { *(.debug_str) }
226  .debug_loc      0 : { *(.debug_loc) }
227  .debug_macinfo  0 : { *(.debug_macinfo) }
228  /* SGI/MIPS DWARF 2 extensions */
229  .debug_weaknames 0 : { *(.debug_weaknames) }
230  .debug_funcnames 0 : { *(.debug_funcnames) }
231  .debug_typenames 0 : { *(.debug_typenames) }
232  .debug_varnames  0 : { *(.debug_varnames) }
233
234  .stack 0xFFFFFEC0 : { _stack = .; *(.stack) } > onchip_ram
235  /* These must appear regardless of  .  */
236}
Note: See TracBrowser for help on using the repository browser.