source: rtems/c/src/lib/libbsp/powerpc/shared/start/start.S @ 443c35c1

4.104.114.84.95
Last change on this file since 443c35c1 was 443c35c1, checked in by Joel Sherrill <joel.sherrill@…>, on Sep 5, 2000 at 3:53:22 PM

2000-09-05 Joel Sherrill <joel@…>

  • start/start.S: Include proper files to compile.
  • Property mode set to 100644
File size: 4.1 KB
Line 
1/*
2 *  start.S :     RTEMS entry point
3 *
4 *  Copyright (C) 1999 Eric Valette. valette@crf.canon.fr
5 *
6 *  The license and distribution terms for this file may be
7 *  found in found in the file LICENSE in this distribution or at
8 *  http://www.OARcorp.com/rtems/license.html.
9 *
10 *  $Id$
11 *
12 */
13
14#include <libcpu/cpu.h>
15#include <libcpu/io.h>
16#include <asm.h>               /* for targopts.h and PPC_HAS_FPU */
17#include <rtems/score/cpu.h>   /* for CPU_MINIMUM_STACK_FRAME_SIZE */
18
19#define SYNC \
20        sync; \
21        isync
22
23#define KERNELBASE      0x0
24
25#define MONITOR_ENTER                   \
26        mfmsr   r10             ;       \
27        ori     r10,r10,MSR_IP  ;       \
28        mtmsr   r10             ;       \
29        li      r10,0x63        ;       \
30        sc
31                       
32        .text
33        .globl  __rtems_entry_point
34        .type   __rtems_entry_point,@function
35__rtems_entry_point:
36#ifdef DEBUG_EARLY_START
37        MONITOR_ENTER
38#endif 
39               
40/*
41 * PREP
42 * This is jumped to on prep systems right after the kernel is relocated
43 * to its proper place in memory by the boot loader.  The expected layout
44 * of the regs is:     
45 *   r3: ptr to residual data
46 *   r4: initrd_start or if no initrd then 0
47 *   r5: initrd_end - unused if r4 is 0
48 *   r6: Start of command line string
49 *   r7: End of command line string
50 *
51 *   The Prep boot loader insure that the MMU is currently off...
52 *
53 */
54       
55        mr      r31,r3                  /* save parameters */
56        mr      r30,r4
57        mr      r29,r5
58        mr      r28,r6
59        mr      r27,r7
60        /*
61         * Make sure we have nothing in BATS and TLB
62         */
63        bl      clear_bats
64        bl      flush_tlbs
65/*
66 * Use the first pair of BAT registers to map the 1st 64MB
67 * of RAM to KERNELBASE.
68 */
69        lis     r11,KERNELBASE@h
70        ori     r11,r11,0x7fe           /* set up BAT registers for 604 */
71        li      r8,2                    /* R/W access */
72        isync
73        mtspr   DBAT0L,r8               /* N.B. 6xx (not 601) have valid */
74        mtspr   DBAT0U,r11              /* bit in upper BAT register */
75        mtspr   IBAT0L,r8
76        mtspr   IBAT0U,r11
77        isync
78
79/*
80 * we now have the 1st 64M of ram mapped with the bats. We are still
81 * running on the bootloader stack and cannot switch to an RTEMS allocated
82 * init stack before copying the residual data that may have been set just after
83 * rtems_end address. This bug has been experienced on MVME2304. Thank to
84 * Till Straumann <strauman@SLAC.Stanford.EDU> for hunting it and suggesting
85 * the appropriate code.
86 */
87       
88enter_C_code:
89        bl      MMUon
90        bl      zero_bss
91        /*
92         * restore prep boot params
93         */
94        mr      r3,r31
95        mr      r4,r30
96        mr      r5,r29
97        mr      r6,r28
98        mr      r7,r27
99        bl      save_boot_params
100        /*
101         * stack = &__rtems_end + 4096
102         */
103        addis   r9,r0, __rtems_end+(4096-CPU_MINIMUM_STACK_FRAME_SIZE)@ha
104        addi    r9,r9, __rtems_end+(4096-CPU_MINIMUM_STACK_FRAME_SIZE)@l
105        mr      r1, r9
106        /*
107         * We are know in a environment that is totally independent from bootloader setup.
108         */
109        lis     r5,environ@ha
110        la      r5,environ@l(r5)        /* environp */
111        li      r4, 0                   /* argv */
112        li      r3, 0                   /* argc */
113        bl      boot_card
114        bl      _return_to_ppcbug
115       
116        .globl  MMUon
117        .type   MMUon,@function
118MMUon: 
119        mfmsr   r0
120#if (PPC_HAS_FPU == 0)
121        ori     r0,r0, MSR_IP | MSR_RI | MSR_IR | MSR_DR | MSR_EE | MSR_FE0 | MSR_FE1 | MSR_FP
122        xori    r0, r0, MSR_EE | MSR_IP | MSR_FP
123#else
124        ori     r0,r0, MSR_IP | MSR_RI | MSR_IR | MSR_DR | MSR_EE | MSR_FE0 | MSR_FE1 | MSR_FP
125        xori    r0, r0, MSR_EE | MSR_IP | MSR_FE0 | MSR_FE1
126#endif
127        mflr    r11
128        mtsrr0  r11
129        mtsrr1  r0
130        SYNC
131        rfi
132       
133        .globl  MMUoff
134        .type   MMUoff,@function
135MMUoff:
136        mfmsr   r0
137        ori     r0,r0,MSR_IR| MSR_DR | MSR_IP
138        mflr    r11
139        xori    r0,r0,MSR_IR|MSR_DR
140        mtsrr0  r11
141        mtsrr1  r0
142        SYNC
143        rfi
144
145        .globl  _return_to_ppcbug
146        .type   _return_to_ppcbug,@function
147
148       
149_return_to_ppcbug:
150        mflr    r30
151        bl      MMUoff
152        MONITOR_ENTER
153        bl      MMUon
154        mtctr   r30
155        bctr   
156
157/*
158 * An undocumented "feature" of 604e requires that the v bit
159 * be cleared before changing BAT values.
160 *
161 * Also, newer IBM firmware does not clear bat3 and 4 so
162 * this makes sure it's done.
163 *  -- Cort
164 */
165clear_bats:
166        li      r20,0
167        mfspr   r9,PVR
168        rlwinm  r9,r9,16,16,31          /* r9 = 1 for 601, 4 for 604 */
169        cmpwi   r9, 1
170        SYNC
171        beq     1f
172        mtspr   DBAT0U,r20
173        mtspr   DBAT0L,r20     
174        mtspr   DBAT1U,r20
175        mtspr   DBAT1L,r20
176        mtspr   DBAT2U,r20
177        mtspr   DBAT2L,r20     
178        mtspr   DBAT3U,r20
179        mtspr   DBAT3L,r20
1801:     
181        mtspr   IBAT0U,r20
182        mtspr   IBAT0L,r20
183        mtspr   IBAT1U,r20
184        mtspr   IBAT1L,r20
185        mtspr   IBAT2U,r20
186        mtspr   IBAT2L,r20
187        mtspr   IBAT3U,r20
188        mtspr   IBAT3L,r20
189        SYNC   
190        blr
191
192flush_tlbs:
193        lis     r20, 0x1000
1941:      addic.  r20, r20, -0x1000
195        tlbie   r20
196        blt     1b
197        sync
198        blr
199       
200
201        .comm   environ,4,4
Note: See TracBrowser for help on using the repository browser.