source: rtems/c/src/lib/libbsp/m68k/gen68302/startup/linkcmds @ 9c1133e

4.104.114.84.9
Last change on this file since 9c1133e was 9c1133e, checked in by Joel Sherrill <joel.sherrill@…>, on Jan 20, 2003 at 7:57:14 PM

mkChangeLogList [-n]

  • Property mode set to 100644
File size: 4.8 KB
Line 
1/*
2 *  This file contains directives for the GNU linker which are specific
3 *  to the Generic MC68302 board.
4 *
5 *  COPYRIGHT (c) 1989-1999.
6 *  On-Line Applications Research Corporation (OAR).
7 *
8 *  The license and distribution terms for this file may be
9 *  found in the file LICENSE in this distribution or at
10 *  http://www.OARcorp.com/rtems/license.html.
11 *
12 *  $Id$
13 */
14
15MEMORY
16{
17        ram : org = 0x0000, l = 16M
18}
19
20m302 = 0xf7f000;
21_VBR = 0x000000;                /* location of the VBR table (in RAM) */
22
23/*
24 * Declare some sizes.
25 */
26_RamBase = DEFINED(_RamBase) ? _RamBase : 0x0;
27_RamSize = DEFINED(_RamSize) ? _RamSize : 16M;
28_HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0x10000;
29_StackSize = DEFINED(_StackSize) ? _StackSize : 0x1000;
30
31SECTIONS
32{
33        ram : {
34                . = 0xc00000;
35        } >ram
36
37        /*
38         * Text, data and bss segments
39         */
40        .text : {
41                *(.text)
42
43                /*
44                 * C++ constructors/destructors
45                 */
46                *(.gnu.linkonce.t.*)
47
48                /*
49                 * Initialization and finalization code.
50                 *
51                 * Various files can provide initialization and finalization
52                 * functions.  crtbegin.o and crtend.o are two instances. The
53                 * body of these functions are in .init and .fini sections. We
54                 * accumulate the bodies here, and prepend function prologues
55                 * from crti.o and function epilogues from crtn.o. crti.o must
56                 * be linked first; crtn.o must be linked last.  Because these
57                 * are wildcards, it doesn't matter if the user does not
58                 * actually link against crti.o and crtn.o; the linker won't
59                 * look for a file to match a wildcard.  The wildcard also
60                 * means that it doesn't matter which directory crti.o and
61                 * crtn.o are in.
62                 */
63                PROVIDE (_init = .);
64                *crti.o(.init)
65                *(.init)
66                *crtn.o(.init)
67                PROVIDE (_fini = .);
68                *crti.o(.fini)
69                *(.fini)
70                *crtn.o(.fini)
71
72                /*
73                 * Special FreeBSD sysctl sections.
74                 */
75                . = ALIGN (16);
76                __start_set_sysctl_set = .;
77                *(set_sysctl_*);
78                __stop_set_sysctl_set = ABSOLUTE(.);
79                *(set_domain_*);
80                *(set_pseudo_*);
81
82                /*
83                 * C++ constructors/destructors
84                 *
85                 * gcc uses crtbegin.o to find the start of the constructors
86                 * and destructors so we make sure it is first.  Because this
87                 * is a wildcard, it doesn't matter if the user does not
88                 * actually link against crtbegin.o; the linker won't look for
89                 * a file to match a wildcard.  The wildcard also means that
90                 * it doesn't matter which directory crtbegin.o is in. The
91                 * constructor and destructor list are terminated in
92                 * crtend.o.  The same comments apply to it.
93                 */
94                . = ALIGN (16);
95                *crtbegin.o(.ctors)
96                *(.ctors)
97                *crtend.o(.ctors)
98                *crtbegin.o(.dtors)
99                *(.dtors)
100                *crtend.o(.dtors)
101
102                /*
103                 * Exception frame info
104                 */
105                . = ALIGN (16);
106                *(.eh_frame)
107
108                /*
109                 * Read-only data
110                 */
111                . = ALIGN (16);
112                _rodata_start = . ;
113                *(.rodata*)
114                *(.gnu.linkonce.r*)
115
116                 . = ALIGN (16);
117                PROVIDE (_etext = .);
118        } >ram
119        .data : {
120                PROVIDE (_copy_start = .);
121                *(.data)
122                *(.gnu.linkonce.d*)
123                *(.gcc_except_table)
124                *(.jcr)
125                . = ALIGN (16);
126                PROVIDE (_edata = .);
127                PROVIDE (_copy_end = .);
128        } >ram
129        .bss : {
130                _clear_start = .;
131                *(.bss)
132                *(COMMON)
133                . = ALIGN (16);
134                PROVIDE (end = .);
135
136                . += _StackSize;
137                . = ALIGN (16);
138                _stack_init = .;
139                _clear_end = .;
140
141                _WorkspaceBase = .;
142        } >ram
143
144  /* Stabs debugging sections.  */
145  .stab 0 : { *(.stab) }
146  .stabstr 0 : { *(.stabstr) }
147  .stab.excl 0 : { *(.stab.excl) }
148  .stab.exclstr 0 : { *(.stab.exclstr) }
149  .stab.index 0 : { *(.stab.index) }
150  .stab.indexstr 0 : { *(.stab.indexstr) }
151  .comment 0 : { *(.comment) }
152
153  /* DWARF debug sections.
154     Symbols in the DWARF debugging sections are relative to the beginning
155     of the section so we begin them at 0.  */
156  /* DWARF 1 */
157  .debug          0 : { *(.debug) }
158  .line           0 : { *(.line) }
159 
160  /* GNU DWARF 1 extensions */
161  .debug_srcinfo  0 : { *(.debug_srcinfo) }
162  .debug_sfnames  0 : { *(.debug_sfnames) }
163 
164  /* DWARF 1.1 and DWARF 2 */
165  .debug_aranges  0 : { *(.debug_aranges) }
166  .debug_pubnames 0 : { *(.debug_pubnames) }
167 
168  /* DWARF 2 */
169  .debug_info     0 : { *(.debug_info) }
170  .debug_abbrev   0 : { *(.debug_abbrev) }
171  .debug_line     0 : { *(.debug_line) }
172  .debug_frame    0 : { *(.debug_frame) }
173  .debug_str      0 : { *(.debug_str) }
174  .debug_loc      0 : { *(.debug_loc) }
175  .debug_macinfo  0 : { *(.debug_macinfo) }
176 
177  /* SGI/MIPS DWARF 2 extensions */
178  .debug_weaknames 0 : { *(.debug_weaknames) }
179  .debug_funcnames 0 : { *(.debug_funcnames) }
180  .debug_typenames 0 : { *(.debug_typenames) }
181  .debug_varnames  0 : { *(.debug_varnames) }
182  /* These must appear regardless of  .  */
183}
Note: See TracBrowser for help on using the repository browser.