source: rtems/c/src/lib/libbsp/m68k/mvme147s/startup/linkcmds @ 9c1133e

4.104.114.84.9
Last change on this file since 9c1133e was 9c1133e, checked in by Joel Sherrill <joel.sherrill@…>, on Jan 20, 2003 at 7:57:14 PM

mkChangeLogList [-n]

  • Property mode set to 100644
File size: 4.8 KB
Line 
1/*
2 *  This file contains directives for the GNU linker which are specific
3 *  to the Motorola MVME147 boards.
4 *
5 *  COPYRIGHT (c) 1989-1999.
6 *  On-Line Applications Research Corporation (OAR).
7 *
8 *  The license and distribution terms for this file may be
9 *  found in the file LICENSE in this distribution or at
10 *  http://www.OARcorp.com/rtems/license.html.
11 *
12 *  MVME147 port for TNI - Telecom Bretagne
13 *  by Dominique LE CAMPION (Dominique.LECAMPION@enst-bretagne.fr)
14 *  May 1996
15 *
16 *  $Id$
17 */
18
19/*
20 * Declare some sizes.
21 */
22_RamBase = DEFINED(_RamBase) ? _RamBase : 0x0;
23_RamSize = DEFINED(_RamSize) ? _RamSize : 4M;
24_HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0x10000;
25_StackSize = DEFINED(_StackSize) ? _StackSize : 0x1000;
26
27MEMORY
28{
29        ram : org = 0x0, l = 0x400000
30}
31
32SECTIONS
33{
34        ram : {
35                . = 0x7000;
36        } >ram
37
38        /*
39         * Text, data and bss segments
40         */
41        .text : {
42                *(.text)
43
44                /*
45                 * C++ constructors/destructors
46                 */
47                *(.gnu.linkonce.t.*)
48
49                /*
50                 * Initialization and finalization code.
51                 *
52                 * Various files can provide initialization and finalization
53                 * functions.  crtbegin.o and crtend.o are two instances. The
54                 * body of these functions are in .init and .fini sections. We
55                 * accumulate the bodies here, and prepend function prologues
56                 * from crti.o and function epilogues from crtn.o. crti.o must
57                 * be linked first; crtn.o must be linked last.  Because these
58                 * are wildcards, it doesn't matter if the user does not
59                 * actually link against crti.o and crtn.o; the linker won't
60                 * look for a file to match a wildcard.  The wildcard also
61                 * means that it doesn't matter which directory crti.o and
62                 * crtn.o are in.
63                 */
64                PROVIDE (_init = .);
65                *crti.o(.init)
66                *(.init)
67                *crtn.o(.init)
68                PROVIDE (_fini = .);
69                *crti.o(.fini)
70                *(.fini)
71                *crtn.o(.fini)
72
73                /*
74                 * Special FreeBSD sysctl sections.
75                 */
76                . = ALIGN (16);
77                __start_set_sysctl_set = .;
78                *(set_sysctl_*);
79                __stop_set_sysctl_set = ABSOLUTE(.);
80                *(set_domain_*);
81                *(set_pseudo_*);
82
83                /*
84                 * C++ constructors/destructors
85                 *
86                 * gcc uses crtbegin.o to find the start of the constructors
87                 * and destructors so we make sure it is first.  Because this
88                 * is a wildcard, it doesn't matter if the user does not
89                 * actually link against crtbegin.o; the linker won't look for
90                 * a file to match a wildcard.  The wildcard also means that
91                 * it doesn't matter which directory crtbegin.o is in. The
92                 * constructor and destructor list are terminated in
93                 * crtend.o.  The same comments apply to it.
94                 */
95                . = ALIGN (16);
96                *crtbegin.o(.ctors)
97                *(.ctors)
98                *crtend.o(.ctors)
99                *crtbegin.o(.dtors)
100                *(.dtors)
101                *crtend.o(.dtors)
102
103                /*
104                 * Exception frame info
105                 */
106                . = ALIGN (16);
107                *(.eh_frame)
108
109                /*
110                 * Read-only data
111                 */
112                . = ALIGN (16);
113                _rodata_start = .;
114                *(.rodata*)
115                *(.gnu.linkonce.r*)
116
117                 . = ALIGN (16);
118                PROVIDE (_etext = .);
119        } >ram
120        .data : {
121                PROVIDE (_copy_start = .);
122                *(.data)
123                *(.gnu.linkonce.d*)
124                *(.gcc_except_table)
125                *(.jcr)
126                . = ALIGN (16);
127                PROVIDE (_edata = .);
128                PROVIDE (_copy_end = .);
129        } >ram
130        .bss : {
131                _clear_start = .;
132                *(.bss)
133                *(COMMON)
134                . = ALIGN (16);
135                PROVIDE (end = .);
136
137                . += _StackSize;
138                . = ALIGN (16);
139                _stack_init = .;
140                _clear_end = .;
141
142                _WorkspaceBase = .;
143        } >ram
144
145  /* Stabs debugging sections.  */
146  .stab 0 : { *(.stab) }
147  .stabstr 0 : { *(.stabstr) }
148  .stab.excl 0 : { *(.stab.excl) }
149  .stab.exclstr 0 : { *(.stab.exclstr) }
150  .stab.index 0 : { *(.stab.index) }
151  .stab.indexstr 0 : { *(.stab.indexstr) }
152  .comment 0 : { *(.comment) }
153
154  /* DWARF debug sections.
155     Symbols in the DWARF debugging sections are relative to the beginning
156     of the section so we begin them at 0.  */
157  /* DWARF 1 */
158  .debug          0 : { *(.debug) }
159  .line           0 : { *(.line) }
160 
161  /* GNU DWARF 1 extensions */
162  .debug_srcinfo  0 : { *(.debug_srcinfo) }
163  .debug_sfnames  0 : { *(.debug_sfnames) }
164 
165  /* DWARF 1.1 and DWARF 2 */
166  .debug_aranges  0 : { *(.debug_aranges) }
167  .debug_pubnames 0 : { *(.debug_pubnames) }
168 
169  /* DWARF 2 */
170  .debug_info     0 : { *(.debug_info) }
171  .debug_abbrev   0 : { *(.debug_abbrev) }
172  .debug_line     0 : { *(.debug_line) }
173  .debug_frame    0 : { *(.debug_frame) }
174  .debug_str      0 : { *(.debug_str) }
175  .debug_loc      0 : { *(.debug_loc) }
176  .debug_macinfo  0 : { *(.debug_macinfo) }
177 
178  /* SGI/MIPS DWARF 2 extensions */
179  .debug_weaknames 0 : { *(.debug_weaknames) }
180  .debug_funcnames 0 : { *(.debug_funcnames) }
181  .debug_typenames 0 : { *(.debug_typenames) }
182  .debug_varnames  0 : { *(.debug_varnames) }
183  /* These must appear regardless of  .  */
184}
Note: See TracBrowser for help on using the repository browser.