source: rtems/c/src/lib/libbsp/i386/pc386/configure.ac @ 3dd381f

Last change on this file since 3dd381f was 3dd381f, checked in by Sebastian Huber <sebastian.huber@…>, on Nov 21, 2017 at 11:50:58 AM

bsps: Simplify RTEMS_BSP_CLEANUP_OPTIONS

Remove BSP-specific defaults for RTEMS_BSP_CLEANUP_OPTIONS to simplify
the BSP configuration and documentation. Change defaults to:

BSP_PRESS_KEY_FOR_RESET=0
BSP_RESET_BOARD_AT_EXIT=1
BSP_PRINT_EXCEPTION_CONTEXT=1

  • Property mode set to 100644
File size: 5.7 KB
Line 
1## Process this file with autoconf to produce a configure script.
2
3AC_PREREQ([2.69])
4AC_INIT([rtems-c-src-lib-libbsp-i386-pc386],[_RTEMS_VERSION],[https://devel.rtems.org/newticket])
5AC_CONFIG_SRCDIR([bsp_specs])
6RTEMS_TOP(../../../../../..)
7
8RTEMS_CANONICAL_TARGET_CPU
9AM_INIT_AUTOMAKE([no-define nostdinc foreign 1.12.2])
10RTEMS_BSP_CONFIGURE
11
12RTEMS_PROG_CC_FOR_TARGET
13RTEMS_CANONICALIZE_TOOLS
14RTEMS_CHECK_TOOL(OBJCOPY,objcopy,:)
15RTEMS_PROG_CCAS
16
17RTEMS_CHECK_NETWORKING
18RTEMS_CHECK_SMP
19
20RTEMS_BSPOPTS_SET([BSP_ENABLE_VGA],[*],[1])
21RTEMS_BSPOPTS_HELP([BSP_ENABLE_VGA],
22[Set if the VGA and keyboard console support is enabled.])
23AM_CONDITIONAL(RTEMS_VGA,[test "$BSP_ENABLE_VGA" = "1"])
24
25RTEMS_BSPOPTS_SET([BSP_ENABLE_COM1_COM4],[*],[1])
26RTEMS_BSPOPTS_HELP([BSP_ENABLE_COM1_COM4],
27[Set if COM1..COM4 support is enabled.])
28
29RTEMS_BSPOPTS_SET([BSP_ENABLE_IDE],[*],[1])
30RTEMS_BSPOPTS_HELP([BSP_ENABLE_IDE],
31[Set if IDE support is enabled.])
32AM_CONDITIONAL(HAS_IDE,[test "$BSP_ENABLE_IDE" = "1"])
33
34RTEMS_BSPOPTS_SET([USE_COM1_AS_CONSOLE],[*],[0])
35RTEMS_BSPOPTS_HELP([USE_COM1_AS_CONSOLE],
36[Determines, whether the console will be associated with the standard
37 VGA display or with the COM1 serial port.  Currently only the VGA
38 display and COM1 support printk.])
39
40RTEMS_BSPOPTS_SET([IDE_USE_PRIMARY_INTERFACE],[*],[1])
41RTEMS_BSPOPTS_HELP([IDE_USE_PRIMARY_INTERFACE],
42[Determines, whether RTEMS will try to use the primary IDE interface.
43 Disable it, if:
44 - you have no primary IDE interface
45 - or you have no disk attached to this interface
46 - or you do not want to access disks attached to this interface])
47
48RTEMS_BSPOPTS_SET([IDE_USE_SECONDARY_INTERFACE],[*],[0])
49RTEMS_BSPOPTS_HELP([IDE_USE_SECONDARY_INTERFACE],
50[Determines, whether RTEMS will try to use the secondary IDE interface.
51 Enable it, if:
52 - you have a secondary IDE interface
53 - and you have at least one disk attached to this interface
54 - and you do want to access disks attached to this interface])
55
56RTEMS_BSPOPTS_SET([BSP_VIDEO_80x50],[*],[0])
57RTEMS_BSPOPTS_HELP([BSP_VIDEO_80x50],
58[If defined, set the VGA display to 80x50.])
59
60RTEMS_BSPOPTS_SET([CLOCK_DRIVER_USE_TSC],[*],[0])
61RTEMS_BSPOPTS_HELP([CLOCK_DRIVER_USE_TSC],
62[If enabled, the clock driver will use the TSC register available
63 with Pentium-class CPUs to report close to nanosecond-accuracy
64 clock times.
65 Enable it, if:
66 - you have nanosecond timing enabled (you do NOT have
67   USE_TICKS_FOR_CPU_USAGE_STATISTICS enabled)
68 - you do NOT have CLOCK_DRIVER_USE_8254 enabled (use one, the other,
69   or neither)
70 - you have a Pentium which supports TSC (all Intels, and probably
71   all or most clones)
72 - you do not have a variable-speed CPU clock. Note that some
73   motherboard BIOS will automatically vary clock speed for thermal
74   control. Note also, however, that really new Pentium-class chips
75   from Intel and AMD will maintain a constant-rate TSC regardless.
76])
77
78#define CLOCK_DRIVER_USE_8254 $CLOCK_DRIVER_USE_8254
79RTEMS_BSPOPTS_SET([CLOCK_DRIVER_USE_8254],[*],[0])
80RTEMS_BSPOPTS_HELP([CLOCK_DRIVER_USE_8254],
81[If enabled, the clock driver will use the good old 8254 chip
82 to report microsecond-accuracy clock times.
83 Enable it, if:
84 - you have nanosecond timing enabled (you do NOT have
85   USE_TICKS_FOR_CPU_USAGE_STATISTICS enabled)
86 - you do NOT have CLOCK_DRIVER_USE_TSC enabled (use one, the other,
87   or neither)
88 - you do not mind adding roughly 5 microseconds to each context switch.
89])
90
91if test "${USE_CIRRUS_GD5446}" != "1" -a "${USE_VGA}" != "1"; then
92  USE_VBE_RM=1;
93  if test -z "${NUM_APP_DRV_GDT_DESCRIPTORS}"; then
94      NUM_APP_DRV_GDT_DESCRIPTORS=2 ;
95  else
96      NUM_APP_DRV_GDT_DESCRIPTORS+=2 ;
97  fi
98fi
99RTEMS_BSPOPTS_SET([NUM_APP_DRV_GDT_DESCRIPTORS],[*],[0])
100RTEMS_BSPOPTS_HELP([NUM_APP_DRV_GDT_DESCRIPTORS],
101[Defines how many descriptors in GDT may be allocated for application or
102 driver usage.])
103
104RTEMS_BSPOPTS_SET([USE_CIRRUS_GD5446],[*],[0])
105RTEMS_BSPOPTS_HELP([USE_CIRRUS_GD5446],
106[If defined, enables use of the Cirrus GD5446 controller rather than the
107 controller utilizing Vesa Bios Extensions - real mode interface.
108
109 NOTE: This has only been tested on Qemu.])
110AM_CONDITIONAL(USE_CIRRUS_GD5446,test "$USE_CIRRUS_GD5446" = "1")
111
112RTEMS_BSPOPTS_SET([USE_VGA],[*],[0])
113RTEMS_BSPOPTS_HELP([USE_VGA],
114[If defined, enables use of the very basic VGA driver for framebuffer support
115 rather than the controller utilizing Vesa Bios Extensions - real mode
116 interface.])
117AM_CONDITIONAL(USE_VGA,test "$USE_VGA" = "1")
118
119RTEMS_BSPOPTS_SET([USE_VBE_RM],[*],[0])
120RTEMS_BSPOPTS_HELP([USE_VBE_RM],
121[Defined by default. Enables use of the Vesa Bios Extensions - real mode
122 interface, which enables graphical mode and introduce it upon bootup.])
123AM_CONDITIONAL(USE_VBE_RM,test "$USE_VBE_RM" = "1")
124
125if test X${CLOCK_DRIVER_USE_TSC} = X1 -a X${CLOCK_DRIVER_USE_8254} = X1 ; then
126  AC_MSG_ERROR([pc386 both TSC and 8254 specified for clock driver])
127fi
128
129## The PC386 BSP supports SMP configurations if this is enabled.
130RTEMS_BSPOPTS_SET([BSP_HAS_SMP],[*],[1])
131RTEMS_BSPOPTS_HELP([BSP_HAS_SMP],
132[Always defined when on a pc386 to enable the pc386 support for
133 determining the CPU core number in an SMP configuration.])
134
135RTEMS_BSPOPTS_SET([BSP_GDB_STUB],[*],[1])
136RTEMS_BSPOPTS_HELP([BSP_GDB_STUB],
137[Defined by default. Enables use of the GDB stub for debugging via a
138 serial port.])
139AM_CONDITIONAL(BSP_GDB_STUB, test "$BSP_GDB_STUB" = "1")
140
141## if this is an i386, does gas have good code16 support?
142RTEMS_I386_GAS_CODE16
143AM_CONDITIONAL(RTEMS_GAS_CODE16,[test "$RTEMS_GAS_CODE16" = "yes"])
144
145AM_CONDITIONAL(HAS_NETWORKING,[test "$HAS_NETWORKING" = "yes"])
146AM_CONDITIONAL(HAS_SMP,[test "$rtems_cv_HAS_SMP" = "yes"])
147
148AC_SUBST([RTEMS_ROOT],[${rtems_updir}'$(top_builddir)'])
149
150RTEMS_CONFIG_BUILD_SUBDIRS(tools)
151
152AC_SUBST(RTEMS_BSP)
153
154RTEMS_BSP_CLEANUP_OPTIONS
155
156# Explicitly list all Makefiles here
157AC_CONFIG_FILES([Makefile])
158AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.