source: rtems/c/src/lib/libbsp/i386/force386/startup/linkcmds @ 5ee559ac

/*
 *  This file contains directives for the GNU linker which are specific
 *  to the FORCE CPU386 board.
 *
 *  COPYRIGHT (c) 1989-1998.
 *  On-Line Applications Research Corporation (OAR).
 *  Copyright assigned to U.S. Government, 1994.
 *
 *  The license and distribution terms for this file may be
 *  found in the file LICENSE in this distribution or at
 *  http://www.OARcorp.com/rtems/license.html.
 *
 *  $Id$
 */

MEMORY
        {
        ram : org = 0x0, l = 1M
        }

SECTIONS
{
        .text 0x0 :
        {
                _text_start = . ;
                *(.text)
                . = ALIGN (16);

                *(.eh_fram)
                . = ALIGN (16);

                /*
                * C++ constructors
                */
                __CTOR_LIST__ = .;
                LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
                *(.ctors)
                LONG(0)
                __CTOR_END__ = .;

                __DTOR_LIST__ = .;
                LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
                *(.dtors)
                LONG(0)
                __DTOR_END__ = .;
                _etext = ALIGN( 0x10 ) ;


        } >RAM

        .init           : { *(.init)            } >RAM
        .fini           : { *(.fini)            } >RAM
        .rodata         : { *(.rodata)          } >RAM

        .data :
        {
                _data_start = . ;
                *(.data)
                _edata = ALIGN( 0x10 ) ;
        } >RAM

        .bss :
        {
                _bss_start = . ;
                *(.bss)
                *(COMMON)
                end = . ;
                _end = . ;
                __end = . ;
        } >RAM
}