source: rtems/c/src/lib/libbsp/m68k/av5282/startup/linkcmdsram @ a474e3c

4.104.114.84.9
Last change on this file since a474e3c was a474e3c, checked in by Joel Sherrill <joel.sherrill@…>, on Mar 12, 2007 at 11:18:19 AM

2007-03-12 Joel Sherrill <joel@…>

  • include/coverhd.h, start/start.S, startup/bspclean.c, startup/bspstart.c, startup/linkcmds, startup/linkcmdsflash, startup/linkcmdsram: Correct license URL and/or fix mistake in copyright notice. Both of these mistakes appear to be from code submitted after these changes were made previously.
  • Property mode set to 100644
File size: 4.6 KB
Line 
1/*
2 *  This file contains directives for the GNU linker which are specific
3 *  to the Arcturus uC DIMM ColdFire 5282
4 *
5 *  COPYRIGHT (c) 1989-1999.
6 *  On-Line Applications Research Corporation (OAR).
7 *
8 *  The license and distribution terms for this file may be
9 *  found in the file LICENSE in this distribution or at
10 *  http://www.rtems.com/license/LICENSE.
11 *
12 *  $Id$
13 */
14
15/*
16 * Declare some sizes.
17 */
18_RamBase = DEFINED(_RamBase) ? _RamBase : 0x0 ;
19_RamSize = DEFINED(_RamSize) ? _RamSize : 16M ;
20_HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0 ;
21_VBR = 0x0;
22
23/*
24 * System clock speed
25 */
26_CPUClockSpeed = DEFINED(_CPUClockSpeed) ? _CPUClockSpeed : 58976000 ;
27
28/*
29 * Location of on-chip devicesa
30 */
31__IPSBAR = DEFINED(__IPSBAR) ? __IPSBAR : 0x40000000 ;
32__SRAMBASE = DEFINED(__SRAMBASE) ? __SRAMBASE : 0x20000000 ;
33
34ENTRY(start)
35MEMORY
36{
37    ram : ORIGIN = 0, LENGTH = 16M
38    sram : ORIGIN = 0x20000000, LENGTH = 64K
39    flash : ORIGIN = 0xFF800000, LENGTH = 8M
40}
41
42SECTIONS
43{
44   
45    _header_offset = 0;
46   
47    /*
48     * Text, data and bss segments
49     */
50    .text 0x40000 : {
51       
52       *(.text*)
53        *(.ram_code)
54
55        /*
56         * C++ constructors/destructors
57         */
58        *(.gnu.linkonce.t.*)
59
60        /*
61         * Initialization and finalization code.
62              *
63              * Various files can provide initialization and finalization
64         * functions.  crtbegin.o and crtend.o are two instances. The
65         * body of these functions are in .init and .fini sections. We
66         * accumulate the bodies here, and prepend function prologues
67         * from crti.o and function epilogues from crtn.o. crti.o must
68         * be linked first; crtn.o must be linked last.  Because these
69         * are wildcards, it doesn't matter if the user does not
70         * actually link against crti.o and crtn.o; the linker won't
71         * look for a file to match a wildcard.  The wildcard also
72         * means that it doesn't matter which directory crti.o and
73         * crtn.o are in.
74         */
75        PROVIDE (_init = .);
76        *crti.o(.init)
77        *(.init)
78        *crtn.o(.init)
79        PROVIDE (_fini = .);
80        *crti.o(.fini)
81        *(.fini)
82        *crtn.o(.fini)
83
84        /*
85         * Special FreeBSD sysctl sections.
86         */
87        . = ALIGN (16);
88        __start_set_sysctl_set = .;
89        *(set_sysctl_*);
90        __stop_set_sysctl_set = ABSOLUTE(.);
91        *(set_domain_*);
92        *(set_pseudo_*);
93
94
95        /*
96         * C++ constructors/destructors
97         *
98         * gcc uses crtbegin.o to find the start of the constructors
99         * and destructors so we make sure it is first.  Because this
100         * is a wildcard, it doesn't matter if the user does not
101         * actually link against crtbegin.o; the linker won't look for
102         * a file to match a wildcard.  The wildcard also means that
103         * it doesn't matter which directory crtbegin.o is in. The
104         * constructor and destructor list are terminated in
105         * crtend.o.  The same comments apply to it.
106         */
107        . = ALIGN (16);
108        *crtbegin.o(.ctors)
109        *(.ctors)
110        *crtend.o(.ctors)
111        *crtbegin.o(.dtors)
112        *(.dtors)
113        *crtend.o(.dtors)
114
115        /*
116         * Exception frame info
117         */
118        . = ALIGN (16);
119        *(.eh_frame)
120
121        /*
122         * Read-only data
123         */
124        . = ALIGN (16);
125        _rodata_start = . ;
126        *(.rodata*)
127        *(.gnu.linkonce.r*)
128       
129        . = ALIGN (16);
130
131        *(.console_gdb_xfer)
132        *(.bootstrap_data)
133        . = ALIGN(16);
134        _estuff = .;
135    PROVIDE (_etext = .);
136    } >ram
137       
138        .data : {
139            PROVIDE( _data_dest_start = . );
140            PROVIDE( _copy_start = .);
141            *(.data)
142            *(.gnu.linkonce.d*)
143            *(.gcc_except_table)
144            *(.jcr)
145            . = ALIGN (16);
146            PROVIDE (_edata = .);
147        PROVIDE (_copy_end = .);
148        PROVIDE (_data_dest_end = . );
149        } >ram
150
151        _data_src_start = _estuff;
152        _data_src_end = _data_dest_start + SIZEOF(.data);       
153       
154        .bss : {
155                _clear_start = .;
156                *(.bss*)
157                *(COMMON)
158                . = ALIGN (16);
159                PROVIDE (end = .);
160                _clear_end = .;
161
162                _WorkspaceBase = .;
163        } >ram
164  /* Stabs debugging sections.  */
165  .stab 0 : { *(.stab) }
166  .stabstr 0 : { *(.stabstr) }
167  .stab.excl 0 : { *(.stab.excl) }
168  .stab.exclstr 0 : { *(.stab.exclstr) }
169  .stab.index 0 : { *(.stab.index) }
170  .stab.indexstr 0 : { *(.stab.indexstr) }
171  .comment 0 : { *(.comment) }
172
173PROVIDE (end_of_all = .); 
174}
Note: See TracBrowser for help on using the repository browser.