source: rtems/c/src/lib/libbsp/m68k/gen68302/startup/linkcmds @ 35ff211

Last change on this file since 35ff211 was 35ff211, checked in by Joel Sherrill <joel.sherrill@…>, on 04/05/00 at 19:09:06

Now all m68k BSPs specify _RamBase. This is necessary for the shared
m68kbsppretaskinghook.c to work.
  • Property mode set to 100644
File size: 3.3 KB
Line 
1/*
2 *  This file contains directives for the GNU linker which are specific
3 *  to the Generic MC68302 board.
4 *
5 *  COPYRIGHT (c) 1989-1999.
6 *  On-Line Applications Research Corporation (OAR).
7 *
8 *  The license and distribution terms for this file may be
9 *  found in the file LICENSE in this distribution or at
10 *  http://www.OARcorp.com/rtems/license.html.
11 *
12 *  $Id$
13 */
14
15MEMORY
16{
17        ram : org = 0x0000, l = 16M
18}
19
20m302 = 0xf7f000;
21_VBR = 0x000000;                /* location of the VBR table (in RAM) */
22
23/*
24 * Declare some sizes.
25 */
26_RamBase = DEFINED(_RamBase) ? _RamBase : 0x0;
27_RamSize = DEFINED(_RamSize) ? _RamSize : 16M;
28_HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0x10000;
29_StackSize = DEFINED(_StackSize) ? _StackSize : 0x1000;
30
31SECTIONS
32{
33        ram : {
34                . = 0xc00000;
35        } >ram
36
37        /*
38         * Text, data and bss segments
39         */
40        .text : {
41                *(.text)
42
43                /*
44                 * C++ constructors/destructors
45                 */
46                *(.gnu.linkonce.t.*)
47
48                /*
49                 * Initialization and finalization code.
50                 *
51                 * Various files can provide initialization and finalization
52                 * functions.  crtbegin.o and crtend.o are two instances. The
53                 * body of these functions are in .init and .fini sections. We
54                 * accumulate the bodies here, and prepend function prologues
55                 * from crti.o and function epilogues from crtn.o. crti.o must
56                 * be linked first; crtn.o must be linked last.  Because these
57                 * are wildcards, it doesn't matter if the user does not
58                 * actually link against crti.o and crtn.o; the linker won't
59                 * look for a file to match a wildcard.  The wildcard also
60                 * means that it doesn't matter which directory crti.o and
61                 * crtn.o are in.
62                 */
63                PROVIDE (_init = .);
64                *crti.o(.init)
65                *(.init)
66                *crtn.o(.init)
67                PROVIDE (_fini = .);
68                *crti.o(.fini)
69                *(.fini)
70                *crtn.o(.fini)
71
72                /*
73                 * C++ constructors/destructors
74                 *
75                 * gcc uses crtbegin.o to find the start of the constructors
76                 * and destructors so we make sure it is first.  Because this
77                 * is a wildcard, it doesn't matter if the user does not
78                 * actually link against crtbegin.o; the linker won't look for
79                 * a file to match a wildcard.  The wildcard also means that
80                 * it doesn't matter which directory crtbegin.o is in. The
81                 * constructor and destructor list are terminated in
82                 * crtend.o.  The same comments apply to it.
83                 */
84                . = ALIGN (16);
85                *crtbegin.o(.ctors)
86                *(.ctors)
87                *crtend.o(.ctors)
88                *crtbegin.o(.dtors)
89                *(.dtors)
90                *crtend.o(.dtors)
91
92                /*
93                 * Exception frame info
94                 */
95                . = ALIGN (16);
96                *(.eh_frame)
97
98                /*
99                 * Read-only data
100                 */
101                . = ALIGN (16);
102                _rodata_start = . ;
103                *(.rodata)
104                *(.gnu.linkonce.r*)
105
106                 . = ALIGN (16);
107                PROVIDE (_etext = .);
108        } >ram
109        .data : {
110                PROVIDE (_copy_start = .);
111                *(.data)
112                *(.gnu.linkonce.d*)
113                *(.gcc_except_table)
114                . = ALIGN (16);
115                PROVIDE (_edata = .);
116                PROVIDE (_copy_end = .);
117        } >ram
118        .bss : {
119                _clear_start = .;
120                *(.bss)
121                *(COMMON)
122                . = ALIGN (16);
123                PROVIDE (end = .);
124
125                . += _StackSize;
126                . = ALIGN (16);
127                _stack_init = .;
128                _clear_end = .;
129
130                _WorkspaceBase = .;
131        } >ram
132}
Note: See TracBrowser for help on using the repository browser.