source: rtems/c/src/aclocal/rtems-top.m4 @ 6963854d

4.115
Last change on this file since 6963854d was 6963854d, checked in by Ralf Corsépius <ralf.corsepius@…>, on 05/18/12 at 05:47:52

Remove references to configure.in.

  • Property mode set to 100644
File size: 1009 bytes
Line 
1# AC_DISABLE_OPTION_CHECKING is not available before 2.62
2AC_PREREQ(2.62)
3
4dnl
5dnl RTEMS_TOP($1)
6dnl
7dnl $1 .. relative path from this configure.ac to the toplevel configure.ac
8dnl
9AC_DEFUN([RTEMS_TOP],
10[dnl
11AC_REQUIRE([RTEMS_VERSIONING])
12AC_REQUIRE([AC_DISABLE_OPTION_CHECKING])
13AC_REQUIRE([AM_SET_LEADING_DOT])
14AC_CONFIG_AUX_DIR([$1])
15AC_CHECK_PROGS(MAKE, gmake make)
16AC_BEFORE([$0], [AM_INIT_AUTOMAKE])dnl
17
18AC_PREFIX_DEFAULT([/opt/rtems-][_RTEMS_API])
19
20AC_SUBST([RTEMS_TOPdir],["$1"])
21
22# HACK: The sed pattern in rtems_updir matches c/src/
23rtems_updir=m4_if([$2],[],[`echo "$1/" | sed 's,^\.\.\/\.\.\/,,'`],[$2/])
24
25AS_IF([test -n "${with_target_subdir}"],
26  [project_top="../${with_project_top}"],
27  [project_top="${with_project_top}"])
28AC_SUBST([PROJECT_TOPdir],[${project_top}${rtems_updir}'$(top_builddir)'])
29
30AC_SUBST([PROJECT_ROOT],[${with_project_root}${rtems_updir}'$(top_builddir)'])
31
32AC_SUBST([dirstamp],[\${am__leading_dot}dirstamp])
33AC_SUBST([pkgdatadir],["\${datadir}"/rtems]_RTEMS_API)
34])dnl
Note: See TracBrowser for help on using the repository browser.