source: rtems/c/src/configure.ac @ dc17e8ed

4.104.114.84.95
Last change on this file since dc17e8ed was 85a8933, checked in by Ralf Corsepius <ralf.corsepius@…>, on 08/11/02 at 02:59:39

2002-08-11 Ralf Corsepius <corsepiu@…>

  • configure.ac: Add BSP_SUBDIRS.
  • Makefile.am: Use BSP_SUBDIRS to setup SUBDIRS.
  • Property mode set to 100644
File size: 3.5 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id$
4
5AC_PREREQ(2.52)
6AC_INIT([rtems-c-src],[_RTEMS_VERSION],[rtems-bugs@OARcorp.com])
7AC_CONFIG_SRCDIR([optman])
8RTEMS_TOP(../..)
9AC_CONFIG_AUX_DIR(../..)
10
11RTEMS_ENABLE_CXX
12RTEMS_ENABLE_NETWORKING
13RTEMS_ENABLE_RDBG
14
15RTEMS_CANONICAL_TARGET_CPU
16RTEMS_CANONICAL_HOST
17
18AM_INIT_AUTOMAKE([no-define foreign 1.6])
19AM_MAINTAINER_MODE
20
21RTEMS_PROG_CC_FOR_TARGET
22RTEMS_CANONICALIZE_TOOLS
23
24RTEMS_ENABLE_MULTILIB
25RTEMS_ENABLE_MULTIPROCESSING
26RTEMS_ENV_RTEMSBSP
27RTEMS_CHECK_CPU
28RTEMS_CHECK_CUSTOM_BSP(RTEMS_BSP)
29
30RTEMS_CHECK_NETWORKING(RTEMS_BSP)
31
32AC_MSG_NOTICE([setting up make/custom])
33
34AS_MKDIR_P([make/custom])
35
36# Collect and copy the BSP's make/custom/*.cfg files from the toplevel make
37# directory into the build tree's <bsp>/make/custom subdirectories
38cfg_dir="${RTEMS_TOPdir}/make"
39CUSTOM_CFG_FILES=""
40f="${RTEMS_BSP}.cfg"
41while test -n "$f"; do
42  if test -r "${srcdir}/${cfg_dir}/custom/$f"; then
43    cp ${srcdir}/${cfg_dir}/custom/$f make/custom/$f
44    CUSTOM_CFG_FILES="$CUSTOM_CFG_FILES make/custom/$f"
45    f=`grep "^include.*make/custom" ${srcdir}/${cfg_dir}/custom/$f \
46    | sed \
47      -e 's%^.*custom\/%%' \
48      -e s%\$\(RTEMS_HOST\)%${RTEMS_HOST}% \
49      -e 's%default\.cfg%%'`;
50  else break; fi;
51done
52cp ${srcdir}/make/custom/default.cfg.in make/custom/default.cfg
53
54AC_MSG_NOTICE([creating make/${RTEMS_BSP}.cache])
55${MAKE-make} -f ${srcdir}/make/bsp.mak \
56RTEMS_BSP=${RTEMS_BSP} \
57BARE_CPU_MODEL=${BARE_CPU_MODEL} \
58RTEMS_ROOT=. make/${RTEMS_BSP}.cache
59
60# Read back the cache
61RTEMS_CHECK_BSP_CACHE(RTEMS_BSP)
62
63AC_SUBST(CUSTOM_CFG_FILES)
64AC_SUBST(cfg_dir)
65
66## Configure ${srcdir}/../../cpukit as exec/ if multilibs are enabled
67AS_IF([test x"$multilib" = x"no"],[
68  RTEMS_CHECK_MULTIPROCESSING
69  RTEMS_CONFIG_SUBDIR([exec],[../../cpukit],
70  [--with-project-root="../../" --enable-rtemsbsp=$RTEMS_BSP
71  ])
72  BSP_SUBDIRS="exec"
73])
74
75## Note: the order of the directories below is essential
76AC_CONFIG_SUBDIRS([make])
77BSP_SUBDIRS="$BSP_SUBDIRS make"
78AC_CONFIG_SUBDIRS([optman])
79BSP_SUBDIRS="$BSP_SUBDIRS optman"
80AC_CONFIG_SUBDIRS([lib/libcpu])
81BSP_SUBDIRS="$BSP_SUBDIRS lib/libcpu"
82AC_CONFIG_SUBDIRS([lib/libbsp])
83BSP_SUBDIRS="$BSP_SUBDIRS lib/libbsp"
84AC_CONFIG_SUBDIRS([libmisc])
85BSP_SUBDIRS="$BSP_SUBDIRS libmisc"
86
87AS_IF([test "$RTEMS_CPU" != "unix"],[
88## HACK: Suppress libchip for unix
89  AC_CONFIG_SUBDIRS([libchip])
90  BSP_SUBDIRS="$BSP_SUBDIRS libchip"
91])
92
93AS_IF([test "$HAS_NETWORKING" = "yes"],[
94  AC_CONFIG_SUBDIRS(libnetworking)
95  BSP_SUBDIRS="$BSP_SUBDIRS libnetworking"
96  AS_IF([test "$RTEMS_HAS_RDBG" = "yes"],[
97    RTEMS_CHECK_RDBG(RTEMS_BSP)
98  ])
99])
100
101AS_IF([test "$HAS_RDBG" = "yes"],[
102  AC_CONFIG_SUBDIRS([librdbg])
103  BSP_SUBDIRS="$BSP_SUBDIRS librdbg"
104])
105
106AS_IF([test "$RTEMS_HAS_CPLUSPLUS" = "yes"],[
107  AC_CONFIG_SUBDIRS([librtems++])
108  BSP_SUBDIRS="$BSP_SUBDIRS librtems++"
109])
110
111BSP_SUBDIRS="$BSP_SUBDIRS wrapup"
112AC_CONFIG_SUBDIRS([tests])
113BSP_SUBDIRS="$BSP_SUBDIRS tests"
114
115AC_SUBST([BSP_SUBDIRS],[$BSP_SUBDIRS])
116
117AM_CONDITIONAL(HAS_NETWORKING, test "$HAS_NETWORKING" = "yes" )
118AM_CONDITIONAL(HAS_RDBG, test "$HAS_RDBG" = "yes" )
119
120# The bare bsp doesn't have libbsp.a
121# FIXME: We should use a feature based check, here
122AM_CONDITIONAL([HAS_LIBBSP],[! test "$RTEMS_BSP_FAMILY" = "bare"])
123AM_CONDITIONAL([MULTILIB],[test x"${enable_multilib}" = x"yes"])
124
125RTEMS_PROJECT_ROOT
126
127# Explicitly list all Makefiles here
128AC_CONFIG_FILES([Makefile],
129[${MAKE} make/${RTEMS_BSP}.cache],
130[RTEMS_BSP=${RTEMS_BSP}
131 MAKE=${MAKE}])
132
133AC_CONFIG_FILES([wrapup/Makefile])
134
135AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.