1 | /* |
---|
2 | * This file contains directives for the GNU linker which are specific |
---|
3 | * to the Generic MC68302 board. |
---|
4 | * |
---|
5 | * COPYRIGHT (c) 1989-2007. |
---|
6 | * On-Line Applications Research Corporation (OAR). |
---|
7 | * |
---|
8 | * The license and distribution terms for this file may be |
---|
9 | * found in the file LICENSE in this distribution or at |
---|
10 | * http://www.rtems.com/license/LICENSE. |
---|
11 | * |
---|
12 | * $Id$ |
---|
13 | */ |
---|
14 | |
---|
15 | MEMORY |
---|
16 | { |
---|
17 | ram : org = 0x0000, l = 16M |
---|
18 | } |
---|
19 | |
---|
20 | m302 = 0xf7f000; |
---|
21 | _VBR = 0x000000; /* location of the VBR table (in RAM) */ |
---|
22 | |
---|
23 | /* |
---|
24 | * Declare some sizes. |
---|
25 | */ |
---|
26 | _RamBase = DEFINED(_RamBase) ? _RamBase : 0x0; |
---|
27 | _RamSize = DEFINED(_RamSize) ? _RamSize : 16M; |
---|
28 | _HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0x10000; |
---|
29 | _StackSize = DEFINED(_StackSize) ? _StackSize : 0x1000; |
---|
30 | |
---|
31 | SECTIONS |
---|
32 | { |
---|
33 | ram : { |
---|
34 | . = 0xc00000; |
---|
35 | } >ram |
---|
36 | |
---|
37 | /* |
---|
38 | * Text, data and bss segments |
---|
39 | */ |
---|
40 | .text : { |
---|
41 | *(.text*) |
---|
42 | |
---|
43 | /* |
---|
44 | * C++ constructors/destructors |
---|
45 | */ |
---|
46 | *(.gnu.linkonce.t.*) |
---|
47 | |
---|
48 | /* |
---|
49 | * Initialization and finalization code. |
---|
50 | * |
---|
51 | * Various files can provide initialization and finalization |
---|
52 | * functions. crtbegin.o and crtend.o are two instances. The |
---|
53 | * body of these functions are in .init and .fini sections. We |
---|
54 | * accumulate the bodies here, and prepend function prologues |
---|
55 | * from crti.o and function epilogues from crtn.o. crti.o must |
---|
56 | * be linked first; crtn.o must be linked last. Because these |
---|
57 | * are wildcards, it doesn't matter if the user does not |
---|
58 | * actually link against crti.o and crtn.o; the linker won't |
---|
59 | * look for a file to match a wildcard. The wildcard also |
---|
60 | * means that it doesn't matter which directory crti.o and |
---|
61 | * crtn.o are in. |
---|
62 | */ |
---|
63 | PROVIDE (_init = .); |
---|
64 | *crti.o(.init) |
---|
65 | *(.init) |
---|
66 | *crtn.o(.init) |
---|
67 | PROVIDE (_fini = .); |
---|
68 | *crti.o(.fini) |
---|
69 | *(.fini) |
---|
70 | *crtn.o(.fini) |
---|
71 | |
---|
72 | /* |
---|
73 | * Special FreeBSD sysctl sections. |
---|
74 | */ |
---|
75 | . = ALIGN (16); |
---|
76 | __start_set_sysctl_set = .; |
---|
77 | *(set_sysctl_*); |
---|
78 | __stop_set_sysctl_set = ABSOLUTE(.); |
---|
79 | *(set_domain_*); |
---|
80 | *(set_pseudo_*); |
---|
81 | |
---|
82 | /* |
---|
83 | * C++ constructors/destructors |
---|
84 | * |
---|
85 | * gcc uses crtbegin.o to find the start of the constructors |
---|
86 | * and destructors so we make sure it is first. Because this |
---|
87 | * is a wildcard, it doesn't matter if the user does not |
---|
88 | * actually link against crtbegin.o; the linker won't look for |
---|
89 | * a file to match a wildcard. The wildcard also means that |
---|
90 | * it doesn't matter which directory crtbegin.o is in. The |
---|
91 | * constructor and destructor list are terminated in |
---|
92 | * crtend.o. The same comments apply to it. |
---|
93 | */ |
---|
94 | . = ALIGN (16); |
---|
95 | *crtbegin.o(.ctors) |
---|
96 | *(.ctors) |
---|
97 | *crtend.o(.ctors) |
---|
98 | *crtbegin.o(.dtors) |
---|
99 | *(.dtors) |
---|
100 | *crtend.o(.dtors) |
---|
101 | |
---|
102 | /* |
---|
103 | * Exception frame info |
---|
104 | */ |
---|
105 | . = ALIGN (16); |
---|
106 | *(.eh_frame) |
---|
107 | |
---|
108 | /* |
---|
109 | * Read-only data |
---|
110 | */ |
---|
111 | . = ALIGN (16); |
---|
112 | _rodata_start = . ; |
---|
113 | *(.rodata*) |
---|
114 | *(.gnu.linkonce.r*) |
---|
115 | |
---|
116 | . = ALIGN (16); |
---|
117 | PROVIDE (_etext = .); |
---|
118 | } >ram |
---|
119 | .data : { |
---|
120 | PROVIDE (_copy_start = .); |
---|
121 | *(.data*) |
---|
122 | *(.gnu.linkonce.d*) |
---|
123 | *(.gcc_except_table) |
---|
124 | *(.jcr) |
---|
125 | . = ALIGN (16); |
---|
126 | PROVIDE (_edata = .); |
---|
127 | PROVIDE (_copy_end = .); |
---|
128 | } >ram |
---|
129 | .bss : { |
---|
130 | _clear_start = .; |
---|
131 | *(.dynbss) |
---|
132 | *(.bss* .gnu.linkonce.b.*) |
---|
133 | *(COMMON) |
---|
134 | . = ALIGN (16); |
---|
135 | PROVIDE (end = .); |
---|
136 | |
---|
137 | . += _StackSize; |
---|
138 | . = ALIGN (16); |
---|
139 | _stack_init = .; |
---|
140 | _clear_end = .; |
---|
141 | |
---|
142 | _WorkspaceBase = .; |
---|
143 | } >ram |
---|
144 | |
---|
145 | /* Stabs debugging sections. */ |
---|
146 | .stab 0 : { *(.stab) } |
---|
147 | .stabstr 0 : { *(.stabstr) } |
---|
148 | .stab.excl 0 : { *(.stab.excl) } |
---|
149 | .stab.exclstr 0 : { *(.stab.exclstr) } |
---|
150 | .stab.index 0 : { *(.stab.index) } |
---|
151 | .stab.indexstr 0 : { *(.stab.indexstr) } |
---|
152 | .comment 0 : { *(.comment) } |
---|
153 | |
---|
154 | /* DWARF debug sections. |
---|
155 | Symbols in the DWARF debugging sections are relative to the beginning |
---|
156 | of the section so we begin them at 0. */ |
---|
157 | /* DWARF 1 */ |
---|
158 | .debug 0 : { *(.debug) } |
---|
159 | .line 0 : { *(.line) } |
---|
160 | |
---|
161 | /* GNU DWARF 1 extensions */ |
---|
162 | .debug_srcinfo 0 : { *(.debug_srcinfo) } |
---|
163 | .debug_sfnames 0 : { *(.debug_sfnames) } |
---|
164 | |
---|
165 | /* DWARF 1.1 and DWARF 2 */ |
---|
166 | .debug_aranges 0 : { *(.debug_aranges) } |
---|
167 | .debug_pubnames 0 : { *(.debug_pubnames) } |
---|
168 | |
---|
169 | /* DWARF 2 */ |
---|
170 | .debug_info 0 : { *(.debug_info) } |
---|
171 | .debug_abbrev 0 : { *(.debug_abbrev) } |
---|
172 | .debug_line 0 : { *(.debug_line) } |
---|
173 | .debug_frame 0 : { *(.debug_frame) } |
---|
174 | .debug_str 0 : { *(.debug_str) } |
---|
175 | .debug_loc 0 : { *(.debug_loc) } |
---|
176 | .debug_macinfo 0 : { *(.debug_macinfo) } |
---|
177 | |
---|
178 | /* SGI/MIPS DWARF 2 extensions */ |
---|
179 | .debug_weaknames 0 : { *(.debug_weaknames) } |
---|
180 | .debug_funcnames 0 : { *(.debug_funcnames) } |
---|
181 | .debug_typenames 0 : { *(.debug_typenames) } |
---|
182 | .debug_varnames 0 : { *(.debug_varnames) } |
---|
183 | /* These must appear regardless of . */ |
---|
184 | } |
---|