source: rtems/c/src/lib/libbsp/powerpc/shared/start/start.S @ c499856

4.115
Last change on this file since c499856 was c499856, checked in by Chris Johns <chrisj@…>, on Mar 20, 2014 at 9:10:47 PM

Change all references of rtems.com to rtems.org.

  • Property mode set to 100644
File size: 3.8 KB
Line 
1/*
2 *  start.S :     RTEMS entry point
3 *
4 *  Copyright (C) 1999 Eric Valette. valette@crf.canon.fr
5 *
6 *  The license and distribution terms for this file may be
7 *  found in the file LICENSE in this distribution or at
8 *  http://www.rtems.org/license/LICENSE.
9 *
10 */
11
12#include <rtems/asm.h>
13#include <rtems/score/cpu.h>
14#include <rtems/powerpc/powerpc.h>
15
16#include <libcpu/io.h>
17#include <libcpu/bat.h>
18#include <bspopts.h>
19
20#define SYNC \
21        sync; \
22        isync
23
24#define KERNELBASE      0x0
25
26#define MONITOR_ENTER                   \
27        mfmsr   r10             ;       \
28        ori     r10,r10,MSR_IP  ;       \
29        mtmsr   r10             ;       \
30        li      r10,0x63        ;       \
31        sc
32
33        .text
34        .globl  __rtems_entry_point
35        .type   __rtems_entry_point,@function
36__rtems_entry_point:
37#ifdef DEBUG_EARLY_START
38        MONITOR_ENTER
39#endif
40
41/*
42 * PREP
43 * This is jumped to on prep systems right after the kernel is relocated
44 * to its proper place in memory by the boot loader.  The expected layout
45 * of the regs is:
46 *   r3: ptr to residual data
47 *   r4: initrd_start or if no initrd then 0
48 *   r5: initrd_end - unused if r4 is 0
49 *   r6: Start of command line string
50 *   r7: End of command line string
51 *
52 *   The Prep boot loader insure that the MMU is currently off...
53 *
54 */
55
56        mr      r31,r3                  /* save parameters */
57        mr      r30,r4
58        mr      r29,r5
59        mr      r28,r6
60        mr      r27,r7
61
62#ifdef __ALTIVEC__
63        /* enable altivec; gcc may use it! */
64        mfmsr r0
65        oris  r0, r0, (1<<(31-16-6))
66        mtmsr r0
67        /*
68         * set vscr and vrsave to known values
69         */
70        li    r0, 0
71        mtvrsave r0
72        vxor   0,0,0
73        mtvscr 0
74#endif
75
76        /*
77         * Make sure we have nothing in BATS and TLB
78         */
79        bl      CPU_clear_bats_early
80        bl      flush_tlbs
81/*
82 * Use the first pair of BAT registers to map the 1st 256MB
83 * of RAM to KERNELBASE.
84 */
85        lis     r11,KERNELBASE@h
86/* set up BAT registers for 604 */
87        ori     r11,r11,0x1ffe
88        li      r8,2                    /* R/W access */
89        isync
90        mtspr   DBAT0L,r8               /* N.B. 6xx (not 601) have valid */
91        mtspr   DBAT0U,r11              /* bit in upper BAT register */
92        mtspr   IBAT0L,r8
93        mtspr   IBAT0U,r11
94        isync
95
96/*
97 * we now have the 1st 256M of ram mapped with the bats. We are still
98 * running on the bootloader stack and cannot switch to an RTEMS allocated
99 * init stack before copying the residual data that may have been set just after
100 * rtems_end address. This bug has been experienced on MVME2304. Thank to
101 * Till Straumann <strauman@SLAC.Stanford.EDU> for hunting it and suggesting
102 * the appropriate code.
103 */
104
105enter_C_code:
106        bl      MMUon
107        bl      __eabi  /* setup EABI and SYSV environment */
108        bl      zero_bss
109        /*
110         * restore prep boot params
111         */
112        mr      r3,r31
113        mr      r4,r30
114        mr      r5,r29
115        mr      r6,r28
116        mr      r7,r27
117        bl      save_boot_params
118        /*
119         * stack = &__rtems_end + 4096
120         */
121        addis   r9,r0, __stack-PPC_MINIMUM_STACK_FRAME_SIZE@ha
122        addi    r9,r9, __stack-PPC_MINIMUM_STACK_FRAME_SIZE@l
123        /*
124         * align initial stack
125         * (we hope that the bootloader stack was 16-byte aligned
126         * or we haven't used altivec yet...)
127         */
128        li   r0, (CPU_STACK_ALIGNMENT-1)
129        andc r1, r9, r0
130        /*
131         * Tag TOS with a NULL (terminator for stack dump)
132         */
133        li   r0, 0
134        stw  r0, 0(r1)
135       
136        /*
137         * We are now in a environment that is totally independent from
138         * bootloader setup.
139         */
140    /* pass result of 'save_boot_params' to 'boot_card' in R3 */
141        bl      boot_card
142        bl      _return_to_ppcbug
143
144        .globl  MMUon
145        .type   MMUon,@function
146MMUon:
147        mfmsr   r0
148        ori     r0,r0, MSR_IP | MSR_RI | MSR_IR | MSR_DR | MSR_EE | MSR_FE0 | MSR_FE1 | MSR_FP
149#if (PPC_HAS_FPU == 0)
150        xori    r0, r0, MSR_EE | MSR_IP | MSR_FP
151#else
152        xori    r0, r0, MSR_EE | MSR_IP | MSR_FE0 | MSR_FE1
153#endif
154        mflr    r11
155        mtsrr0  r11
156        mtsrr1  r0
157        SYNC
158        rfi
159
160        .globl  MMUoff
161        .type   MMUoff,@function
162MMUoff:
163        mfmsr   r0
164        ori     r0,r0,MSR_IR| MSR_DR | MSR_IP
165        mflr    r11
166        xori    r0,r0,MSR_IR|MSR_DR
167        mtsrr0  r11
168        mtsrr1  r0
169        SYNC
170        rfi
171
172        .globl  _return_to_ppcbug
173        .type   _return_to_ppcbug,@function
174
175_return_to_ppcbug:
176        mflr    r30
177        bl      MMUoff
178        MONITOR_ENTER
179        bl      MMUon
180        mtctr   r30
181        bctr
182
183flush_tlbs:
184        lis     r20, 0x1000
1851:      addic.  r20, r20, -0x1000
186        tlbie   r20
187        bgt     1b
188        sync
189        blr
Note: See TracBrowser for help on using the repository browser.