source: rtems/c/src/lib/libbsp/i960/rxgen960/startup/linkcmds @ 9c1133e

/*
 *  This is not the real linkcmds for this target.  See
 *  linkcmds.real and make those work for you.  That linkcmds
 *  goes to great lengths to handplace certain object files
 *  in very specific locations.  
 *
 *  $Id$
 */

/*
 * Declare some sizes.
 */
_RamBase = DEFINED(_RamBase) ? _RamBase : 0x0;
_RamSize = DEFINED(_RamSize) ? _RamSize : 1M;
_HeapSize = DEFINED(_HeapSize) ? _HeapSize : 0x10000;
_StackSize = DEFINED(_StackSize) ? _StackSize : 0x1000;

SECTIONS
{ 
    . = 0x0;
    .text : 
    { 
         CREATE_OBJECT_SYMBOLS
        *(.text) 
        _rodata_start = . ;
        *(.rodata*)
        *(.gnu.linkonce.r*)
        _erodata = ALIGN( 0x10 ) ;
         _etext = .;
        
        /*
         * Special FreeBSD sysctl sections.
         */
        . = ALIGN (16);
        __start_set_sysctl_set = .;
        *(set_sysctl_*);
        __stop_set_sysctl_set = ABSOLUTE(.);
        *(set_domain_*);
        *(set_pseudo_*);

        ___CTOR_LIST__ = .;
        LONG((___CTOR_END__ - ___CTOR_LIST__) / 4 - 2)
        *(.ctors)
        LONG(0)
        ___CTOR_END__ = .;
        ___DTOR_LIST__ = .;
        LONG((___DTOR_END__ - ___DTOR_LIST__) / 4 - 2)
        *(.dtors)
        LONG(0)
        ___DTOR_END__ = .;
    }  
    .data SIZEOF(.text) + ADDR(.text):
    { 
        *(.data) 
        CONSTRUCTORS
         _edata = .;
    }  
    .bss SIZEOF(.data) + ADDR(.data):
    { 
         _bss_start = .;
        *(.bss)  
        *(COMMON) 
        . = ALIGN (64);
        _stack_init = .;
        . += _StackSize;
        _clear_end = .;
        _WorkspaceBase = .;
        . += 512K;      /* reserve some memory for workspace */
        _HeapBase = .;
        . += _HeapSize; /* reserve some memory for heap */
         _end = .;
         __end = .;
    } 
}