source: rtems/c/src/lib/libbsp/sh/gensh2/startup/linkcmds @ 716d0d4

4.104.114.84.95
Last change on this file since 716d0d4 was 716d0d4, checked in by Joel Sherrill <joel.sherrill@…>, on Nov 8, 2002 at 12:13:12 AM

2002-11-07 Joel Sherrill <joel@…>

  • startup/linkcmds: Include all .rodata* sections.
  • Property mode set to 100644
File size: 6.3 KB
Line 
1/*
2 * This is an adapted linker script from egcs-1.0.1
3 *
4 * Memory layout for an SH7045F with main memory in area 2
5 * This memory layout it very similar to that used for Hitachi's
6 * EVB with CMON in FLASH
7 *
8 * NOTE: The ram start address may vary, all other start addresses are fixed
9 *       Not suiteable for gdb's simulator
10 *
11 *  Authors: Ralf Corsepius (corsepiu@faw.uni-ulm.de) and
12 *           Bernd Becker (becker@faw.uni-ulm.de)
13 *
14 *  COPYRIGHT (c) 1997-1998, FAW Ulm, Germany
15 *
16 *  This program is distributed in the hope that it will be useful,
17 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
18 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
19 *
20 *
21 *  COPYRIGHT (c) 1998.
22 *  On-Line Applications Research Corporation (OAR).
23 *
24 *  The license and distribution terms for this file may be
25 *  found in the file LICENSE in this distribution or at
26 *  http://www.OARcorp.com/rtems/license.html.
27 *
28 *      Modified to reflect SH7045F processor and EVB:
29 *      John M. Mills (jmills@tga.com)
30 *      TGA Technologies, Inc.
31 *      100 Pinnacle Way, Suite 140
32 *      Norcross, GA 30071 U.S.A.
33 *
34 *      This modified file may be copied and distributed in accordance
35 *      the above-referenced license. It is provided for critique and
36 *      developmental purposes without any warranty nor representation
37 *      by the authors or by TGA Technologies.
38 *
39 *  $Id$
40 */
41
42OUTPUT_ARCH(sh)
43ENTRY(_start)
44
45/* These assignments load code into SH7045F EVB SRAM for monitor debugging */
46
47MEMORY
48{
49  rom           : o = 0x00400000, l = 0x00040000
50  ram           : o = 0x00440000, l = 0x00040000
51  onchip_peri   : o = 0xFFFF8000, l = 0x00000800
52  onchip_ram    : o = 0xFFFFF000, l = 0x00001000
53}
54
55/* Sections are defined for RAM loading and monitor debugging */
56SECTIONS
57{
58  /* boot vector table */
59  .monvects 0x00400000 (NOLOAD): {
60    _monvects = . ;
61  } > rom
62
63  /* monitor play area */
64  .monram 0x00440000 (NOLOAD) :
65  {
66  _ramstart = .;
67  } > ram
68
69  /* monitor vector table */
70  .vects   0x00442000 (NOLOAD) : {
71    _vectab = . ;
72    *(.vects);
73  }
74
75  /* Read-only sections, merged into text segment: */
76
77  . = 0x00444000 ;
78  .interp        : { *(.interp)         }
79  .hash          : { *(.hash)           }
80  .dynsym        : { *(.dynsym)         }
81  .dynstr        : { *(.dynstr)         }
82  .gnu.version   : { *(.gnu.version)    }
83  .gnu.version_d : { *(.gnu.version_d)  }
84  .gnu.version_r : { *(.gnu.version_r)  }
85  .rel.text      :
86    { *(.rel.text) *(.rel.gnu.linkonce.t*) }
87  .rela.text     :
88    { *(.rela.text) *(.rela.gnu.linkonce.t*) }
89  .rel.data      :
90    { *(.rel.data) *(.rel.gnu.linkonce.d*) }
91  .rela.data     :
92    { *(.rela.data) *(.rela.gnu.linkonce.d*) }
93  .rel.rodata    :
94    { *(.rel.rodata*) *(.rel.gnu.linkonce.r*) }
95  .rela.rodata   :
96    { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
97  .rel.got       : { *(.rel.got)                }
98  .rela.got      : { *(.rela.got)               }
99  .rel.ctors     : { *(.rel.ctors)      }
100  .rela.ctors    : { *(.rela.ctors)     }
101  .rel.dtors     : { *(.rel.dtors)      }
102  .rela.dtors    : { *(.rela.dtors)     }
103  .rel.init      : { *(.rel.init)       }
104  .rela.init     : { *(.rela.init)      }
105  .rel.fini      : { *(.rel.fini)       }
106  .rela.fini     : { *(.rela.fini)      }
107  .rel.bss       : { *(.rel.bss)                }
108  .rela.bss      : { *(.rela.bss)               }
109  .rel.plt       : { *(.rel.plt)                }
110  .rela.plt      : { *(.rela.plt)               }
111  .init          : { *(.init)   } =0
112  .plt           : { *(.plt)    }
113  .text   .      :
114  {
115    *(.text)
116    *(.stub)
117    /* .gnu.warning sections are handled specially by elf32.em.  */
118    *(.gnu.warning)
119    *(.gnu.linkonce.t*)
120  } > ram
121  _etext = .;
122  PROVIDE (etext = .);
123  .fini    .  : { *(.fini)    } =0
124  .rodata  .  : { *(.rodata) *(.gnu.linkonce.r*) }
125  .rodata1 .  : { *(.rodata1) }
126  /* Adjust the address for the data segment.  We want to adjust up to
127     the same address within the page on the next page up.  */
128  . = ALIGN(128) + (. & (128 - 1));
129  .data  .  :
130  {
131    *(.data)
132    *(.gcc_exc*)
133    ___EH_FRAME_BEGIN__ = .;
134    *(.eh_fram*)
135    ___EH_FRAME_END__ = .;
136    LONG(0);
137    *(.gcc_except_table)
138    *(.gnu.linkonce.d*)
139    CONSTRUCTORS
140  } > ram
141  .data1  . : { *(.data1) }
142  .ctors  .       :
143  {
144    ___ctors = .;
145    *(.ctors)
146    ___ctors_end = .;
147  }
148  .dtors  .       :
149  {
150    ___dtors = .;
151    *(.dtors)
152    ___dtors_end = .;
153  }
154  .got     .      : { *(.got.plt) *(.got) }
155  .dynamic .      : { *(.dynamic) }
156  /* We want the small data sections together, so single-instruction offsets
157     can access them all, and initialized data all before uninitialized, so
158     we can shorten the on-disk segment size.  */
159  .sdata   .  : { *(.sdata) }
160  _edata  =  .;
161  PROVIDE (edata = .);
162  __bss_start = .;
163  .sbss    .  : { *(.sbss) *(.scommon) }
164  .bss     .  :
165  {
166   *(.dynbss)
167   *(.bss)
168   *(COMMON)
169  } > ram
170  _end = . ;
171  PROVIDE (end = .);
172
173  _HeapStart = . ;
174  . = . + 1024 * 20 ;
175  PROVIDE( _HeapEnd = . );
176
177  _WorkSpaceStart = . ;
178  . = 0x00480000 ;
179  PROVIDE(_WorkSpaceEnd = .);
180
181  _CPU_Interrupt_stack_low  = 0xFFFFF000 ;
182  _CPU_Interrupt_stack_high = _CPU_Interrupt_stack_low + 4096 ;
183
184  /* Stabs debugging sections.  */
185  .stab 0 : { *(.stab) }
186  .stabstr 0 : { *(.stabstr) }
187  .stab.excl 0 : { *(.stab.excl) }
188  .stab.exclstr 0 : { *(.stab.exclstr) }
189  .stab.index 0 : { *(.stab.index) }
190  .stab.indexstr 0 : { *(.stab.indexstr) }
191  .comment 0 : { *(.comment) }
192  /* DWARF debug sections.
193     Symbols in the DWARF debugging sections are relative to the beginning
194     of the section so we begin them at 0.  */
195  /* DWARF 1 */
196  .debug          0 : { *(.debug) }
197  .line           0 : { *(.line) }
198  /* GNU DWARF 1 extensions */
199  .debug_srcinfo  0 : { *(.debug_srcinfo) }
200  .debug_sfnames  0 : { *(.debug_sfnames) }
201  /* DWARF 1.1 and DWARF 2 */
202  .debug_aranges  0 : { *(.debug_aranges) }
203  .debug_pubnames 0 : { *(.debug_pubnames) }
204  /* DWARF 2 */
205  .debug_info     0 : { *(.debug_info) }
206  .debug_abbrev   0 : { *(.debug_abbrev) }
207  .debug_line     0 : { *(.debug_line) }
208  .debug_frame    0 : { *(.debug_frame) }
209  .debug_str      0 : { *(.debug_str) }
210  .debug_loc      0 : { *(.debug_loc) }
211  .debug_macinfo  0 : { *(.debug_macinfo) }
212  /* SGI/MIPS DWARF 2 extensions */
213  .debug_weaknames 0 : { *(.debug_weaknames) }
214  .debug_funcnames 0 : { *(.debug_funcnames) }
215  .debug_typenames 0 : { *(.debug_typenames) }
216  .debug_varnames  0 : { *(.debug_varnames) }
217
218  .stack 0xFFFFFEC0 : { _stack = .; *(.stack) } > onchip_ram
219  /* These must appear regardless of  .  */
220}
Note: See TracBrowser for help on using the repository browser.