source: rtems/bsps/powerpc/virtex4/start/linkcmds @ ec1dd51a

5
Last change on this file since ec1dd51a was ec1dd51a, checked in by Chris Johns <chrisj@…>, on 03/06/19 at 10:15:56

libdl: Add small data support to the remaining PowerPC BSPs.

Updates #3687
  • Property mode set to 100644
File size: 11.0 KB
Line 
1/*
2 *  This file contains directives for the GNU linker which are specific to the
3 *  Virtex 4 PPC 405.  No assumptions are made on the firmware in the FPGA.
4 *  This file is intended to be used together with start.S to generate
5 *  downloadable code.
6 */
7
8OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
9OUTPUT_ARCH(powerpc)
10
11STARTUP(start.o)
12ENTRY(download_entry)
13EXTERN(download_entry)
14EXTERN(__vectors)
15
16MsgAreaSize       = DEFINED(MsgAreaSize)   ? MsgAreaSize   : 1M;
17RamBase           = DEFINED(RamBase)       ? RamBase       : 0x0;
18RamSize           = DEFINED(RamSize)       ? RamSize       : 128M - MsgAreaSize;
19HeapSize          = DEFINED(HeapSize)      ? HeapSize      : 0; /* 0=Use def */
20
21
22MEMORY
23{
24  VECTORS         : ORIGIN = 0x00000000, LENGTH = 12K
25  RAM             : ORIGIN = 0x00003000, LENGTH = 128M - 12K
26}
27
28
29SECTIONS
30{
31  bsp_exc_vector_base = 0x100;
32  __exeentry          = download_entry;
33  __exestart          = bsp_exc_vector_base;
34  .vectors bsp_exc_vector_base : { *(.vectors)                  } > VECTORS
35
36  /* Read-only sections, merged into text segment: */
37  .interp         : { *(.interp)                                } > RAM
38  .hash           : { *(.hash)                                  } > RAM
39  .dynsym         : { *(.dynsym)                                } > RAM
40  .dynstr         : { *(.dynstr)                                } > RAM
41  .gnu.version    : { *(.gnu.version)                           } > RAM
42  .gnu.version_d  : { *(.gnu.version_d)                         } > RAM
43  .gnu.version_r  : { *(.gnu.version_r)                         } > RAM
44  .rela.text      : { *(.rela.text) *(.rela.gnu.linkonce.t*)    } > RAM
45  .rela.data      : { *(.rela.data) *(.rela.gnu.linkonce.d*)    } > RAM
46  .rela.rodata    : { *(.rela.rodata*) *(.rela.gnu.linkonce.r*) } > RAM
47  .rela.got       : { *(.rela.got)                              } > RAM
48  .rela.got1      : { *(.rela.got1)                             } > RAM
49  .rela.got2      : { *(.rela.got2)                             } > RAM
50  .rela.ctors     : { *(.rela.ctors)                            } > RAM
51  .rela.dtors     : { *(.rela.dtors)                            } > RAM
52  .rela.init      : { *(.rela.init)                             } > RAM
53  .rela.fini      : { *(.rela.fini)                             } > RAM
54  .rela.bss       : { *(.rela.bss)                              } > RAM
55  .rela.plt       : { *(.rela.plt)                              } > RAM
56  .rela.sdata     : { *(.rela.sdata)                            } > RAM
57  .rela.sbss      : { *(.rela.sbss)                             } > RAM
58  .rela.sdata2    : { *(.rela.sdata2)                           } > RAM
59  .rela.sbss2     : { *(.rela.sbss2)                            } > RAM
60  .rela.dyn       : { *(.rela.dyn)                              } > RAM
61
62  /* Initialization code */
63  .init           : { PROVIDE (_init = .);
64                      *ecrti.o(.init)
65                      KEEP(*(.init))
66                      *ecrtn.o(.init)
67                    } > RAM
68
69  .text           : { *(.entry)
70                      *(.text)
71                      *(.text.*)
72
73                      /* Special FreeBSD sysctl sections */
74                      . = ALIGN (16);
75                      __start_set_sysctl_set = .;
76                      *(set_sysctl_*);
77                      __stop_set_sysctl_set = ABSOLUTE(.);
78                      *(set_domain_*);
79                      *(set_pseudo_*);
80
81                      /* .gnu.warning sections are handled specially by elf32.em
82                       */
83                      *(.gnu.warning)
84                      *(.gnu.linkonce.t*)
85                    } > RAM
86
87  /* Finalization code */
88  .fini           : { PROVIDE (_fini = .);
89                      *ecrti.o(.fini)
90                      KEEP(*(.fini))
91                      *ecrtn.o(.fini)
92                    } > RAM
93
94  /* Miscellaneous read-only data */
95  .rodata         : { *(.rodata.* .gnu.linkonce.r*) KEEP (*(SORT(.rtemsroset.*))) } > RAM
96  .rodata1        : { *(.rodata1)                                      } > RAM
97
98  .tdata : {
99    _TLS_Data_begin = .;
100    *(.tdata .tdata.* .gnu.linkonce.td.*)
101    _TLS_Data_end = .;
102  } >RAM
103
104  .tbss : {
105    _TLS_BSS_begin = .;
106    *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon)
107    _TLS_BSS_end = .;
108  } >RAM
109
110  _TLS_Data_size = _TLS_Data_end - _TLS_Data_begin;
111  _TLS_Data_begin = _TLS_Data_size != 0 ? _TLS_Data_begin : _TLS_BSS_begin;
112  _TLS_Data_end = _TLS_Data_size != 0 ? _TLS_Data_end : _TLS_BSS_begin;
113  _TLS_BSS_size = _TLS_BSS_end - _TLS_BSS_begin;
114  _TLS_Size = _TLS_BSS_end - _TLS_Data_begin;
115  _TLS_Alignment = MAX (ALIGNOF (.tdata), ALIGNOF (.tbss));
116
117  /* Initialised small data addressed as offsets from r2 */
118  .sdata2         : { PROVIDE (_SDA2_BASE_ = 32768); *(.sdata2 .sdata2.* .gnu.linkonce.s2.*)          } > RAM
119
120  /* Zeroed small data addressed as offsets from r2 */
121  .sbss2          : { *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*)
122
123                      /* Avoid empty sdata2/sbss2 area: __eabi would not set up
124                       * r2 which may be important if run-time loading is used
125                       */
126                      . += 1;
127
128                      PROVIDE (__SBSS2_END__ = .);
129                    } > RAM
130
131  /* Exception frame info */
132  .eh_frame       : { *(.eh_frame .eh_frame.*)                         } > RAM
133  .eh_frame_hdr   : { *(.eh_frame_hdr)                                 } > RAM
134
135  /*  Declares where the .text section ends */
136  _etext          = .;
137  PROVIDE (etext  = .);
138
139  /* Initialized R/W Data section goes in RAM */
140  .data           : { PROVIDE(__DATA_START__ = ABSOLUTE(.) );
141                      *(.data)
142                      *(.data.*)
143                      KEEP (*(SORT(.rtemsrwset.*)))
144                      *(.gnu.linkonce.d*)
145                    } > RAM
146
147  .data1          : { *(.data1)                                        } > RAM
148
149                        PROVIDE (__EXCEPT_START__ = .);
150  .gcc_except_table : { *(.gcc_except_table .gcc_except_table.*)       } > RAM
151                        PROVIDE (__EXCEPT_END__ = .);
152
153  .got1           : { *(.got1)                                         } > RAM
154
155  /* Put .ctors and .dtors next to the .got2 section, so that the pointers
156   * get relocated with -mrelocatable. Also put in the .fixup pointers.
157   * The current compiler no longer needs this, but keep it around for 2.7.2.
158   */
159                      PROVIDE (_GOT2_START_ = .);
160  .got2           : { *(.got2)                                         } > RAM
161
162  .dynamic        : { *(.dynamic)                                      } > RAM
163
164  .ctors          : { /* gcc uses crtbegin.o to find the start of
165                       * the constructors, so we make sure it is
166                       * first.  Because this is a wildcard, it
167                       * doesn't matter if the user does not
168                       * actually link against crtbegin.o; the
169                       * linker won't look for a file to match a
170                       * wildcard.  The wildcard also means that it
171                       * doesn't matter which directory crtbegin.o
172                       * is in.
173                       */
174                      KEEP (*crtbegin.o(.ctors))
175                      /* We don't want to include the .ctor section from
176                       * the crtend.o file until after the sorted ctors.
177                       * The .ctor section from the crtend file contains the
178                       * end of ctors marker and it must be last.
179                       */
180                      KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
181                      KEEP (*(SORT(.ctors.*)))
182                      KEEP (*(.ctors))
183                    } > RAM
184
185  .dtors          : { KEEP (*crtbegin.o(.dtors))
186                      KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
187                      KEEP (*(SORT(.dtors.*)))
188                      KEEP (*(.dtors))
189                    } > RAM
190
191                      PROVIDE (_FIXUP_START_ = .);
192  .fixup          : { *(.fixup)                                        } > RAM
193                      PROVIDE (_FIXUP_END_ = .);
194
195                      PROVIDE (_GOT2_END_ = .);
196
197                      PROVIDE (_GOT_START_ = .);
198  .got            : { __got_start = .;
199                      *(.got)
200                    } > RAM
201
202  .got.plt        : { *(.got.plt)                                      } > RAM
203                      PROVIDE (_GOT_END_ = .);
204
205  .jcr            : { KEEP (*(.jcr))                                   } > RAM
206
207  /* We want the small data sections together, so single-instruction offsets
208   * can access them all, and initialized data all before uninitialized, so
209   * we can shorten the on-disk segment size.
210   */
211  /* Initialised small data addressed as offsets from r13 */
212  .sdata          : {
213        bsp_section_sdata_begin = .;
214        PROVIDE (_SDA_BASE_ = 32768); *(.sdata* .gnu.linkonce.s.*);
215        bsp_section_sdata_end = .;
216   } > RAM
217
218  _edata          = .;
219  PROVIDE (edata  = .);
220
221  /* Zeroed small data addressed as offsets from r13 */
222  .sbss           : { PROVIDE (__sbss_start = .);
223                      bsp_section_sbss_begin = .;
224                      *(.dynsbss)
225                      *(.sbss*)
226                      *(.gnu.linkonce.sb.*)
227                      *(.scommon)
228
229                      /* Avoid empty sdata/sbss area: __eabi would not set up
230                       * r13, which may be important if run-time loading is used
231                       */
232                      . += 1;
233
234                      PROVIDE (__SBSS_END__ = .);
235                      PROVIDE (__sbss_end   = .);
236                      bsp_section_sbss_end = .;
237                      bsp_section_sdata_libdl_begin = .;
238                      . = DEFINED(bsp_section_small_data_area_size) ?
239                        bsp_section_sdata_begin + bsp_section_small_data_area_size : .;
240                      bsp_section_sdata_libdl_end = .;
241                    } > RAM
242
243  .plt            : { *(.plt)                                          } > RAM
244  .iplt           : { *(.iplt)                                         } > RAM
245
246  /* Zeroed large data */
247  .bss            : { PROVIDE (__bss_start = .);
248                      *(.dynbss)
249                      *(.bss)
250                      *(.bss.*)
251                      *(.gnu.linkonce.b*)
252                      *(COMMON)
253
254                      PROVIDE (__bss_end = ALIGN(4));
255                      __bss_size = __bss_end - __bss_start;
256                    } > RAM
257
258  __exeend        = ALIGN(4);
259  __rtems_end     = .;
260  .               = ALIGN(0x10);        /* Align to a cache-line boundary */
261  PROVIDE(__bsp_ram_start = .);
262
263  .rtemsstack (NOLOAD) : {
264    *(SORT(.rtemsstack.*))
265  } >RAM
266
267  WorkAreaBase = .;
268
269  /* The heap comes after the work space */
270
271   .              = RamBase + RamSize;
272  PROVIDE(__bsp_ram_end = .);
273
274  /* Message area for capturing early printk output */
275  /* Placed here to be easily findable with a debugger */
276  MsgAreaBase     = .;
277  .              += MsgAreaSize;
278
279  __phy_ram_end   = .;                  /* True end of physical memory */
280
281  /DISCARD/ :
282  {
283    *(.comment)
284  }
285
286  /* Some configuration constants: Not clear why they're placed here */
287  __dccr          = 0x80000000;
288  __iccr          = 0x80000000;
289  __sgr           = 0x7fffffff;
290  __vectors       = 0;
291}
Note: See TracBrowser for help on using the repository browser.