source: rtems/c/src/lib/libbsp/m68k/ods68302/startup/linkcmds @ 9c1133e

4.104.114.84.95
Last change on this file since 9c1133e was 9c1133e, checked in by Joel Sherrill <joel.sherrill@…>, on 01/20/03 at 19:57:14

mkChangeLogList [-n]

  • Property mode set to 100644
File size: 4.9 KB
Line 
1/*
2 * $Id$
3 *
4 * MC68302 Linker command file
5 *
6 */
7
8/*
9 * Declare some sizes.
10 */
11_RamBase = DEFINED(_RamBase) ? _RamBase : 0x0;
12_RamSize = DEFINED(_RamSize) ? _RamSize : 1M;
13_HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0x10000;
14_StackSize = DEFINED(_StackSize) ? _StackSize : 0x1000;
15
16/*
17 * Declare on-board memory.
18 */
19MEMORY {
20          ram : ORIGIN = 0x00000000, LENGTH = 1M
21}
22SECTIONS
23{
24        ram : {
25                . = .;
26        } >ram
27
28        .vtable :
29        {
30                vtable_start = .;
31                *(.vtable)
32                evtable = .;
33        } >ram
34
35
36        /*
37         * Text, data and bss segments
38         */
39        .text : {
40                *(.text)
41
42                /*
43                 * C++ constructors/destructors
44                 */
45                *(.gnu.linkonce.t.*)
46
47                /*
48                 * Initialization and finalization code.
49                 *
50                 * Various files can provide initialization and finalization
51                 * functions.  crtbegin.o and crtend.o are two instances. The
52                 * body of these functions are in .init and .fini sections. We
53                 * accumulate the bodies here, and prepend function prologues
54                 * from crti.o and function epilogues from crtn.o. crti.o must
55                 * be linked first; crtn.o must be linked last.  Because these
56                 * are wildcards, it doesn't matter if the user does not
57                 * actually link against crti.o and crtn.o; the linker won't
58                 * look for a file to match a wildcard.  The wildcard also
59                 * means that it doesn't matter which directory crti.o and
60                 * crtn.o are in.
61                 */
62                PROVIDE (_init = .);
63                *crti.o(.init)
64                *(.init)
65                *crtn.o(.init)
66                PROVIDE (_fini = .);
67                *crti.o(.fini)
68                *(.fini)
69                *crtn.o(.fini)
70
71                /*
72                 * Special FreeBSD sysctl sections.
73                 */
74                . = ALIGN (16);
75                __start_set_sysctl_set = .;
76                *(set_sysctl_*);
77                __stop_set_sysctl_set = ABSOLUTE(.);
78                *(set_domain_*);
79                *(set_pseudo_*);
80
81                /*
82                 * C++ constructors/destructors
83                 *
84                 * gcc uses crtbegin.o to find the start of the constructors
85                 * and destructors so we make sure it is first.  Because this
86                 * is a wildcard, it doesn't matter if the user does not
87                 * actually link against crtbegin.o; the linker won't look for
88                 * a file to match a wildcard.  The wildcard also means that
89                 * it doesn't matter which directory crtbegin.o is in. The
90                 * constructor and destructor list are terminated in
91                 * crtend.o.  The same comments apply to it.
92                 */
93                . = ALIGN (16);
94                *crtbegin.o(.ctors)
95                *(.ctors)
96                *crtend.o(.ctors)
97                *crtbegin.o(.dtors)
98                *(.dtors)
99                *crtend.o(.dtors)
100
101                /*
102                 * Exception frame info
103                 */
104                . = ALIGN (16);
105                *(.eh_frame)
106
107                /*
108                 * Read-only data
109                 */
110                . = ALIGN (16);
111                _rodata_start = .;
112                *(.rodata*)
113                *(.gnu.linkonce.r*)
114
115                 . = ALIGN (16);
116                PROVIDE (_etext = .);
117        } >ram
118        .data : {
119                PROVIDE (_copy_start = .);
120                *(.data)
121                *(.gnu.linkonce.d*)
122                *(.gcc_except_table)
123                *(.jcr)
124                . = ALIGN (16);
125                PROVIDE (_edata = .);
126                PROVIDE (_copy_end = .);
127        } >ram
128        .bss : {
129                _clear_start = .;
130                *(.bss)
131                *(COMMON)
132                . = ALIGN (16);
133                PROVIDE (end = .);
134
135                . += _StackSize;
136                . = ALIGN (16);
137                _stack_init = .;
138                _clear_end = .;
139
140                _WorkspaceBase = .;
141        } >ram
142
143  /* Stabs debugging sections.  */
144  .stab 0 : { *(.stab) }
145  .stabstr 0 : { *(.stabstr) }
146  .stab.excl 0 : { *(.stab.excl) }
147  .stab.exclstr 0 : { *(.stab.exclstr) }
148  .stab.index 0 : { *(.stab.index) }
149  .stab.indexstr 0 : { *(.stab.indexstr) }
150  .comment 0 : { *(.comment) }
151
152  /* DWARF debug sections.
153     Symbols in the DWARF debugging sections are relative to the beginning
154     of the section so we begin them at 0.  */
155  /* DWARF 1 */
156  .debug          0 : { *(.debug) }
157  .line           0 : { *(.line) }
158 
159  /* GNU DWARF 1 extensions */
160  .debug_srcinfo  0 : { *(.debug_srcinfo) }
161  .debug_sfnames  0 : { *(.debug_sfnames) }
162 
163  /* DWARF 1.1 and DWARF 2 */
164  .debug_aranges  0 : { *(.debug_aranges) }
165  .debug_pubnames 0 : { *(.debug_pubnames) }
166 
167  /* DWARF 2 */
168  .debug_info     0 : { *(.debug_info) }
169  .debug_abbrev   0 : { *(.debug_abbrev) }
170  .debug_line     0 : { *(.debug_line) }
171  .debug_frame    0 : { *(.debug_frame) }
172  .debug_str      0 : { *(.debug_str) }
173  .debug_loc      0 : { *(.debug_loc) }
174  .debug_macinfo  0 : { *(.debug_macinfo) }
175 
176  /* SGI/MIPS DWARF 2 extensions */
177  .debug_weaknames 0 : { *(.debug_weaknames) }
178  .debug_funcnames 0 : { *(.debug_funcnames) }
179  .debug_typenames 0 : { *(.debug_typenames) }
180  .debug_varnames  0 : { *(.debug_varnames) }
181  /* These must appear regardless of  .  */
182}
183
184RAM_BASE = DEFINED(RAM_BASE) ? RAM_BASE : 0x00000000;
185RAM_SIZE = DEFINED(RAM_SIZE) ? RAM_SIZE : 0x00100000;
186ROM_BASE = DEFINED(ROM_BASE) ? ROM_BASE : 0x00C00000;
187ROM_SIZE = DEFINED(ROM_SIZE) ? ROM_SIZE : 0x00100000;
188MC68302_BASE = DEFINED(MC68302_BASE) ? MC68302_BASE : 0x00700000;
189m302 = MC68302_BASE;
190_VBR = ADDR(.vtable);           /* location of the VBR table (in RAM) */
191
Note: See TracBrowser for help on using the repository browser.