source: rtems/c/src/lib/libbsp/m68k/gen68340/startup/linkcmds @ c1d2cc9

/*
 * This file contains GNU linker directives for a generic MC68340/349 board.
 * Variations in hardware type and dynamic memory size can be made
 * by overriding some values with linker command-line arguments.
 *
 * ATTENTION: RAM and ROM placement must accord those in start340.S!!
 *            (next time I'll use some shared variables :) )
 *
 * Geoffroy Montel
 * France Telecom - CNET/DSM/TAM/CAT
 * 4, rue du Clos Courtel
 * 35512 CESSON-SEVIGNE
 * FRANCE
 * 
 * e-mail: g_montel@yahoo.com
 * 
 *  $Id$
 */

/*
 * a.out format doesn't handle prom images very well
 */
OUTPUT_FORMAT(coff-m68k)

/*
 * Declare some sizes.
 */
RamSize = DEFINED(RamSize) ? RamSize : 4M;
HeapSize = DEFINED(HeapSize) ? HeapSize : 0x10000;
StackSize = DEFINED(StackSize) ? StackSize : 0x1000;

/*
 * Declare on-board memory.
 * It would be nice if the ram length could be given as
 * LENGTH=RamSize, but gld doesn't allow non-constant
 * values in the LENGTH expression.  
 */
MEMORY {
          ram : ORIGIN = 0x10000000, LENGTH = 4M
          rom : ORIGIN = 0x01000000, LENGTH = 4M
/*        dpram : ORIGIN = 0xFE000000, LENGTH = 8k */
}

/*
 * Declare low-order three octets of Ethernet address.
 */
ETHERNET_ADDRESS = DEFINED(ETHERNET_ADDRESS) ? ETHERNET_ADDRESS : 0xDEAD12;

/*
 * Load objects
 */
SECTIONS {
        /*
         * Hardware variations
         */
        _RamSize = RamSize;
        __RamSize = RamSize;

        /*
         * Boot PROM
         */
        rom : {
                _RomBase = .;
                __RomBase = .;
        } >rom

        /*
         * Dynamic RAM
         */
        ram : {
                _RamBase = .;
                __RamBase = .;
        } >ram

        /*
         * Text, data and bss segments
         */
        .text : {
                *(.text)

                /*
                 * C++ constructors/destructors
                 */
                *(.gnu.linkonce.t.*)

                /*
                 * Initialization and finalization code.
                 *
                 * Various files can provide initialization and finalization
                 * functions.  crtbegin.o and crtend.o are two instances. The
                 * body of these functions are in .init and .fini sections. We
                 * accumulate the bodies here, and prepend function prologues
                 * from crti.o and function epilogues from crtn.o. crti.o must
                 * be linked first; crtn.o must be linked last.  Because these
                 * are wildcards, it doesn't matter if the user does not
                 * actually link against crti.o and crtn.o; the linker won't
                 * look for a file to match a wildcard.  The wildcard also
                 * means that it doesn't matter which directory crti.o and
                 * crtn.o are in. 
                 */
                PROVIDE (_init = .);
                *crti.o(.init)
                *(.init)
                *crtn.o(.init)
                PROVIDE (_fini = .);
                *crti.o(.fini)
                *(.fini)
                *crtn.o(.fini)

                /*
                 * C++ constructors/destructors
                 *
                 * gcc uses crtbegin.o to find the start of the constructors
                 * and destructors so we make sure it is first.  Because this
                 * is a wildcard, it doesn't matter if the user does not
                 * actually link against crtbegin.o; the linker won't look for
                 * a file to match a wildcard.  The wildcard also means that
                 * it doesn't matter which directory crtbegin.o is in. The
                 * constructor and destructor list are terminated in
                 * crtend.o.  The same comments apply to it.
                 */
                . = ALIGN (16);
                *crtbegin.o(.ctors)
                *(.ctors)
                *crtend.o(.ctors)
                *crtbegin.o(.dtors)
                *(.dtors)
                *crtend.o(.dtors)

                /*
                 * Exception frame info
                 */
                . = ALIGN (16);
                *(.eh_frame)

                /*
                 * Read-only data
                 */
                . = ALIGN (16);
                _rodata_start = . ;
                *(.rodata)
                *(.gnu.linkonce.r*)

                 . = ALIGN (16);
                PROVIDE (_etext = .);
        } >ram
        .data : {
                PROVIDE (_copy_start = .);
                *(.data)
                *(.gnu.linkonce.d*)
                *(.gcc_except_table)
                . = ALIGN (16);
                PROVIDE (_edata = .);
                PROVIDE (_copy_end = .);
        } >ram
        .bss : {
                M68Kvec = .;
                _M68Kvec = .;
                . += (256 * 4);
                PROVIDE (_bss_start = .);
                PROVIDE (_clear_start = .);
                *(.bss)
                *(COMMON)
                . = ALIGN (16);
                PROVIDE (end = .);

                . += StackSize;
                PROVIDE (_stack_init = .);

                . = ALIGN (16);
                PROVIDE (_HeapStart = .);
                . += HeapSize;
                PROVIDE (_HeapEnd = .);

                clear_end = .;

                PROVIDE (_WorkspaceBase = .);
        } >ram

       /*
        * On-chip memory/peripherals
        *
        */
        dpram : {
                m340 = .;
                _m340 = .;
                . += (8 * 1024);
        } >ram

}