source: rtems/c/src/exec/score/cpu/m68k/cpu_asm.s @ c80add4

4.104.114.84.95
Last change on this file since c80add4 was c80add4, checked in by Joel Sherrill <joel.sherrill@…>, on Mar 25, 1998 at 6:46:47 PM

m68k software interrupt stack support from Chris Johns and Eric Norum.

  • Property mode set to 100644
File size: 9.6 KB
Line 
1/*  cpu_asm.s
2 *
3 *  This file contains all assembly code for the MC68020 implementation
4 *  of RTEMS.
5 *
6 *  COPYRIGHT (c) 1989-1998.
7 *  On-Line Applications Research Corporation (OAR).
8 *  Copyright assigned to U.S. Government, 1994.
9 *
10 *  The license and distribution terms for this file may be
11 *  found in the file LICENSE in this distribution or at
12 *  http://www.OARcorp.com/rtems/license.html.
13 *
14 *  $Id$
15 */
16
17
18#include <asm.h>
19
20        .text
21
22/*  void _CPU_Context_switch( run_context, heir_context )
23 *
24 *  This routine performs a normal non-FP context.
25 */
26
27        .align  4
28        .global SYM (_CPU_Context_switch)
29
30.set RUNCONTEXT_ARG,   4                   | save context argument
31.set HEIRCONTEXT_ARG,  8                   | restore context argument
32
33SYM (_CPU_Context_switch):
34          moval    a7@(RUNCONTEXT_ARG),a0| a0 = running thread context
35          movw     sr,d1                 | d1 = status register
36          movml    d1-d7/a2-a7,a0@       | save context
37
38          moval    a7@(HEIRCONTEXT_ARG),a0| a0 = heir thread context
39restore:  movml    a0@,d1-d7/a2-a7     | restore context
40          movw     d1,sr                  | restore status register
41          rts
42
43/*PAGE
44 *  void __CPU_Context_save_fp_context( &fp_context_ptr )
45 *  void __CPU_Context_restore_fp_context( &fp_context_ptr )
46 *
47 *  These routines are used to context switch a MC68881 or MC68882.
48 *
49 *  NOTE:  Context save and restore code is based upon the code shown
50 *         on page 6-38 of the MC68881/68882 Users Manual (rev 1).
51 *
52 *         CPU_FP_CONTEXT_SIZE is higher than expected to account for the
53 *         -1 pushed at end of this sequence.
54 *
55 *         Neither of these entries is required if we have software FPU
56 *         emulation.  But if we don't have an FPU or emulation, then
57 *         we need the stub versions of these routines.
58 */
59
60#if (CPU_SOFTWARE_FP == FALSE)
61
62.set FPCONTEXT_ARG,   4                    | save FP context argument
63
64        .align  4
65        .global SYM (_CPU_Context_save_fp)
66SYM (_CPU_Context_save_fp):
67#if ( M68K_HAS_FPU == 1 )
68        moval    a7@(FPCONTEXT_ARG),a1    | a1 = &ptr to context area
69        moval    a1@,a0                   | a0 = Save context area
70        fsave    a0@-                     | save 68881/68882 state frame
71        tstb     a0@                      | check for a null frame
72        beq      nosv                     | Yes, skip save of user model
73        fmovem   fp0-fp7,a0@-             | save data registers (fp0-fp7)
74        fmovem   fpc/fps/fpi,a0@-         | and save control registers
75        movl     #-1,a0@-                 | place not-null flag on stack
76nosv:   movl     a0,a1@                   | save pointer to saved context
77#endif
78        rts
79
80        .align  4
81        .global SYM (_CPU_Context_restore_fp)
82SYM (_CPU_Context_restore_fp):
83#if ( M68K_HAS_FPU == 1 )
84        moval    a7@(FPCONTEXT_ARG),a1    | a1 = &ptr to context area
85        moval    a1@,a0                   | a0 = address of saved context
86        tstb     a0@                      | Null context frame?
87        beq      norst                    | Yes, skip fp restore
88        addql    #4,a0                    | throwaway non-null flag
89        fmovem   a0@+,fpc/fps/fpi         | restore control registers
90        fmovem   a0@+,fp0-fp7             | restore data regs (fp0-fp7)
91norst:  frestore a0@+                     | restore the fp state frame
92        movl     a0,a1@                   | save pointer to saved context
93#endif
94        rts
95#endif
96
97/*PAGE
98 *  void _ISR_Handler()
99 *
100 *  This routine provides the RTEMS interrupt management.
101 *
102 *  NOTE:
103 *    Upon entry, the master stack will contain an interrupt stack frame
104 *    back to the interrupted thread and the interrupt stack will contain
105 *    a throwaway interrupt stack frame.  If dispatching is enabled, this
106 *    is the outer most interrupt, and (a context switch is necessary or
107 *    the current thread has signals), then set up the master stack to
108 *    transfer control to the interrupt dispatcher.
109 */
110
111/*
112 *  With this approach, lower priority interrupts may
113 *  execute twice if a higher priority interrupt is
114 *  acknowledged before _Thread_Dispatch_disable is
115 *  increamented and the higher priority interrupt
116 *  preforms a context switch after executing. The lower
117 *  priority intterrupt will execute (1) at the end of the
118 *  higher priority interrupt in the new context if
119 *  permitted by the new interrupt level mask, and (2) when
120 *  the original context regains the cpu.
121 */
122 
123#if ( M68K_HAS_VBR == 1)
124.set SR_OFFSET,    0                     | Status register offset
125.set PC_OFFSET,    2                     | Program Counter offset
126.set FVO_OFFSET,   6                     | Format/vector offset
127#else
128.set SR_OFFSET,    2                     | Status register offset
129.set PC_OFFSET,    4                     | Program Counter offset
130.set FVO_OFFSET,   0                     | Format/vector offset placed in the stack
131#endif /* M68K_HAS_VBR */
132 
133.set SAVED,        16                    | space for saved registers
134
135        .align  4
136        .global SYM (_ISR_Handler)
137
138SYM (_ISR_Handler):
139        addql   #1,SYM (_Thread_Dispatch_disable_level) | disable multitasking
140        moveml  d0-d1/a0-a1,a7@-         | save d0-d1,a0-a1
141        movew   a7@(SAVED+FVO_OFFSET),d0 | d0 = F/VO
142        andl    #0x0fff,d0               | d0 = vector offset in vbr
143
144
145#if ( CPU_HAS_SOFTWARE_INTERRUPT_STACK == 1 )
146        movew   sr,d1                   | Save status register
147        oriw    #0x700,sr               | Disable interrupts
148        tstl    SYM (_ISR_Nest_level)   | Interrupting an interrupt handler?
149        bne     1f                      | Yes, just skip over stack switch code
150        movel   SYM(_CPU_Interrupt_stack_high),a0       | End of interrupt stack
151        movel   a7,a0@-                 | Save task stack pointer
152        movel   a0,a7                   | Switch to interrupt stack
1531:
154        addql   #1,SYM(_ISR_Nest_level) | one nest level deeper
155        movew   d1,sr                   | Restore status register
156#else
157        addql   #1,SYM (_ISR_Nest_level) | one nest level deeper
158#endif /* CPU_HAS_SOFTWARE_INTERRUPT_STACK == 1 */
159
160#if ( M68K_HAS_PREINDEXING == 1 )
161        movel   @( SYM (_ISR_Vector_table),d0:w:1),a0| fetch the ISR
162#else
163        movel   # SYM (_ISR_Vector_table),a0   | a0 = base of RTEMS table
164        addal   d0,a0                    | a0 = address of vector
165        movel   (a0),a0                  | a0 = address of user routine
166#endif
167
168        lsrl    #2,d0                    | d0 = vector number
169        movel   d0,a7@-                  | push vector number
170        jbsr    a0@                      | invoke the user ISR
171        addql   #4,a7                    | remove vector number
172
173#if ( CPU_HAS_SOFTWARE_INTERRUPT_STACK == 1 )
174        movew   sr,d0                   | Save status register
175        oriw    #0x700,sr               | Disable interrupts
176        subql   #1,SYM(_ISR_Nest_level) | Reduce interrupt-nesting count
177        bne     1f                      | Skip if return to interrupt
178        movel   (a7),a7                 | Restore task stack pointer
1791:
180        movew   d0,sr                   | Restore status register
181#else
182        subql   #1,SYM (_ISR_Nest_level) | one less nest level
183#endif /* CPU_HAS_SOFTWARE_INTERRUPT_STACK == 1 */
184
185        subql   #1,SYM (_Thread_Dispatch_disable_level)
186                                         | unnest multitasking
187        bne     exit                     | If dispatch disabled, exit
188
189#if ( M68K_HAS_SEPARATE_STACKS == 1 )
190        movew   #0xf000,d0               | isolate format nibble
191        andw    a7@(SAVED+FVO_OFFSET),d0 | get F/VO
192        cmpiw   #0x1000,d0               | is it a throwaway isf?
193        bne     exit                     | NOT outer level, so branch
194#endif
195
196        tstl    SYM (_Context_Switch_necessary)
197                                         | Is thread switch necessary?
198        bne     bframe                   | Yes, invoke dispatcher
199
200        tstl    SYM (_ISR_Signals_to_thread_executing)
201                                         | signals sent to Run_thread
202                                         |   while in interrupt handler?
203        beq     exit                     | No, then exit
204
205
206bframe: clrl    SYM (_ISR_Signals_to_thread_executing)
207                                         | If sent, will be processed
208#if ( M68K_HAS_SEPARATE_STACKS == 1 )
209        movec   msp,a0                   | a0 = master stack pointer
210        movew   #0,a0@-                  | push format word
211        movel   # SYM (_ISR_Dispatch),a0@- | push return addr
212        | filter out the trace bit to stop single step debugging breaking
213        movew   a0@(6+SR_OFFSET),d0
214        andw    #0x7FFF,d0
215        movew   d0,a0@-                  | push thread sr
216        movec   a0,msp                   | set master stack pointer
217#else
218
219        | filter out the trace bit to stop single step debugging breaking
220        movew   a7@(16+SR_OFFSET),d0
221        andw    #0x7FFF,d0
222        movew   d0,sr
223        jsr SYM (_Thread_Dispatch)
224#endif
225
226exit:   moveml  a7@+,d0-d1/a0-a1         | restore d0-d1,a0-a1
227#if ( M68K_HAS_VBR == 0 )
228        addql   #2,a7                    | pop format/id
229#endif /* M68K_HAS_VBR */
230        rte                              | return to thread
231                                         |   OR _Isr_dispatch
232
233/*PAGE
234 *  void _ISR_Dispatch()
235 *
236 *  Entry point from the outermost interrupt service routine exit.
237 *  The current stack is the supervisor mode stack if this processor
238 *  has separate stacks.
239 *
240 *    1.  save all registers not preserved across C calls.
241 *    2.  invoke the _Thread_Dispatch routine to switch tasks
242 *        or a signal to the currently executing task.
243 *    3.  restore all registers not preserved across C calls.
244 *    4.  return from interrupt
245 */
246
247        .global SYM (_ISR_Dispatch)
248SYM (_ISR_Dispatch):
249        movml   d0-d1/a0-a1,a7@-
250        jsr     SYM (_Thread_Dispatch)
251        movml   a7@+,d0-d1/a0-a1
252#if ( M68K_HAS_VBR == 0 )
253        addql   #2,a7                    | pop format/id
254#endif /* M68K_HAS_VBR */
255        rte
Note: See TracBrowser for help on using the repository browser.