source: rtems/c/src/lib/libbsp/m68k/dmv152/startup/linkcmds @ c2e9632

4.104.114.84.95
Last change on this file since c2e9632 was 9980062, checked in by Joel Sherrill <joel.sherrill@…>, on Sep 4, 2003 at 6:51:36 PM

2003-09-04 Joel Sherrill <joel@…>

  • clock/ckinit.c, console/console.c, include/bsp.h, include/coverhd.h, spurious/spinit.c, startup/bspclean.c, startup/bspstart.c, startup/linkcmds, startup/vmeintr.c, timer/timer.c, timer/timerisr.S: URL for license changed.
  • Property mode set to 100644
File size: 4.7 KB
Line 
1/*
2 *  This file contains directives for the GNU linker which are specific
3 *  to the DY-4 DMV152/SVME153 boards.
4 *
5 *  COPYRIGHT (c) 1989-2003.
6 *  On-Line Applications Research Corporation (OAR).
7 *
8 *  The license and distribution terms for this file may be
9 *  found in the file LICENSE in this distribution or at
10 *  http://www.rtems.com/license/LICENSE.
11 *
12 *  $Id$
13 */
14
15/*
16 * Declare some sizes.
17 */
18_RamBase = DEFINED(_RamBase) ? _RamBase : 0x0;
19_RamSize = DEFINED(_RamSize) ? _RamSize : 1M;
20_HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0x10000;
21_StackSize = DEFINED(_StackSize) ? _StackSize : 0x1000;
22
23MEMORY
24{
25        ram : org = 0x0, l = 1M
26}
27
28SECTIONS
29{
30        ram : {
31                . = 0x12800;
32        } >ram
33
34        /*
35         * Text, data and bss segments
36         */
37        .text : {
38                *(.text)
39
40                /*
41                 * C++ constructors/destructors
42                 */
43                *(.gnu.linkonce.t.*)
44
45                /*
46                 * Initialization and finalization code.
47                 *
48                 * Various files can provide initialization and finalization
49                 * functions.  crtbegin.o and crtend.o are two instances. The
50                 * body of these functions are in .init and .fini sections. We
51                 * accumulate the bodies here, and prepend function prologues
52                 * from crti.o and function epilogues from crtn.o. crti.o must
53                 * be linked first; crtn.o must be linked last.  Because these
54                 * are wildcards, it doesn't matter if the user does not
55                 * actually link against crti.o and crtn.o; the linker won't
56                 * look for a file to match a wildcard.  The wildcard also
57                 * means that it doesn't matter which directory crti.o and
58                 * crtn.o are in.
59                 */
60                PROVIDE (_init = .);
61                *crti.o(.init)
62                *(.init)
63                *crtn.o(.init)
64                PROVIDE (_fini = .);
65                *crti.o(.fini)
66                *(.fini)
67                *crtn.o(.fini)
68
69                /*
70                 * Special FreeBSD sysctl sections.
71                 */
72                . = ALIGN (16);
73                __start_set_sysctl_set = .;
74                *(set_sysctl_*);
75                __stop_set_sysctl_set = ABSOLUTE(.);
76                *(set_domain_*);
77                *(set_pseudo_*);
78
79                /*
80                 * C++ constructors/destructors
81                 *
82                 * gcc uses crtbegin.o to find the start of the constructors
83                 * and destructors so we make sure it is first.  Because this
84                 * is a wildcard, it doesn't matter if the user does not
85                 * actually link against crtbegin.o; the linker won't look for
86                 * a file to match a wildcard.  The wildcard also means that
87                 * it doesn't matter which directory crtbegin.o is in. The
88                 * constructor and destructor list are terminated in
89                 * crtend.o.  The same comments apply to it.
90                 */
91                . = ALIGN (16);
92                *crtbegin.o(.ctors)
93                *(.ctors)
94                *crtend.o(.ctors)
95                *crtbegin.o(.dtors)
96                *(.dtors)
97                *crtend.o(.dtors)
98
99                /*
100                 * Exception frame info
101                 */
102                . = ALIGN (16);
103                *(.eh_frame)
104
105                /*
106                 * Read-only data
107                 */
108                . = ALIGN (16);
109                _rodata_start = . ;
110                *(.rodata*)
111                *(.gnu.linkonce.r*)
112
113                 . = ALIGN (16);
114                PROVIDE (etext = .);
115        } >ram
116        .data : {
117                copy_start = .;
118                *(.data)
119                *(.gnu.linkonce.d*)
120                *(.gcc_except_table)
121                *(.jcr)
122                . = ALIGN (16);
123                PROVIDE (_edata = .);
124                copy_end = .;
125        } >ram
126        .bss : {
127                _clear_start = .;
128                *(.bss)
129                *(COMMON)
130                . = ALIGN (16);
131                PROVIDE (end = .);
132
133                . += _StackSize;
134                . = ALIGN (16);
135                _stack_init = .;
136                _clear_end = .;
137
138                _WorkspaceBase = .;
139        } >ram
140
141  /* Stabs debugging sections.  */
142  .stab 0 : { *(.stab) }
143  .stabstr 0 : { *(.stabstr) }
144  .stab.excl 0 : { *(.stab.excl) }
145  .stab.exclstr 0 : { *(.stab.exclstr) }
146  .stab.index 0 : { *(.stab.index) }
147  .stab.indexstr 0 : { *(.stab.indexstr) }
148  .comment 0 : { *(.comment) }
149
150  /* DWARF debug sections.
151     Symbols in the DWARF debugging sections are relative to the beginning
152     of the section so we begin them at 0.  */
153  /* DWARF 1 */
154  .debug          0 : { *(.debug) }
155  .line           0 : { *(.line) }
156 
157  /* GNU DWARF 1 extensions */
158  .debug_srcinfo  0 : { *(.debug_srcinfo) }
159  .debug_sfnames  0 : { *(.debug_sfnames) }
160 
161  /* DWARF 1.1 and DWARF 2 */
162  .debug_aranges  0 : { *(.debug_aranges) }
163  .debug_pubnames 0 : { *(.debug_pubnames) }
164 
165  /* DWARF 2 */
166  .debug_info     0 : { *(.debug_info) }
167  .debug_abbrev   0 : { *(.debug_abbrev) }
168  .debug_line     0 : { *(.debug_line) }
169  .debug_frame    0 : { *(.debug_frame) }
170  .debug_str      0 : { *(.debug_str) }
171  .debug_loc      0 : { *(.debug_loc) }
172  .debug_macinfo  0 : { *(.debug_macinfo) }
173 
174  /* SGI/MIPS DWARF 2 extensions */
175  .debug_weaknames 0 : { *(.debug_weaknames) }
176  .debug_funcnames 0 : { *(.debug_funcnames) }
177  .debug_typenames 0 : { *(.debug_typenames) }
178  .debug_varnames  0 : { *(.debug_varnames) }
179  /* These must appear regardless of  .  */
180}
Note: See TracBrowser for help on using the repository browser.