source: rtems/bsps/arm/shared/start/linkcmds.base @ 33c12d5

Last change on this file since 33c12d5 was 33c12d5, checked in by Sebastian Huber <sebastian.huber@…>, on 01/25/21 at 10:19:21

bsps: Support DWARF 5 sections

GCC 11 uses DWARF 5 by default.
  • Property mode set to 100644
File size: 16.1 KB
Line 
1/**
2 * @file
3 *
4 * @ingroup bsp_linker
5 *
6 * @brief Linker command base file.
7 */
8
9/*
10 * Copyright (c) 2008, 2016 embedded brains GmbH.  All rights reserved.
11 *
12 *  embedded brains GmbH
13 *  Dornierstr. 4
14 *  82178 Puchheim
15 *  Germany
16 *  <rtems@embedded-brains.de>
17 *
18 * The license and distribution terms for this file may be
19 * found in the file LICENSE in this distribution or at
20 * http://www.rtems.org/license/LICENSE.
21 */
22
23OUTPUT_FORMAT ("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
24
25OUTPUT_ARCH (arm)
26
27ENTRY (_start)
28STARTUP (start.o)
29
30/*
31 * Global symbols that may be defined externally
32 */
33
34bsp_vector_table_size = DEFINED (bsp_vector_table_size) ? bsp_vector_table_size : 64;
35
36bsp_section_xbarrier_align = DEFINED (bsp_section_xbarrier_align) ? bsp_section_xbarrier_align : 1;
37bsp_section_robarrier_align = DEFINED (bsp_section_robarrier_align) ? bsp_section_robarrier_align : 1;
38bsp_section_rwbarrier_align = DEFINED (bsp_section_rwbarrier_align) ? bsp_section_rwbarrier_align : 1;
39
40bsp_stack_align = DEFINED (bsp_stack_align) ? bsp_stack_align : 8;
41
42bsp_stack_abt_size = DEFINED (bsp_stack_abt_size) ? bsp_stack_abt_size : 0;
43bsp_stack_abt_size = ALIGN (bsp_stack_abt_size, bsp_stack_align);
44
45bsp_stack_fiq_size = DEFINED (bsp_stack_fiq_size) ? bsp_stack_fiq_size : 0;
46bsp_stack_fiq_size = ALIGN (bsp_stack_fiq_size, bsp_stack_align);
47
48bsp_stack_und_size = DEFINED (bsp_stack_und_size) ? bsp_stack_und_size : 0;
49bsp_stack_und_size = ALIGN (bsp_stack_und_size, bsp_stack_align);
50
51bsp_stack_hyp_size = DEFINED (bsp_stack_hyp_size) ? bsp_stack_hyp_size : 0;
52bsp_stack_hyp_size = ALIGN (bsp_stack_hyp_size, bsp_stack_align);
53
54MEMORY {
55        UNEXPECTED_SECTIONS : ORIGIN = 0xffffffff, LENGTH = 0
56}
57
58SECTIONS {
59        .start : ALIGN_WITH_INPUT {
60                bsp_section_start_begin = .;
61                KEEP (*(.bsp_start_text))
62                KEEP (*(.bsp_start_data))
63                bsp_section_start_end = .;
64        } > REGION_START AT > REGION_START
65        bsp_section_start_size = bsp_section_start_end - bsp_section_start_begin;
66
67        .xbarrier : ALIGN_WITH_INPUT {
68                . = ALIGN (bsp_section_xbarrier_align);
69        } > REGION_VECTOR AT > REGION_VECTOR
70
71        .text : ALIGN_WITH_INPUT {
72                bsp_section_text_begin = .;
73                *(.text.unlikely .text.*_unlikely)
74                *(.text .stub .text.* .gnu.linkonce.t.*)
75                /* .gnu.warning sections are handled specially by elf32.em.  */
76                *(.gnu.warning)
77                *(.glue_7t) *(.glue_7) *(.vfp11_veneer) *(.v4_bx)
78        } > REGION_TEXT AT > REGION_TEXT_LOAD
79        .init : ALIGN_WITH_INPUT {
80                KEEP (*(.init))
81        } > REGION_TEXT AT > REGION_TEXT_LOAD
82        .fini : ALIGN_WITH_INPUT {
83                KEEP (*(.fini))
84
85                /*
86                 * If requested, align the size of the combined start and text
87                 * section to the next power of two to meet MPU region
88                 * alignment requirements.
89                 */
90                . = DEFINED (bsp_align_text_and_rodata_end_to_power_of_2) ?
91                    bsp_section_start_begin
92                    + ALIGN (. - bsp_section_start_begin,
93                    1 << LOG2CEIL (. - bsp_section_start_begin)) : .;
94
95                bsp_section_text_end = .;
96        } > REGION_TEXT AT > REGION_TEXT_LOAD
97        bsp_section_text_size = bsp_section_text_end - bsp_section_text_begin;
98        bsp_section_text_load_begin = LOADADDR (.text);
99        bsp_section_text_load_end = bsp_section_text_load_begin + bsp_section_text_size;
100
101        .robarrier : ALIGN_WITH_INPUT {
102                . = ALIGN (bsp_section_robarrier_align);
103        } > REGION_RODATA AT > REGION_RODATA
104
105        .rodata : ALIGN_WITH_INPUT {
106                bsp_section_rodata_begin = .;
107                *(.rodata .rodata.* .gnu.linkonce.r.*)
108        } > REGION_RODATA AT > REGION_RODATA_LOAD
109        .rodata1 : ALIGN_WITH_INPUT {
110                *(.rodata1)
111        } > REGION_RODATA AT > REGION_RODATA_LOAD
112        .ARM.extab : ALIGN_WITH_INPUT {
113                *(.ARM.extab* .gnu.linkonce.armextab.*)
114        } > REGION_RODATA AT > REGION_RODATA_LOAD
115        .ARM.exidx : ALIGN_WITH_INPUT {
116                __exidx_start = .;
117                *(.ARM.exidx* .gnu.linkonce.armexidx.*)
118                __exidx_end = .;
119        } > REGION_RODATA AT > REGION_RODATA_LOAD
120        .eh_frame : ALIGN_WITH_INPUT {
121                KEEP (*(.eh_frame))
122        } > REGION_RODATA AT > REGION_RODATA_LOAD
123        .gcc_except_table : ALIGN_WITH_INPUT {
124                *(.gcc_except_table .gcc_except_table.*)
125        } > REGION_RODATA AT > REGION_RODATA_LOAD
126        .tdata : ALIGN_WITH_INPUT {
127                _TLS_Data_begin = .;
128                *(.tdata .tdata.* .gnu.linkonce.td.*)
129                _TLS_Data_end = .;
130        } > REGION_RODATA AT > REGION_RODATA_LOAD
131        .tbss : ALIGN_WITH_INPUT {
132                _TLS_BSS_begin = .;
133                *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon)
134                _TLS_BSS_end = .;
135        } > REGION_RODATA AT > REGION_RODATA_LOAD
136        _TLS_Data_size = _TLS_Data_end - _TLS_Data_begin;
137        _TLS_Data_begin = _TLS_Data_size != 0 ? _TLS_Data_begin : _TLS_BSS_begin;
138        _TLS_Data_end = _TLS_Data_size != 0 ? _TLS_Data_end : _TLS_BSS_begin;
139        _TLS_BSS_size = _TLS_BSS_end - _TLS_BSS_begin;
140        _TLS_Size = _TLS_BSS_end - _TLS_Data_begin;
141        _TLS_Alignment = MAX (ALIGNOF (.tdata), ALIGNOF (.tbss));
142        .preinit_array : ALIGN_WITH_INPUT {
143                PROVIDE_HIDDEN (__preinit_array_start = .);
144                KEEP (*(.preinit_array))
145                PROVIDE_HIDDEN (__preinit_array_end = .);
146        } > REGION_RODATA AT > REGION_RODATA_LOAD
147        .init_array : ALIGN_WITH_INPUT {
148                PROVIDE_HIDDEN (__init_array_start = .);
149                KEEP (*(SORT_BY_INIT_PRIORITY(.init_array.*) SORT_BY_INIT_PRIORITY(.ctors.*)))
150                KEEP (*(.init_array EXCLUDE_FILE (*crtbegin.o *crtbegin?.o *crtend.o *crtend?.o ) .ctors))
151                PROVIDE_HIDDEN (__init_array_end = .);
152        } > REGION_RODATA AT > REGION_RODATA_LOAD
153        .fini_array : ALIGN_WITH_INPUT {
154                PROVIDE_HIDDEN (__fini_array_start = .);
155                KEEP (*(SORT_BY_INIT_PRIORITY(.fini_array.*) SORT_BY_INIT_PRIORITY(.dtors.*)))
156                KEEP (*(.fini_array EXCLUDE_FILE (*crtbegin.o *crtbegin?.o *crtend.o *crtend?.o ) .dtors))
157                PROVIDE_HIDDEN (__fini_array_end = .);
158        } > REGION_RODATA AT > REGION_RODATA_LOAD
159        .data.rel.ro : ALIGN_WITH_INPUT {
160                *(.data.rel.ro.local* .gnu.linkonce.d.rel.ro.local.*)
161                *(.data.rel.ro* .gnu.linkonce.d.rel.ro.*)
162        } > REGION_RODATA AT > REGION_RODATA_LOAD
163        .jcr : ALIGN_WITH_INPUT {
164                KEEP (*(.jcr))
165        } > REGION_RODATA AT > REGION_RODATA_LOAD
166        .interp : ALIGN_WITH_INPUT {
167                *(.interp)
168        } > REGION_RODATA AT > REGION_RODATA_LOAD
169        .note.gnu.build-id : ALIGN_WITH_INPUT {
170                *(.note.gnu.build-id)
171        } > REGION_RODATA AT > REGION_RODATA_LOAD
172        .hash : ALIGN_WITH_INPUT {
173                *(.hash)
174        } > REGION_RODATA AT > REGION_RODATA_LOAD
175        .gnu.hash : ALIGN_WITH_INPUT {
176                *(.gnu.hash)
177        } > REGION_RODATA AT > REGION_RODATA_LOAD
178        .dynsym : ALIGN_WITH_INPUT {
179                *(.dynsym)
180        } > REGION_RODATA AT > REGION_RODATA_LOAD
181        .dynstr : ALIGN_WITH_INPUT {
182                *(.dynstr)
183        } > REGION_RODATA AT > REGION_RODATA_LOAD
184        .gnu.version : ALIGN_WITH_INPUT {
185                *(.gnu.version)
186        } > REGION_RODATA AT > REGION_RODATA_LOAD
187        .gnu.version_d : ALIGN_WITH_INPUT {
188                *(.gnu.version_d)
189        } > REGION_RODATA AT > REGION_RODATA_LOAD
190        .gnu.version_r : ALIGN_WITH_INPUT {
191                *(.gnu.version_r)
192        } > REGION_RODATA AT > REGION_RODATA_LOAD
193        .rel.dyn : ALIGN_WITH_INPUT {
194                *(.rel.init)
195                *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*)
196                *(.rel.fini)
197                *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*)
198                *(.rel.data.rel.ro* .rel.gnu.linkonce.d.rel.ro.*)
199                *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*)
200                *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*)
201                *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*)
202                *(.rel.ctors)
203                *(.rel.dtors)
204                *(.rel.got)
205                *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*)
206                PROVIDE_HIDDEN (__rel_iplt_start = .);
207                *(.rel.iplt)
208                PROVIDE_HIDDEN (__rel_iplt_end = .);
209                PROVIDE_HIDDEN (__rela_iplt_start = .);
210                PROVIDE_HIDDEN (__rela_iplt_end = .);
211        } > REGION_RODATA AT > REGION_RODATA_LOAD
212        .rela.dyn : ALIGN_WITH_INPUT {
213                *(.rela.init)
214                *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*)
215                *(.rela.fini)
216                *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*)
217                *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*)
218                *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*)
219                *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*)
220                *(.rela.ctors)
221                *(.rela.dtors)
222                *(.rela.got)
223                *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)
224                *(.rela.rtemsroset*)
225                *(.rela.rtemsrwset*)
226                PROVIDE_HIDDEN (__rel_iplt_start = .);
227                PROVIDE_HIDDEN (__rel_iplt_end = .);
228                PROVIDE_HIDDEN (__rela_iplt_start = .);
229                *(.rela.iplt)
230                PROVIDE_HIDDEN (__rela_iplt_end = .);
231        } > REGION_RODATA AT > REGION_RODATA_LOAD
232        .rel.plt : ALIGN_WITH_INPUT {
233                *(.rel.plt)
234        } > REGION_RODATA AT > REGION_RODATA_LOAD
235        .rela.plt : ALIGN_WITH_INPUT {
236                *(.rela.plt)
237        } > REGION_RODATA AT > REGION_RODATA_LOAD
238        .plt : ALIGN_WITH_INPUT {
239                *(.plt)
240        } > REGION_RODATA AT > REGION_RODATA_LOAD
241        .iplt : ALIGN_WITH_INPUT {
242                *(.iplt)
243        } > REGION_RODATA AT > REGION_RODATA_LOAD
244        .dynamic : ALIGN_WITH_INPUT {
245                *(.dynamic)
246        } > REGION_RODATA AT > REGION_RODATA_LOAD
247        .tm_clone_table : ALIGN_WITH_INPUT {
248                *(.tm_clone_table)
249        } > REGION_RODATA AT > REGION_RODATA_LOAD
250        .got : ALIGN_WITH_INPUT {
251                *(.got.plt) *(.igot.plt) *(.got) *(.igot)
252        } > REGION_RODATA AT > REGION_RODATA_LOAD
253        .rtemsroset : ALIGN_WITH_INPUT {
254                /* Special FreeBSD linker set sections */
255                __start_set_sysctl_set = .;
256                *(set_sysctl_*);
257                __stop_set_sysctl_set = .;
258                *(set_domain_*);
259                *(set_pseudo_*);
260
261                KEEP (*(SORT(.rtemsroset.*)))
262
263                /*
264                 * If requested, align the size of the rodata section to the
265                 * next power of two to meet MPU region alignment requirements.
266                 */
267                . = DEFINED (bsp_align_text_and_rodata_end_to_power_of_2) ?
268                    bsp_section_rodata_begin
269                    + ALIGN (. - bsp_section_rodata_begin,
270                    1 << LOG2CEIL (. - bsp_section_rodata_begin)) : .;
271
272                bsp_section_rodata_end = .;
273        } > REGION_RODATA AT > REGION_RODATA_LOAD
274        bsp_section_rodata_size = bsp_section_rodata_end - bsp_section_rodata_begin;
275        bsp_section_rodata_load_begin = LOADADDR (.rodata);
276        bsp_section_rodata_load_end = bsp_section_rodata_load_begin + bsp_section_rodata_size;
277
278        .rwbarrier : ALIGN_WITH_INPUT {
279                . = ALIGN (bsp_section_rwbarrier_align);
280        } > REGION_DATA AT > REGION_DATA
281
282        .vector : ALIGN_WITH_INPUT {
283                bsp_section_vector_begin = .;
284                . = . + DEFINED (bsp_vector_table_in_start_section) ? 0 : bsp_vector_table_size;
285                bsp_section_vector_end = .;
286        } > REGION_VECTOR AT > REGION_VECTOR
287        bsp_section_vector_size = bsp_section_vector_end - bsp_section_vector_begin;
288        bsp_vector_table_begin = DEFINED (bsp_vector_table_in_start_section) ? bsp_section_start_begin : bsp_section_vector_begin;
289        bsp_vector_table_end = bsp_vector_table_begin + bsp_vector_table_size;
290
291        .fast_text : ALIGN_WITH_INPUT {
292                bsp_section_fast_text_begin = .;
293                *(SORT_BY_ALIGNMENT (SORT_BY_NAME (.bsp_fast_text*)))
294                bsp_section_fast_text_end = .;
295        } > REGION_FAST_TEXT AT > REGION_FAST_TEXT_LOAD
296        bsp_section_fast_text_size = bsp_section_fast_text_end - bsp_section_fast_text_begin;
297        bsp_section_fast_text_load_begin = LOADADDR (.fast_text);
298        bsp_section_fast_text_load_end = bsp_section_fast_text_load_begin + bsp_section_fast_text_size;
299
300        .fast_data : ALIGN_WITH_INPUT {
301                bsp_section_fast_data_begin = .;
302                *(SORT_BY_ALIGNMENT (SORT_BY_NAME (.bsp_fast_data*)))
303                bsp_section_fast_data_end = .;
304        } > REGION_FAST_DATA AT > REGION_FAST_DATA_LOAD
305        bsp_section_fast_data_size = bsp_section_fast_data_end - bsp_section_fast_data_begin;
306        bsp_section_fast_data_load_begin = LOADADDR (.fast_data);
307        bsp_section_fast_data_load_end = bsp_section_fast_data_load_begin + bsp_section_fast_data_size;
308
309        .data : ALIGN_WITH_INPUT {
310                bsp_section_data_begin = .;
311                *(.data .data.* .gnu.linkonce.d.*)
312                SORT(CONSTRUCTORS)
313        } > REGION_DATA AT > REGION_DATA_LOAD
314        .data1 : ALIGN_WITH_INPUT {
315                *(.data1)
316        } > REGION_DATA AT > REGION_DATA_LOAD
317        .rtemsrwset : ALIGN_WITH_INPUT {
318                KEEP (*(SORT(.rtemsrwset.*)))
319                bsp_section_data_end = .;
320        } > REGION_DATA AT > REGION_DATA_LOAD
321        bsp_section_data_size = bsp_section_data_end - bsp_section_data_begin;
322        bsp_section_data_load_begin = LOADADDR (.data);
323        bsp_section_data_load_end = bsp_section_data_load_begin + bsp_section_data_size;
324
325        .bss : ALIGN_WITH_INPUT {
326                bsp_section_bss_begin = .;
327                *(.dynbss)
328                *(.bss .bss.* .gnu.linkonce.b.*)
329                *(COMMON)
330                bsp_section_bss_end = .;
331        } > REGION_BSS AT > REGION_BSS
332        bsp_section_bss_size = bsp_section_bss_end - bsp_section_bss_begin;
333
334        .rtemsstack (NOLOAD) : ALIGN_WITH_INPUT {
335                bsp_section_rtemsstack_begin = .;
336                *(SORT_BY_ALIGNMENT (SORT_BY_NAME (.rtemsstack*)))
337                bsp_section_rtemsstack_end = .;
338        } > REGION_WORK AT > REGION_WORK
339        bsp_section_rtemsstack_size = bsp_section_rtemsstack_end - bsp_section_rtemsstack_begin;
340
341        .work : ALIGN_WITH_INPUT {
342                /*
343                 * The work section will occupy the remaining REGION_WORK region and
344                 * contains the RTEMS work space and heap.
345                 */
346                bsp_section_work_begin = .;
347                . += ORIGIN (REGION_WORK) + LENGTH (REGION_WORK) - ABSOLUTE (.);
348                bsp_section_work_end = .;
349        } > REGION_WORK AT > REGION_WORK
350        bsp_section_work_size = bsp_section_work_end - bsp_section_work_begin;
351
352        .stack : ALIGN_WITH_INPUT {
353                /*
354                 * The stack section will occupy the remaining REGION_STACK region and may
355                 * contain the task stacks.  Depending on the region distribution this
356                 * section may be of zero size.
357                 */
358                bsp_section_stack_begin = .;
359                . += ORIGIN (REGION_STACK) + LENGTH (REGION_STACK) - ABSOLUTE (.);
360                bsp_section_stack_end = .;
361        } > REGION_STACK AT > REGION_STACK
362        bsp_section_stack_size = bsp_section_stack_end - bsp_section_stack_begin;
363
364        .nocache : ALIGN_WITH_INPUT {
365                bsp_section_nocache_begin = .;
366                *(SORT_BY_ALIGNMENT (SORT_BY_NAME (.bsp_nocache*)))
367                bsp_section_nocache_end = .;
368        } > REGION_NOCACHE AT > REGION_NOCACHE_LOAD
369        bsp_section_nocache_size = bsp_section_nocache_end - bsp_section_nocache_begin;
370        bsp_section_nocache_load_begin = LOADADDR (.nocache);
371        bsp_section_nocache_load_end = bsp_section_nocache_load_begin + bsp_section_nocache_size;
372
373        .nocachenoload (NOLOAD) : ALIGN_WITH_INPUT {
374                bsp_section_nocachenoload_begin = .;
375                *(SORT_BY_ALIGNMENT (SORT_BY_NAME (.bsp_noload_nocache*)))
376                bsp_section_nocacheheap_begin = .;
377                . += ORIGIN (REGION_NOCACHE) + LENGTH (REGION_NOCACHE) - ABSOLUTE (.);
378                bsp_section_nocacheheap_end = .;
379                bsp_section_nocachenoload_end = .;
380        } > REGION_NOCACHE AT > REGION_NOCACHE
381        bsp_section_nocacheheap_size = bsp_section_nocacheheap_end - bsp_section_nocacheheap_begin;
382        bsp_section_nocachenoload_size = bsp_section_nocachenoload_end - bsp_section_nocachenoload_begin;
383
384        /* FIXME */
385        RamBase = ORIGIN (REGION_WORK);
386        RamSize = LENGTH (REGION_WORK);
387        RamEnd = RamBase + RamSize;
388        WorkAreaBase = bsp_section_work_begin;
389        HeapSize = 0;
390
391        /* Stabs debugging sections.  */
392        .stab          0 : { *(.stab) }
393        .stabstr       0 : { *(.stabstr) }
394        .stab.excl     0 : { *(.stab.excl) }
395        .stab.exclstr  0 : { *(.stab.exclstr) }
396        .stab.index    0 : { *(.stab.index) }
397        .stab.indexstr 0 : { *(.stab.indexstr) }
398        .comment       0 : { *(.comment) }
399        /* DWARF debug sections.
400           Symbols in the DWARF debugging sections are relative to the beginning
401           of the section so we begin them at 0.  */
402        /* DWARF 1.  */
403        .debug          0 : { *(.debug) }
404        .line           0 : { *(.line) }
405        /* GNU DWARF 1 extensions.  */
406        .debug_srcinfo  0 : { *(.debug_srcinfo) }
407        .debug_sfnames  0 : { *(.debug_sfnames) }
408        /* DWARF 1.1 and DWARF 2.  */
409        .debug_aranges  0 : { *(.debug_aranges) }
410        .debug_pubnames 0 : { *(.debug_pubnames) }
411        /* DWARF 2.  */
412        .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
413        .debug_abbrev   0 : { *(.debug_abbrev) }
414        .debug_line     0 : { *(.debug_line .debug_line.* .debug_line_end) }
415        .debug_frame    0 : { *(.debug_frame) }
416        .debug_str      0 : { *(.debug_str) }
417        .debug_loc      0 : { *(.debug_loc) }
418        .debug_macinfo  0 : { *(.debug_macinfo) }
419        /* SGI/MIPS DWARF 2 extensions.  */
420        .debug_weaknames 0 : { *(.debug_weaknames) }
421        .debug_funcnames 0 : { *(.debug_funcnames) }
422        .debug_typenames 0 : { *(.debug_typenames) }
423        .debug_varnames  0 : { *(.debug_varnames) }
424        /* DWARF 3.  */
425        .debug_pubtypes 0 : { *(.debug_pubtypes) }
426        .debug_ranges   0 : { *(.debug_ranges) }
427        /* DWARF 5.  */
428        .debug_loclists 0 : { *(.debug_loclists) }
429        .debug_rnglists 0 : { *(.debug_rnglists) }
430        .debug_line_str 0 : { *(.debug_line_str) }
431        .debug_str_offsets 0 : { *(.debug_str_offsets) }
432        .debug_macro    0 : { *(.debug_macro) }
433        .debug_addr     0 : { *(.debug_addr) }
434        .ARM.attributes 0 : { KEEP (*(.ARM.attributes)) KEEP (*(.gnu.attributes)) }
435        .note.gnu.arm.ident 0 : { KEEP (*(.note.gnu.arm.ident)) }
436        /DISCARD/ : { *(.note.GNU-stack) *(.gnu_debuglink) *(.gnu.lto_*) }
437
438        /*
439         * This is a RTEMS specific section to catch all unexpected input
440         * sections.  In case you get an error like
441         *   "section `.unexpected_sections' will not fit in region
442         *   `UNEXPECTED_SECTIONS'"
443         * you have to figure out the offending input section and add it to the
444         * appropriate output section definition above.
445         */
446        .unexpected_sections : { *(*) } > UNEXPECTED_SECTIONS
447}
Note: See TracBrowser for help on using the repository browser.