source: rtems/c/src/aclocal/prog-cc.m4 @ 4778c6e0

4.11
Last change on this file since 4778c6e0 was 05eb1fb, checked in by Ralf Corsepius <ralf.corsepius@…>, on Oct 23, 2009 at 2:57:58 PM

Remove RTEMS_CFLAGS.

  • Property mode set to 100644
File size: 1.1 KB
Line 
1dnl
2dnl $Id$
3dnl
4dnl Check for target gcc
5dnl
6
7AC_DEFUN([RTEMS_PROG_CC],
8[
9AC_BEFORE([$0], [AC_PROG_CPP])dnl
10AC_BEFORE([$0], [AC_PROG_CC])dnl
11AC_BEFORE([$0], [RTEMS_CANONICALIZE_TOOLS])dnl
12
13RTEMS_CHECK_TOOL(CC,gcc)
14test -z "$CC" && \
15  AC_MSG_ERROR([no acceptable cc found in \$PATH])
16AC_PROG_CC
17AC_PROG_CPP
18])
19
20AC_DEFUN([RTEMS_PROG_CC_FOR_TARGET],
21[
22dnl check target cc
23RTEMS_PROG_CC
24dnl check if the compiler supports -isystem
25RTEMS_GCC_ISYSTEM
26dnl check if the target compiler may use --pipe
27RTEMS_GCC_PIPE
28test "$rtems_cv_gcc_pipe" = "yes" && CC="$CC --pipe"
29
30dnl check if the compiler supports --specs
31RTEMS_GCC_SPECS
32
33AS_IF([test x"$rtems_cv_gcc_specs" = xyes],[
34GCCSPECS="-B\$(PROJECT_ROOT)/lib/ -B\$(PROJECT_ROOT)/$RTEMS_BSP/lib/"
35GCCSPECS="${GCCSPECS} -specs bsp_specs -qrtems"])
36AC_SUBST(GCCSPECS)
37
38AS_IF([test x"$rtems_cv_gcc_isystem" = xyes],[
39  RTEMS_CPPFLAGS="-isystem \$(PROJECT_INCLUDE)"],[
40  RTEMS_CPPFLAGS="-I\$(PROJECT_INCLUDE)"
41])
42AC_SUBST(RTEMS_CPPFLAGS)
43
44AS_IF([test "$GCC" = yes],[
45  RTEMS_RELLDFLAGS="-qnolinkcmds -nostdlib -r"
46])
47AC_SUBST(RTEMS_RELLDFLAGS)
48])
Note: See TracBrowser for help on using the repository browser.