source: rtems/c/src/lib/libbsp/m68k/mvme147/startup/linkcmds @ 9f30a08b

4.104.114.84.95
Last change on this file since 9f30a08b was 9f30a08b, checked in by Joel Sherrill <joel.sherrill@…>, on Sep 29, 2000 at 2:25:46 PM

2000-09-29 Charles-Antoine Gauthier <charles.gauthier@…>

  • startup/linkcmds: Added lines so DWARF debug information would be available. Otherwise gdb complains that the offsets for the debug info are incorrect and doesn't load the files.
  • Property mode set to 100644
File size: 4.6 KB
Line 
1/*
2 *  This file contains directives for the GNU linker which are specific
3 *  to the Motorola MVME147 boards.
4 *
5 *  COPYRIGHT (c) 1989-1999.
6 *  On-Line Applications Research Corporation (OAR).
7 *
8 *  The license and distribution terms for this file may be
9 *  found in the file LICENSE in this distribution or at
10 *  http://www.OARcorp.com/rtems/license.html.
11 *
12 *  MVME147 port for TNI - Telecom Bretagne
13 *  by Dominique LE CAMPION (Dominique.LECAMPION@enst-bretagne.fr)
14 *  May 1996
15 *
16 *  $Id$
17 */
18
19/*
20 * Declare some sizes.
21 */
22_RamBase = DEFINED(_RamBase) ? _RamBase : 0x0;
23_RamSize = DEFINED(_RamSize) ? _RamSize : 4M;
24_HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0x10000;
25_StackSize = DEFINED(_StackSize) ? _StackSize : 0x1000;
26
27MEMORY
28{
29        ram : org = 0x0, l = 0x400000
30}
31
32SECTIONS
33{
34        ram : {
35                . = 0x5000;
36        } >ram
37
38        /*
39         * Text, data and bss segments
40         */
41        .text : {
42                *(.text)
43
44                /*
45                 * C++ constructors/destructors
46                 */
47                *(.gnu.linkonce.t.*)
48
49                /*
50                 * Initialization and finalization code.
51                 *
52                 * Various files can provide initialization and finalization
53                 * functions.  crtbegin.o and crtend.o are two instances. The
54                 * body of these functions are in .init and .fini sections. We
55                 * accumulate the bodies here, and prepend function prologues
56                 * from crti.o and function epilogues from crtn.o. crti.o must
57                 * be linked first; crtn.o must be linked last.  Because these
58                 * are wildcards, it doesn't matter if the user does not
59                 * actually link against crti.o and crtn.o; the linker won't
60                 * look for a file to match a wildcard.  The wildcard also
61                 * means that it doesn't matter which directory crti.o and
62                 * crtn.o are in.
63                 */
64                PROVIDE (_init = .);
65                *crti.o(.init)
66                *(.init)
67                *crtn.o(.init)
68                PROVIDE (_fini = .);
69                *crti.o(.fini)
70                *(.fini)
71                *crtn.o(.fini)
72
73                /*
74                 * C++ constructors/destructors
75                 *
76                 * gcc uses crtbegin.o to find the start of the constructors
77                 * and destructors so we make sure it is first.  Because this
78                 * is a wildcard, it doesn't matter if the user does not
79                 * actually link against crtbegin.o; the linker won't look for
80                 * a file to match a wildcard.  The wildcard also means that
81                 * it doesn't matter which directory crtbegin.o is in. The
82                 * constructor and destructor list are terminated in
83                 * crtend.o.  The same comments apply to it.
84                 */
85                . = ALIGN (16);
86                *crtbegin.o(.ctors)
87                *(.ctors)
88                *crtend.o(.ctors)
89                *crtbegin.o(.dtors)
90                *(.dtors)
91                *crtend.o(.dtors)
92
93                /*
94                 * Exception frame info
95                 */
96                . = ALIGN (16);
97                *(.eh_frame)
98
99                /*
100                 * Read-only data
101                 */
102                . = ALIGN (16);
103                _rodata_start = . ;
104                *(.rodata)
105                *(.gnu.linkonce.r*)
106
107                 . = ALIGN (16);
108                PROVIDE (_etext = .);
109        } >ram
110        .data : {
111                PROVIDE (_copy_start = .);
112                *(.data)
113                *(.gnu.linkonce.d*)
114                *(.gcc_except_table)
115                . = ALIGN (16);
116                PROVIDE (_edata = .);
117                PROVIDE (_copy_end = .);
118        } >ram
119        .bss : {
120                _clear_start = .;
121                *(.bss)
122                *(COMMON)
123                . = ALIGN (16);
124                PROVIDE (end = .);
125
126                . += _StackSize;
127                . = ALIGN (16);
128                _stack_init = .;
129                _clear_end = .;
130
131                _WorkspaceBase = .;
132        } >ram
133
134  /* Stabs debugging sections.  */
135  .stab 0 : { *(.stab) }
136  .stabstr 0 : { *(.stabstr) }
137  .stab.excl 0 : { *(.stab.excl) }
138  .stab.exclstr 0 : { *(.stab.exclstr) }
139  .stab.index 0 : { *(.stab.index) }
140  .stab.indexstr 0 : { *(.stab.indexstr) }
141  .comment 0 : { *(.comment) }
142
143  /* DWARF debug sections.
144     Symbols in the DWARF debugging sections are relative to the beginning
145     of the section so we begin them at 0.  */
146  /* DWARF 1 */
147  .debug          0 : { *(.debug) }
148  .line           0 : { *(.line) }
149 
150  /* GNU DWARF 1 extensions */
151  .debug_srcinfo  0 : { *(.debug_srcinfo) }
152  .debug_sfnames  0 : { *(.debug_sfnames) }
153 
154  /* DWARF 1.1 and DWARF 2 */
155  .debug_aranges  0 : { *(.debug_aranges) }
156  .debug_pubnames 0 : { *(.debug_pubnames) }
157 
158  /* DWARF 2 */
159  .debug_info     0 : { *(.debug_info) }
160  .debug_abbrev   0 : { *(.debug_abbrev) }
161  .debug_line     0 : { *(.debug_line) }
162  .debug_frame    0 : { *(.debug_frame) }
163  .debug_str      0 : { *(.debug_str) }
164  .debug_loc      0 : { *(.debug_loc) }
165  .debug_macinfo  0 : { *(.debug_macinfo) }
166 
167  /* SGI/MIPS DWARF 2 extensions */
168  .debug_weaknames 0 : { *(.debug_weaknames) }
169  .debug_funcnames 0 : { *(.debug_funcnames) }
170  .debug_typenames 0 : { *(.debug_typenames) }
171  .debug_varnames  0 : { *(.debug_varnames) }
172  /* These must appear regardless of  .  */
173}
Note: See TracBrowser for help on using the repository browser.