source: rtems/c/src/configure.ac @ 382e1eb3

4.104.114.84.95
Last change on this file since 382e1eb3 was 382e1eb3, checked in by Ralf Corsepius <ralf.corsepius@…>, on Dec 6, 2002 at 4:44:40 AM

2002-12-06 Ralf Corsepius <corsepiu@…>

  • configure.ac: Append CPU_CFLAGS, CFLAGS_OPTIMIZE_V, CFLAGS_DEBUG_V, CFLAGS_PROFILE_V, RTEMS_BSP_FAMILY to ac_configure_args.
  • Property mode set to 100644
File size: 4.6 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id$
4
5AC_PREREQ(2.52)
6AC_INIT([rtems-c-src],[_RTEMS_VERSION],[rtems-bugs@OARcorp.com])
7AC_CONFIG_SRCDIR([optman])
8RTEMS_TOP(../..)
9AC_CONFIG_AUX_DIR(../..)
10
11RTEMS_ENABLE_CXX
12RTEMS_ENABLE_NETWORKING
13RTEMS_ENABLE_RDBG
14
15RTEMS_CANONICAL_TARGET_CPU
16RTEMS_CANONICAL_HOST
17
18AM_INIT_AUTOMAKE([no-define foreign 1.6])
19AM_MAINTAINER_MODE
20
21RTEMS_PROG_CC_FOR_TARGET
22RTEMS_CANONICALIZE_TOOLS
23
24RTEMS_ENABLE_MULTILIB
25RTEMS_ENABLE_MULTIPROCESSING
26RTEMS_ENV_RTEMSBSP
27RTEMS_CHECK_CPU
28RTEMS_CHECK_CUSTOM_BSP(RTEMS_BSP)
29
30RTEMS_CHECK_NETWORKING(RTEMS_BSP)
31
32AC_MSG_NOTICE([setting up make/custom])
33
34AS_MKDIR_P([make/custom])
35
36# Collect and copy the BSP's make/custom/*.cfg files from the toplevel make
37# directory into the build tree's <bsp>/make/custom subdirectories
38cfg_dir="${RTEMS_TOPdir}/make"
39CUSTOM_CFG_FILES=""
40f="${RTEMS_BSP}.cfg"
41while test -n "$f"; do
42  if test -r "${srcdir}/${cfg_dir}/custom/$f"; then
43    cp ${srcdir}/${cfg_dir}/custom/$f make/custom/$f
44    CUSTOM_CFG_FILES="$CUSTOM_CFG_FILES make/custom/$f"
45    f=`grep "^include.*make/custom" ${srcdir}/${cfg_dir}/custom/$f \
46    | sed \
47      -e 's%^.*custom\/%%' \
48      -e s%\$\(RTEMS_HOST\)%${RTEMS_HOST}% \
49      -e 's%default\.cfg%%'`;
50  else break; fi;
51done
52cp ${srcdir}/make/custom/default.cfg.in make/custom/default.cfg
53
54AC_MSG_NOTICE([creating make/${RTEMS_BSP}.cache])
55${MAKE-make} -f ${srcdir}/make/bsp.mak \
56RTEMS_BSP=${RTEMS_BSP} \
57RTEMS_HOST=${RTEMS_HOST} \
58BARE_CPU_MODEL=${BARE_CPU_MODEL} \
59RTEMS_ROOT=. make/${RTEMS_BSP}.cache
60
61# Read back the cache
62RTEMS_CHECK_BSP_CACHE(RTEMS_BSP)
63
64test -n "${RTEMS_BSP_CFLAGS}" && \
65  ac_configure_args="$ac_configure_args 'CPU_CFLAGS=${RTEMS_BSP_CFLAGS}'"
66test -n "{RTEMS_BSP_CFLAGS_OPTIMIZE_V}" && \
67  ac_configure_args="$ac_configure_args 'CFLAGS_OPTIMIZE_V=${RTEMS_BSP_CFLAGS_OPTIMIZE_V}'"
68test -n "${RTEMS_BSP_CFLAGS_DEBUG_V}" && \
69  ac_configure_args="$ac_configure_args 'CFLAGS_DEBUG_V=${RTEMS_BSP_CFLAGS_DEBUG_V}'"
70test -n "${RTEMS_BSP_CFLAGS_PROFILE_V}" && \
71  ac_configure_args="$ac_configure_args 'CFLAGS_PROFILE_V=${RTEMS_BSP_CFLAGS_PROFILE_V}'"
72test -n "${RTEMS_BSP_FAMILY}" && \
73  ac_configure_args="$ac_configure_args 'RTEMS_BSP_FAMILY=${RTEMS_BSP_FAMILY}'"
74
75AC_SUBST(CUSTOM_CFG_FILES)
76AC_SUBST(cfg_dir)
77
78## Configure ${srcdir}/../../cpukit as exec/ if multilibs are disabled
79AS_IF([test x"$multilib" = x"no"],[
80  RTEMS_CHECK_MULTIPROCESSING
81  RTEMS_CONFIG_SUBDIR([exec],[../../cpukit],
82  ['--with-project-root=../../' '--enable-rtemsbsp=$RTEMS_BSP'
83  ])
84  BSP_SUBDIRS="exec"
85])
86
87## Note: the order of the directories below is essential
88AC_CONFIG_SUBDIRS([make])
89BSP_SUBDIRS="$BSP_SUBDIRS make"
90AC_CONFIG_SUBDIRS([optman])
91BSP_SUBDIRS="$BSP_SUBDIRS optman"
92AC_CONFIG_SUBDIRS([lib/libcpu])
93BSP_SUBDIRS="$BSP_SUBDIRS lib/libcpu"
94AC_CONFIG_SUBDIRS([lib/libbsp])
95BSP_SUBDIRS="$BSP_SUBDIRS lib/libbsp"
96AC_CONFIG_SUBDIRS([libmisc])
97BSP_SUBDIRS="$BSP_SUBDIRS libmisc"
98
99AS_IF([test "$RTEMS_CPU" != "unix"],[
100## HACK: Suppress libchip for unix
101  AC_CONFIG_SUBDIRS([libchip])
102  BSP_SUBDIRS="$BSP_SUBDIRS libchip"
103])
104
105AS_IF([test "$HAS_NETWORKING" = "yes"],[
106  AC_CONFIG_SUBDIRS(libnetworking)
107  BSP_SUBDIRS="$BSP_SUBDIRS libnetworking"
108  AS_IF([test "$RTEMS_HAS_RDBG" = "yes"],[
109    RTEMS_CHECK_RDBG(RTEMS_BSP)
110  ])
111])
112
113AS_IF([test "$HAS_RDBG" = "yes"],[
114  AC_CONFIG_SUBDIRS([librdbg])
115  BSP_SUBDIRS="$BSP_SUBDIRS librdbg"
116])
117
118AS_IF([test "$RTEMS_HAS_CPLUSPLUS" = "yes"],[
119  AC_CONFIG_SUBDIRS([librtems++])
120  BSP_SUBDIRS="$BSP_SUBDIRS librtems++"
121])
122
123BSP_SUBDIRS="$BSP_SUBDIRS wrapup"
124
125AC_ARG_ENABLE([ada],
126[AC_HELP_STRING([--enable-ada],[enable ada support])],
127[case "${enable_ada}" in
128  yes) ;;
129  no) ;;
130  *)  AC_MSG_ERROR(bad value ${enable_ada} for --enable-ada) ;;
131esac],[enable_ada=no])
132
133AS_IF([test x"$enable_ada" = x"yes"],[
134  AS_IF([test -d ${srcdir}/ada-tests],[
135    AC_CONFIG_SUBDIRS([ada-tests])
136    BSP_SUBDIRS="$BSP_SUBDIRS ada-tests"
137  ])
138])
139
140AC_CONFIG_SUBDIRS([tests])
141BSP_SUBDIRS="$BSP_SUBDIRS tests"
142
143AC_SUBST([BSP_SUBDIRS],[$BSP_SUBDIRS])
144
145AM_CONDITIONAL([HAS_NETWORKING],[test "$HAS_NETWORKING" = "yes"])
146AM_CONDITIONAL([HAS_RDBG],[test "$HAS_RDBG" = "yes"])
147
148# The posix bsp doesn't support libchip
149# FIXME: We should use a feature based check, here
150AM_CONDITIONAL([LIBCHIP],[test "$RTEMS_BSP_FAMILY" != "posix"])
151
152# The bare bsp doesn't have libbsp.a
153# FIXME: We should use a feature based check, here
154AM_CONDITIONAL([HAS_LIBBSP],[test "$RTEMS_BSP_FAMILY" != "bare"])
155AM_CONDITIONAL([MULTILIB],[test x"${enable_multilib}" = x"yes"])
156
157RTEMS_PROJECT_ROOT
158
159# Explicitly list all Makefiles here
160AC_CONFIG_FILES([Makefile],
161[${MAKE} make/${RTEMS_BSP}.cache],
162[RTEMS_BSP=${RTEMS_BSP}
163 MAKE=${MAKE}])
164
165AC_CONFIG_FILES([wrapup/Makefile])
166
167AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.