source: rtems/c/src/lib/libbsp/powerpc/gen5200/startup/linkcmds @ a557bdf6

4.104.114.9
Last change on this file since a557bdf6 was a557bdf6, checked in by Joel Sherrill <joel.sherrill@…>, on Mar 3, 2008 at 11:07:08 PM

2008-03-03 Joel Sherrill <joel.sherrill@…>

  • startup/linkcmds, startup/linkcmds.brs5l, startup/linkcmds.icecube, startup/linkcmds.pm520: Add wildcard to gcc_except_table section so programs compiled with gcc 4.3.x can link.
  • Property mode set to 100644
File size: 8.3 KB
Line 
1/*
2 *  This file contains directives for the GNU linker which are specific
3 *  to a gen5200 Board
4 *
5 *  linkcmds,v 1.3 2003/01/20 19:53:27 joel Exp
6 */
7
8OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc",
9              "elf32-powerpc")
10OUTPUT_ARCH(powerpc)
11 SEARCH_DIR(/usr/local/rtems/powerpc-rtems/lib);
12 
13ENTRY(start)
14
15/*
16 * Declare some sizes.
17 * XXX: The assignment of ". += XyzSize;" fails in older gld's if the
18 *      number used there is not constant.  If this happens to you, edit
19 *      the lines marked XXX below to use a constant value.
20 */
21HeapSize = DEFINED(HeapSize) ? HeapSize    : 0x6800000;  /* 104M  Heap */
22StackSize = DEFINED(StackSize) ? StackSize :   0x80000;  /* 512 kB   */
23WorkSpaceSize = DEFINED(WorkSpaceSize) ? WorkSpaceSize : 0x80000; /* 512k */
24RamDiskSize = DEFINED(RamDiskSize) ? RamDiskSize : 0x80000; /* 512 ram disk */
25 
26MEMORY
27        {
28        ram : org = 0x0, l = 256M
29        mpc5200_regs : org = 0xF0000000, l = 24K
30        dpram : org = 0xFF000000, l = 0x400
31        flash : org = 0xFFE00000, l = 2M
32        }
33
34
35SECTIONS
36{
37
38   .vectors 0x100 :
39    {
40    *(.vectors)
41    }   
42    > ram
43
44    /*
45     * The stack will live in this area - between the vectors and
46     * the text section.
47     */
48       
49    .text 0x10000:
50    {
51    _textbase = .;
52
53
54    text.start = .;
55
56    /* Entry point is the .entry section */
57    *(.entry)
58    *(.entry2)
59
60    /* Actual Code */
61    *(.text*)
62
63    *(.rodata*)
64    *(.rodata1)
65
66
67    /*
68     * Special FreeBSD sysctl sections.
69     */
70    . = ALIGN (16);
71    __start_set_sysctl_set = .;
72    *(set_sysctl_*);
73    __stop_set_sysctl_set = ABSOLUTE(.);
74    *(set_domain_*);
75    *(set_pseudo_*);
76
77    /* C++ constructors/destructors */
78    *(.gnu.linkonce.t*)
79
80    /*  Initialization and finalization code.
81     *
82     *  Various files can provide initialization and finalization functions.
83     *  The bodies of these functions are in .init and .fini sections. We
84     *  accumulate the bodies here, and prepend function prologues from
85     *  ecrti.o and function epilogues from ecrtn.o. ecrti.o must be linked
86     *  first; ecrtn.o must be linked last. Because these are wildcards, it
87     *  doesn't matter if the user does not actually link against ecrti.o and
88     *  ecrtn.o; the linker won't look for a file to match a wildcard.  The
89     *  wildcard also means that it doesn't matter which directory ecrti.o
90     *  and ecrtn.o are in.
91     */
92    PROVIDE (_init = .);
93    *ecrti.o(.init)
94    *(.init)
95    *ecrtn.o(.init)
96   
97    PROVIDE (_fini = .);
98    *ecrti.o(.fini)
99    *(.fini)
100    *ecrtn.o(.init)
101
102    /*
103     *  C++ constructors and destructors for static objects.
104     *  PowerPC EABI does not use crtstuff yet, so we build "old-style"
105     *  constructor and destructor lists that begin with the list lenght
106     *  end terminate with a NULL entry.
107     */
108     
109    PROVIDE (__CTOR_LIST__ = .);             
110    /* LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2) */
111    *crtbegin.o(.ctors)
112    *(.ctors)
113    *crtend.o(.ctors)
114    LONG(0)
115    PROVIDE (__CTOR_END__ = .);
116       
117    PROVIDE (__DTOR_LIST__ = .);
118    /* LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2) */
119    *crtbegin.o(.dtors)
120    *(.dtors)
121    *crtend.o(.dtors)
122    LONG(0)
123    PROVIDE (__DTOR_END__ = .);
124       
125    /* Exception frame info */
126    *(.eh_frame)
127
128    /* Miscellaneous read-only data */
129    _rodata_start = . ;
130    *(.gnu.linkonce.r*)
131    *(.lit)
132    *(.shdata)
133    *(.rodata)
134    *(.rodata1)
135    *(.descriptors)
136    *(rom_ver)
137    _erodata = .;
138
139    PROVIDE (__EXCEPT_START__ = .);
140    *(.gcc_except_table*)
141    PROVIDE (__EXCEPT_END__ = .);
142    __GOT_START__ = .;
143    s.got = .;
144    *(.got.plt)
145    *(.got)
146    *(.got1)
147    PROVIDE (__GOT2_START__ = .);
148    PROVIDE (_GOT2_START_ = .);
149    *(.got2)
150    PROVIDE (__GOT2_END__ = .);
151    PROVIDE (_GOT2_END_ = .);
152   
153    PROVIDE (__FIXUP_START__ = .);
154    PROVIDE (_FIXUP_START_ = .);
155    *(.fixup)
156    PROVIDE (_FIXUP_END_ = .);
157    PROVIDE (__FIXUP_END__ = .);
158   
159    /* Various possible names for the end of the .text section */
160    etext = ALIGN(0x10);
161    _etext = .;
162    _endtext = .;
163    text.end = .;
164    PROVIDE (etext = .);
165    PROVIDE (__etext = .);
166 
167    } > ram
168
169  .jcr : { KEEP (*(.jcr)) } >ram
170
171    .rel.dyn : {
172      *(.rel.init)
173      *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*)
174      *(.rel.fini)
175      *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*)
176      *(.rel.data.rel.ro* .rel.gnu.linkonce.d.rel.ro.*)
177      *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*)
178      *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*)
179      *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*)
180      *(.rel.ctors)
181      *(.rel.dtors)
182      *(.rel.got)
183      *(.rel.sdata .rel.sdata.* .rel.gnu.linkonce.s.*)
184      *(.rel.sbss .rel.sbss.* .rel.gnu.linkonce.sb.*)
185      *(.rel.sdata2 .rel.sdata2.* .rel.gnu.linkonce.s2.*)
186      *(.rel.sbss2 .rel.sbss2.* .rel.gnu.linkonce.sb2.*)
187      *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*)
188    } >ram
189    .rela.dyn : {
190      *(.rela.init)
191      *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*)
192      *(.rela.fini)
193      *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*)
194      *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*)
195      *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*)
196      *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*)
197      *(.rela.ctors)
198      *(.rela.dtors)
199      *(.rela.got)
200      *(.rela.got1)
201      *(.rela.got2)
202      *(.rela.sdata .rela.sdata.* .rela.gnu.linkonce.s.*)
203      *(.rela.sbss .rela.sbss.* .rela.gnu.linkonce.sb.*)
204      *(.rela.sdata2 .rela.sdata2.* .rela.gnu.linkonce.s2.*)
205      *(.rela.sbss2 .rela.sbss2.* .rela.gnu.linkonce.sb2.*)
206      *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)
207    } >ram
208
209    PROVIDE (__SDATA2_START__ = .);
210  .sdata2         : { *(.sdata2) *(.gnu.linkonce.s2.*)  } >ram
211  .sbss2          : { *(.sbss2) *(.gnu.linkonce.sb2.*)  } >ram
212    PROVIDE (__SBSS2_END__ = .);
213       
214    .sbss2        : { *(.sbss2)         } >ram
215    PROVIDE (__SBSS2_END__ = .);
216       
217    /* R/W Data */
218    .data ( . ) :
219    {
220      . = ALIGN (4);
221
222      data.start = .;
223
224      *(.data)
225      *(.data1)
226      *(.data.* .gnu.linkonce.d.*)
227      PROVIDE (__SDATA_START__ = .);
228      *(.sdata*)
229      *(.gnu.linkonce.s.*)
230      data.end = .;
231    } > ram
232
233    __SBSS_START__ = .;
234    .bss :
235    {
236      bss.start = .;
237      *(.bss .bss* .gnu.linkonce.b*)
238      *(.sbss*) *(COMMON)
239      . = ALIGN(4);
240      bss.end = .;
241    } > ram
242    __SBSS_END__ = .;
243
244    PROVIDE(_bss_start   = ADDR(.bss));
245    PROVIDE(_bss_size    = SIZEOF(.bss));
246    PROVIDE(_data_start  = ADDR(.data));
247    PROVIDE(_data_size   = SIZEOF(.data));
248    PROVIDE(_text_start  = ADDR(.text));
249    PROVIDE(_text_size   = SIZEOF(.text));
250    PROVIDE(_end = data.end);
251
252    .gzipmalloc : {
253        . = ALIGN (16);
254        _startmalloc = .;
255     } >ram
256
257    /*
258     * Interrupt stack setup
259     */
260    IntrStack_start = ALIGN(0x10);
261    . += 0x4000;
262    intrStack = .;
263    PROVIDE(intrStackPtr = intrStack);
264
265
266
267
268    _WorkspaceBase = .;
269    __WorkspaceBase = .;
270    . += WorkSpaceSize;
271
272    _RamDiskBase = .;
273    __RamDiskBase = .;
274    . += RamDiskSize;
275    _RamDiskEnd  = .;
276    __RamDiskEnd = .;
277    PROVIDE( _RamDiskSize = _RamDiskEnd - _RamDiskBase );
278
279    _HeapStart = .;
280    __HeapStart = .;
281    . += HeapSize;
282    _HeapEnd = .;
283    __HeapEnd = .;
284
285    clear_end = .;
286
287    /* Sections for compressed .text and .data         */
288    /* after the .datarom section is an int specifying */
289    /* the length of the following compressed image    */
290    /* Executes once then could get overwritten        */
291    .textrom 0x100000 :
292    {
293        *(.textrom)
294        _endloader = .;
295    } > ram
296
297    .datarom :
298    {
299        _dr_start = .;
300        *(.datarom)
301        _dr_end = .;
302    } > ram
303    dr_len = _dr_end - _dr_start;
304
305    mpc5200_regs :
306    {
307    MBAR = .;
308    mpc5200 = .;
309    _mpc5200 = .;
310    . += (0x6000);
311    } > mpc5200_regs
312
313    .dpram :
314    {
315      dp_ram = .;
316      _dp_ram = .;
317      . += (0x400);
318     } > dpram
319
320
321     /* the reset vector is at 0xfff00000 which is */
322     /* located at offset 0x400000 from the base   */
323     /* of flash                                   */
324    .bootrom 0xFFE00000 :
325    {
326      *(.bootrom)
327      _endboot = .;
328    } > flash
329
330
331    .line 0 : { *(.line) }
332    .debug 0 : { *(.debug) }
333    .debug_sfnames 0 : { *(.debug_sfnames) }
334    .debug_srcinfo 0 : { *(.debug_srcinfo) }
335    .debug_pubnames 0 : { *(.debug_pubnames) }
336    .debug_aranges 0 : { *(.debug_aranges) }
337    .debug_aregion 0 : { *(.debug_aregion) }
338    .debug_macinfo 0 : { *(.debug_macinfo) }
339    .stab 0 : { *(.stab) }
340    .stabstr 0 : { *(.stabstr) }
341}
Note: See TracBrowser for help on using the repository browser.