source: rtems/c/src/lib/libbsp/lm32/milkymist/startup/linkcmds @ d60e760

4.115
Last change on this file since d60e760 was d60e760, checked in by Sebastian Huber <sebastian.huber@…>, on 04/22/14 at 07:45:39

bsps: Fix TLS support in linker command files

The TLS section symbols had wrong values in case of an empty TLS data
section and a nonempty TLS BSS section.
  • Property mode set to 100644
File size: 9.9 KB
Line 
1OUTPUT_FORMAT("elf32-lm32", "elf32-lm32",
2              "elf32-lm32")
3OUTPUT_ARCH(lm32)
4ENTRY(_start)
5/* Do we need any of these for elf?
6   __DYNAMIC = 0;    */
7
8/*
9 * Declare some sizes. Heap is sized at whatever ram space is left.
10 */
11RamBase = DEFINED(RamBase) ? RamBase : 0x40000000;
12RamSize = DEFINED(RamSize) ? RamSize : 128M;
13HeapSize = DEFINED(HeapSize) ? HeapSize : 92M;
14_StackSize = DEFINED(_StackSize) ? _StackSize : 0x2000;
15
16PROVIDE (__stack = 0);
17MEMORY {
18        sdram   : ORIGIN = 0x40000000 , LENGTH = 128M
19}
20SECTIONS
21{
22  .boot :
23  {
24    KEEP (*(.boot))
25  } > sdram
26
27  /* Read-only sections, merged into text segment: */
28  .interp   : { *(.interp) }    > sdram
29  .hash           : { *(.hash)          }       > sdram
30  .dynsym         : { *(.dynsym)                }       > sdram
31  .dynstr         : { *(.dynstr)                }       > sdram
32  .gnu.version   : { *(.gnu.version)      }     > sdram
33  .gnu.version_d   : { *(.gnu.version_d)  }     > sdram
34  .gnu.version_r   : { *(.gnu.version_r)  }     > sdram
35  .rela.text     :
36    { *(.rela.text) *(.rela.gnu.linkonce.t*) }  > sdram
37  .rela.data     :
38    { *(.rela.data) *(.rela.gnu.linkonce.d*) }  > sdram
39  .rela.rodata   :
40    { *(.rela.rodata*) *(.rela.gnu.linkonce.r*) }       > sdram
41  .rela.got       : { *(.rela.got)      }       > sdram
42  .rela.got1      : { *(.rela.got1)     }       > sdram
43  .rela.got2      : { *(.rela.got2)     }       > sdram
44  .rela.ctors     : { *(.rela.ctors)    }       > sdram
45  .rela.dtors     : { *(.rela.dtors)    }       > sdram
46  .rela.init      : { *(.rela.init)     }       > sdram
47  .rela.fini      : { *(.rela.fini)     }       > sdram
48  .rela.bss       : { *(.rela.bss)      }       > sdram
49  .rela.plt       : { *(.rela.plt)      }       > sdram
50  .rela.sdata     : { *(.rela.sdata)    }       > sdram
51  .rela.sbss      : { *(.rela.sbss)     }       > sdram
52  .rela.sdata2    : { *(.rela.sdata2)   }       > sdram
53  .rela.sbss2     : { *(.rela.sbss2)    }       > sdram
54  .rela.dyn       : { *(.rela.dyn)      }       > sdram
55
56  .init           : { KEEP(*(.init))            } > sdram
57
58  .text      : 
59  {
60    *(.text*)   
61
62    /*
63     * Special FreeBSD sysctl sections.
64     */
65    . = ALIGN (16);
66    __start_set_sysctl_set = .;
67    *(set_sysctl_*);
68    __stop_set_sysctl_set = ABSOLUTE(.);
69    *(set_domain_*);
70    *(set_pseudo_*);
71
72    /* .gnu.warning sections are handled specially by elf32.em.  */
73    *(.gnu.warning)
74    *(.gnu.linkonce.t*)
75  }  > sdram
76
77  .fini           : { _fini = .; KEEP(*(.fini)) } > sdram
78
79  .rodata         : { *(.rodata*) *(.gnu.linkonce.r*) } > sdram
80  .rodata1        : { *(.rodata1) }     > sdram
81  .tdata : {
82    _TLS_Data_begin = .;
83    *(.tdata .tdata.* .gnu.linkonce.td.*)
84    _TLS_Data_end = .;
85  } > sdram
86  .tbss : {
87    _TLS_BSS_begin = .;
88    *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon)
89    _TLS_BSS_end = .;
90  } > sdram
91  _TLS_Data_size = _TLS_Data_end - _TLS_Data_begin;
92  _TLS_Data_begin = _TLS_Data_size != 0 ? _TLS_Data_begin : _TLS_BSS_begin;
93  _TLS_Data_end = _TLS_Data_size != 0 ? _TLS_Data_end : _TLS_BSS_begin;
94  _TLS_BSS_size = _TLS_BSS_end - _TLS_BSS_begin;
95  _TLS_Size = _TLS_BSS_end - _TLS_Data_begin;
96  _TLS_Alignment = MAX (ALIGNOF (.tdata), ALIGNOF (.tbss));
97
98  /* Adjust the address for the data segment.  We want to adjust up to
99     the same address within the page on the next page up.  */
100  . = ALIGN(0x10000) + (. & (0x10000 - 1));
101  /* Ensure the __preinit_array_start label is properly aligned.  We
102     could instead move the label definition inside the section, but
103     the linker would then create the section even if it turns out to
104     be empty, which isn't pretty.  */
105  . = ALIGN(32 / 8);
106  PROVIDE (__preinit_array_start = .);
107  .preinit_array     : { *(.preinit_array) } >sdram
108  PROVIDE (__preinit_array_end = .);
109  PROVIDE (__init_array_start = .);
110  .init_array     : { *(.init_array) } >sdram
111  PROVIDE (__init_array_end = .);
112  PROVIDE (__fini_array_start = .);
113  .fini_array     : { *(.fini_array) } >sdram
114  PROVIDE (__fini_array_end = .);
115
116/* _SDA2_BASE_ = __SDATA2_START__ + 0xe000; */
117  .sdata2         : { *(.sdata2 .sdata2.* .gnu.linkonce.s2.*) } >sdram
118  .sbss2          : { *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*)
119                        /* avoid empty sdata2/sbss2 area -- __eabi would not set up r2
120                         * which may be important if run-time loading is used
121                         */
122                     . += 1;
123                    } >sdram
124  .eh_frame       : { *.(eh_frame)              } >sdram
125
126  /* NOTE: if the BSP uses page tables, the correctness of
127   *       '_etext' (and __DATA_START__) is CRUCIAL - otherwise,
128   *       an invalid mapping may result!!!
129   */
130  _etext = .;
131  PROVIDE (etext = .);
132
133  /* Adjust the address for the data segment.  We want to adjust up to
134     the same address within the page on the next page up.  It would
135     be more correct to do this:
136       . = ALIGN(0x40000) + (ALIGN(8) & (0x40000 - 1));
137     The current expression does not correctly handle the case of a
138     text segment ending precisely at the end of a page; it causes the
139     data segment to skip a page.  The above expression does not have
140     this problem, but it will currently (2/95) cause BFD to allocate
141     a single segment, combining both text and data, for this case.
142     This will prevent the text segment from being shared among
143     multiple executions of the program; I think that is more
144     important than losing a page of the virtual address space (note
145     that no actual memory is lost; the page which is skipped can not
146     be referenced).  */
147  . = ALIGN(0x1000);
148 .data ALIGN(0x1000) :
149  {
150   /* NOTE: if the BSP uses page tables, the correctness of
151    *       '__DATA_START__' (and _etext) is CRUCIAL - otherwise,
152    *       an invalid mapping may result!!!
153    */
154        PROVIDE(__DATA_START__ = ABSOLUTE(.) );
155    *(.data .data.* .gnu.linkonce.d*)   
156    SORT(CONSTRUCTORS)
157  } > sdram
158  .data1   : { *(.data1) }      > sdram
159  PROVIDE (__EXCEPT_START__ = .);
160  .gcc_except_table   : {
161    *(.gcc_except_table)
162    *(.gcc_except_table.*)
163  } > sdram
164  PROVIDE (__EXCEPT_END__ = .);
165  .got1           : { *(.got1) }        > sdram
166  /* Put .ctors and .dtors next to the .got2 section, so that the pointers
167     get relocated with -mrelocatable. Also put in the .fixup pointers.
168     The current compiler no longer needs this, but keep it around for 2.7.2  */
169                PROVIDE (_GOT2_START_ = .);
170  .got2           :  { *(.got2) }       > sdram
171  .dynamic        : { *(.dynamic) }     > sdram
172
173  .ctors          :
174  {
175    /* gcc uses crtbegin.o to find the start of
176       the constructors, so we make sure it is
177       first.  Because this is a wildcard, it
178       doesn't matter if the user does not
179       actually link against crtbegin.o; the
180       linker won't look for a file to match a
181       wildcard.  The wildcard also means that it
182       doesn't matter which directory crtbegin.o
183       is in.  */
184    KEEP (*crtbegin.o(.ctors))
185    /* We don't want to include the .ctor section from
186       from the crtend.o file until after the sorted ctors.
187       The .ctor section from the crtend file contains the
188       end of ctors marker and it must be last */
189    KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
190    KEEP (*(SORT(.ctors.*)))
191    KEEP (*(.ctors))
192  } > sdram
193  .dtors          :
194  {
195    KEEP (*crtbegin.o(.dtors))
196    KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
197    KEEP (*(SORT(.dtors.*)))
198    KEEP (*(.dtors))
199  } > sdram
200
201
202                PROVIDE (_FIXUP_START_ = .);
203  .fixup          : { *(.fixup) }       > sdram
204                PROVIDE (_FIXUP_END_ = .);
205                PROVIDE (_GOT2_END_ = .);
206                PROVIDE (_GOT_START_ = .);
207
208  .got            : { *(.got) } > sdram
209  .got.plt        : { *(.got.plt) }     > sdram
210
211                PROVIDE (_GOT_END_ = .);
212
213  .jcr            : { KEEP (*(.jcr)) } > sdram
214
215  /* We want the small data sections together, so single-instruction offsets
216     can access them all, and initialized data all before uninitialized, so
217     we can shorten the on-disk segment size.  */
218/* _SDA_BASE_ = __SDATA_START__ + 0xe000; */
219  .sdata          : { *(.sdata*) *(.gnu.linkonce.s.*)   } >sdram
220  _edata  =  .;
221  _gp = .;
222  PROVIDE (edata = .);
223  .sbss      :
224  {
225    _clear_start = .;
226    PROVIDE (__sbss_start = .);
227    *(.dynsbss)
228    *(.sbss* .gnu.linkonce.sb.*)
229    *(.scommon)
230    /* avoid empty sdata/sbss area -- __eabi would not set up r13
231     * which may be important if run-time loading is used
232     */
233    . += 1;
234    . = ALIGN(16);
235    PROVIDE (__sbss_end = .);
236  } > sdram
237  .plt   : { *(.plt) }  > sdram
238  .bss       :
239  {
240   PROVIDE (__bss_start = .);
241   *(.dynbss)
242   *(.bss .bss* .gnu.linkonce.b*)
243   *(COMMON)
244  . = ALIGN(16);
245  _end = . ;
246  __rtems_end = . ;
247  PROVIDE (end = .);
248
249  . += _StackSize;
250  _fstack = .;
251
252  WorkAreaBase = .;
253
254    . = ALIGN (16);
255    _stack_init = .;
256    _clear_end = .;
257
258  } > sdram
259
260
261  /DISCARD/ :
262  {
263    *(.comment)
264  }
265
266
267  /* Stabs debugging sections.  */
268  .stab 0 : { *(.stab) }
269  .stabstr 0 : { *(.stabstr) }
270  .stab.excl 0 : { *(.stab.excl) }
271  .stab.exclstr 0 : { *(.stab.exclstr) }
272  .stab.index 0 : { *(.stab.index) }
273  .stab.indexstr 0 : { *(.stab.indexstr) }
274  .comment 0 : { *(.comment) }
275
276  /* DWARF debug sections.
277     Symbols in the DWARF debugging sections are relative to the beginning
278     of the section so we begin them at 0.  */
279  /* DWARF 1 */
280  .debug          0 : { *(.debug) }
281  .line           0 : { *(.line) }
282 
283  /* GNU DWARF 1 extensions */
284  .debug_srcinfo  0 : { *(.debug_srcinfo) }
285  .debug_sfnames  0 : { *(.debug_sfnames) }
286 
287  /* DWARF 1.1 and DWARF 2 */
288  .debug_aranges  0 : { *(.debug_aranges) }
289  .debug_pubnames 0 : { *(.debug_pubnames) }
290 
291  /* DWARF 2 */
292  .debug_info     0 : { *(.debug_info) }
293  .debug_abbrev   0 : { *(.debug_abbrev) }
294  .debug_line     0 : { *(.debug_line) }
295  .debug_frame    0 : { *(.debug_frame) }
296  .debug_str      0 : { *(.debug_str) }
297  .debug_loc      0 : { *(.debug_loc) }
298  .debug_macinfo  0 : { *(.debug_macinfo) }
299 
300  /* SGI/MIPS DWARF 2 extensions */
301  .debug_weaknames 0 : { *(.debug_weaknames) }
302  .debug_funcnames 0 : { *(.debug_funcnames) }
303  .debug_typenames 0 : { *(.debug_typenames) }
304  .debug_varnames  0 : { *(.debug_varnames) }
305  /* These must appear regardless of  .  */
306}
Note: See TracBrowser for help on using the repository browser.