source: rtems/c/src/lib/libbsp/m68k/efi332/startup/linkcmds_ROM @ 6f9c75c3

4.104.114.84.95
Last change on this file since 6f9c75c3 was 6f9c75c3, checked in by Joel Sherrill <joel.sherrill@…>, on 01/16/98 at 16:56:48

Ralf Corsepius reported a number of missing CVS Id's:

RTEMS is under CVS control and has been since rtems 3.1.16 which was
around May 1995. So I just to add the $Id$. If you notice other files
with missing $Id$'s let me know. I try to keep w\up with it.

Now that you have asked -- I'll attach a list of files lacking an RCS-Id to
this mail. This list has been generated by a little sh-script I'll also
enclose.

  • Property mode set to 100644
File size: 2.0 KB
Line 
1/*  linkcmds
2 *
3 *  $Id$
4 */
5
6OUTPUT_ARCH(m68k)
7STARTUP(except_vect_332_ROM.o)
8__DYNAMIC  =  0;
9
10/*
11 * ROM:
12 * +--------------------+ <- low memory
13 * | .text              |
14 * |        etext       |
15 * |        ctor list   | the ctor and dtor lists are for
16 * |        dtor list   | C++ support
17 * |        _endtext    |
18 * | temporary .data    | .data is moved to RAM by crt0
19 * |                    |
20 * +--------------------+ <- high memory
21 *
22 *
23 * RAM:
24 * +--------------------+ <- low memory
25 * | .data              | initialized data goes here
26 * |        _sdata      |
27 * |        _edata      |
28 * +--------------------+
29 * | .bss               |
30 * |        __bss_start | start of bss, cleared by crt0
31 * |        _end        | start of heap, used by sbrk()
32 * +--------------------+
33 * |    heap space      |
34 * |        _ENDHEAP    |
35 * |    stack space     |
36 * |        __stack     | top of stack
37 * +--------------------+ <- high memory
38 */
39
40MEMORY
41{
42  rom     : ORIGIN = 0x00000, LENGTH = 256K
43  ram     : ORIGIN = 0x80000, LENGTH = 256K
44}
45
46__end_of_ram = 0xc0000;
47_copy_data_from_rom = 1;
48
49/*
50 *
51 */
52SECTIONS
53{
54  .text :
55  {
56    CREATE_OBJECT_SYMBOLS
57    text_start = .;
58    _text_start = .;
59    *(.text)
60    etext = ALIGN(0x10);
61    _etext = .;
62    __CTOR_LIST__ = .;
63    LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
64    *(.ctors)
65    LONG(0)
66    __CTOR_END__ = .;
67    __DTOR_LIST__ = .;
68    LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
69    *(.dtors)
70    LONG(0)
71    __DTOR_END__ = .;
72    *(.lit)
73    *(.shdata)
74    _endtext = .;
75  } > rom
76  .data :
77  AT ( ADDR(.text) + SIZEOF( .text ) )
78  {
79    data_start = .;
80    _data_start = .;
81    _sdata = . ;
82    *(.data)
83    CONSTRUCTORS
84    edata = ALIGN(0x10);
85    _edata = .;
86  } > ram
87  .shbss :
88  {
89    *(.shbss)
90  } > ram
91  .bss :
92  {
93    __bss_start = ALIGN(0x8);
94    bss_start = .;
95    _bss_start = .;
96    *(.bss)
97    *(COMMON)
98    end = .;
99    _end = ALIGN(0x8);
100    __end = ALIGN(0x8);
101  } > ram
102  .stab . (NOLOAD) :
103  {
104    [ .stab ]
105  }
106  .stabstr . (NOLOAD) :
107  {
108    [ .stabstr ]
109  }
110}
Note: See TracBrowser for help on using the repository browser.