source: rtems/c/src/lib/libbsp/powerpc/shared/start/start.S @ 5cf0656

Last change on this file since 5cf0656 was 5cf0656, checked in by Éric Tremblay <e.tremblay@…>, on Mar 20, 2018 at 1:14:39 PM

bsps/powerpc: Support more than 256MiB of RAM

Close #3322.

  • Property mode set to 100644
File size: 4.2 KB
Line 
1/*
2 *  start.S :     RTEMS entry point
3 *
4 *  Copyright (C) 1999 Eric Valette. valette@crf.canon.fr
5 *
6 *  The license and distribution terms for this file may be
7 *  found in the file LICENSE in this distribution or at
8 *  http://www.rtems.org/license/LICENSE.
9 *
10 */
11
12#include <rtems/asm.h>
13#include <rtems/score/cpu.h>
14#include <rtems/powerpc/powerpc.h>
15
16#include <libcpu/io.h>
17#include <libcpu/bat.h>
18#include <bspopts.h>
19
20#define SYNC \
21        sync; \
22        isync
23
24#define KERNELBASE      0x0
25
26#define MONITOR_ENTER                   \
27        mfmsr   r10             ;       \
28        ori     r10,r10,MSR_IP  ;       \
29        mtmsr   r10             ;       \
30        li      r10,0x63        ;       \
31        sc
32
33        .text
34        .globl  __rtems_entry_point
35        .type   __rtems_entry_point,@function
36__rtems_entry_point:
37#ifdef DEBUG_EARLY_START
38        MONITOR_ENTER
39#endif
40
41/*
42 * PREP
43 * This is jumped to on prep systems right after the kernel is relocated
44 * to its proper place in memory by the boot loader.  The expected layout
45 * of the regs is:
46 *   r3: ptr to residual data
47 *   r4: initrd_start or if no initrd then 0
48 *   r5: initrd_end - unused if r4 is 0
49 *   r6: Start of command line string
50 *   r7: End of command line string
51 *
52 *   The Prep boot loader insure that the MMU is currently off...
53 *
54 */
55
56        mr      r31,r3                  /* save parameters */
57        mr      r30,r4
58        mr      r29,r5
59        mr      r28,r6
60        mr      r27,r7
61
62#ifdef __ALTIVEC__
63        /* enable altivec; gcc may use it! */
64        mfmsr r0
65        oris  r0, r0, (1<<(31-16-6))
66        mtmsr r0
67        isync
68        /*
69         * set vscr and vrsave to known values
70         */
71        li    r0, 0
72        mtvrsave r0
73        vxor   0,0,0
74        mtvscr 0
75#endif
76
77        /*
78         * Make sure we have nothing in BATS and TLB
79         */
80        bl      CPU_clear_bats_early
81        bl      flush_tlbs
82/*
83 * Use the first pair of BAT registers to map the 1st 256MB
84 * of RAM to KERNELBASE.
85 */
86        lis     r11,KERNELBASE@h
87/* set up BAT registers for 604 */
88        ori     r11,r11,0x1ffe
89        li      r8,2                    /* R/W access */
90        isync
91        mtspr   DBAT0L,r8               /* N.B. 6xx (not 601) have valid */
92        mtspr   DBAT0U,r11              /* bit in upper BAT register */
93        mtspr   IBAT0L,r8
94        mtspr   IBAT0U,r11
95        isync
96/*   Map section where residual is located if outside
97 *   the first 256Mb of RAM.  This is to support cases
98 *   where the available system memory is larger than
99 *   256Mb of RAM.
100 */
101        mr      r9, r1 /* Get where residual was mapped */
102        lis r12,0xf0000000@h
103        and     r9,r9,r12
104        cmpi    0,1,r9, 0
105        beq     enter_C_code
106        isync
107        ori r11,r9,0x1ffe
108        mtspr   DBAT1L,r8               /* N.B. 6xx (not 601) have valid */
109        mtspr   DBAT1U,r11              /* bit in upper BAT register */
110        mtspr   IBAT1L,r8
111        mtspr   IBAT1U,r11
112        isync
113
114/*
115 * we now have the 1st 256M of ram mapped with the bats. We are still
116 * running on the bootloader stack and cannot switch to an RTEMS allocated
117 * init stack before copying the residual data that may have been set just after
118 * rtems_end address. This bug has been experienced on MVME2304. Thank to
119 * Till Straumann <strauman@SLAC.Stanford.EDU> for hunting it and suggesting
120 * the appropriate code.
121 */
122
123enter_C_code:
124        bl      MMUon
125        bl      __eabi  /* setup EABI and SYSV environment */
126        bl      zero_bss
127        /*
128         * restore prep boot params
129         */
130        mr      r3,r31
131        mr      r4,r30
132        mr      r5,r29
133        mr      r6,r28
134        mr      r7,r27
135        bl      save_boot_params
136        /*
137         * stack = &__rtems_end + 4096
138         */
139        addis   r9,r0, __stack-PPC_MINIMUM_STACK_FRAME_SIZE@ha
140        addi    r9,r9, __stack-PPC_MINIMUM_STACK_FRAME_SIZE@l
141        /*
142         * align initial stack
143         * (we hope that the bootloader stack was 16-byte aligned
144         * or we haven't used altivec yet...)
145         */
146        li   r0, (CPU_STACK_ALIGNMENT-1)
147        andc r1, r9, r0
148        /*
149         * Tag TOS with a NULL (terminator for stack dump)
150         */
151        li   r0, 0
152        stw  r0, 0(r1)
153       
154        /*
155         * We are now in a environment that is totally independent from
156         * bootloader setup.
157         */
158    /* pass result of 'save_boot_params' to 'boot_card' in R3 */
159        bl      boot_card
160        bl      _return_to_ppcbug
161
162        .globl  MMUon
163        .type   MMUon,@function
164MMUon:
165        mfmsr   r0
166        ori     r0,r0, MSR_IP | MSR_RI | MSR_IR | MSR_DR | MSR_EE | MSR_FE0 | MSR_FE1 | MSR_FP
167#if (PPC_HAS_FPU == 0)
168        xori    r0, r0, MSR_EE | MSR_IP | MSR_FP
169#else
170        xori    r0, r0, MSR_EE | MSR_IP | MSR_FE0 | MSR_FE1
171#endif
172        mflr    r11
173        mtsrr0  r11
174        mtsrr1  r0
175        SYNC
176        rfi
177
178        .globl  MMUoff
179        .type   MMUoff,@function
180MMUoff:
181        mfmsr   r0
182        ori     r0,r0,MSR_IR| MSR_DR | MSR_IP
183        mflr    r11
184        xori    r0,r0,MSR_IR|MSR_DR
185        mtsrr0  r11
186        mtsrr1  r0
187        SYNC
188        rfi
189
190        .globl  _return_to_ppcbug
191        .type   _return_to_ppcbug,@function
192
193_return_to_ppcbug:
194        mflr    r30
195        bl      MMUoff
196        MONITOR_ENTER
197        bl      MMUon
198        mtctr   r30
199        bctr
200
201flush_tlbs:
202        lis     r20, 0x1000
2031:      addic.  r20, r20, -0x1000
204        tlbie   r20
205        bgt     1b
206        sync
207        blr
Note: See TracBrowser for help on using the repository browser.